VBScript: What is the simplest way to format a string?

Question

I have the following format: Value1 is {0} and Value2 is {1}.

I need to replace the numbers in the brackets with strings. This is easily done in most languages using string.Format or something along those lines. How can I do this using only vbscript?

I've tried:

Replace (strFormat, "{0}", value1)  
Replace (strFormat, "{1}", value2)

It does not work. Any solutions?

score 12 · Accepted Answer · edited Jan 30 '15 at 11:34

12

Replace (strFormat, "{0}", value1)

Based on your code snip, I'm guessing you believe Replace mutates strFormat directly. It doesn't work like that; You assign the result to the original variable like this:

strFormat = Replace (strFormat, "{0}", value1)

You can also assign to another variable to store the changed results, like this:

strFormat2 = Replace (strFormat, "{0}", value1)

edited Jan 30 '15 at 11:34

James McCormack

9,217
3
47
57

answered Dec 03 '09 at 15:51

JasDev

726
6
13

Hehe, Thanks. It's always something simple. – Paxenos Dec 03 '09 at 15:55
6

he doesnt need _another_ variable, but just to update original string. – Rubens Farias Dec 03 '09 at 16:07

score 11 · Answer 2 · edited Sep 05 '12 at 15:18

11

I wanted something similar and didn't like any of these answers as they meant multiple lines for each value (Ignoring Beaner's answer is for the wrong language!) so I created the following:

Public Function StrFormat(FormatString, Arguments())
    Dim Value, CurArgNum

    StrFormat = FormatString

    CurArgNum = 0
    For Each Value In Arguments
        StrFormat = Replace(StrFormat, "{" & CurArgNum & "}", Value)
        CurArgNum = CurArgNum + 1
    Next
End Function

You can use the following then (note that you need to add "Array()" around your variables):

formatString = "Test '{0}', '{2}', '{1}' and {0} again!"
Response.Write StrFormat(formatString, Array(1, 2, "three", "Unused"))
Response.Write StrFormat(formatString, Array(4, 5, "six", "Unused"))

Which will output what you expect:

Test '1', 'three', '2' and 1 again!
Test '4', 'six', '5' and 4 again!

Hope this feels a bit more natural for people from other languages.

edited Sep 05 '12 at 15:18

Christoffer Lette

14,346
7
50
58

answered Jun 29 '12 at 10:05

GazB

3,510
1
36
42

1

This is IMHO the best answer; simple and reusable. I almost upvoted it, but then I ran into trouble. Thing is, your example modifies `SourceString`. That's no good when `SourceString` contains a format string that you will be reusing. Subsequent calls to `StringFormat(SourceString, ...)` won't work because `SourceString` contains the result of the previous call. I'll edit your answer to fix this. – Christoffer Lette Sep 05 '12 at 15:13
1

Edited. I changed the name of the parameter `SourceString` to `FormatString`. Eg. [.Net's String.Format](http://msdn.microsoft.com/en-us/library/b1csw23d.aspx) has the name `format` for the first parameter. Now, I can upvote! – Christoffer Lette Sep 05 '12 at 15:26
1

The only possible problem I see with this solution is that arguments that contain later argument number formats will be replaced themselves. – EdGruberman May 08 '14 at 20:01

score 5 · Answer 3 · edited May 23 '17 at 12:25

As none of the answers so far addresses the problem of formatting (as opposed to interpolating/splicing strings into strings):

This simple Class:

Class cFormat
  Private m_oSB
  Private Sub Class_Initialize()
    Set m_oSB = CreateObject("System.Text.StringBuilder")
  End Sub ' Class_Initialize
  Public Function formatOne(sFmt, vElm)
    m_oSB.AppendFormat sFmt, vElm
    formatOne = m_oSB.ToString()
    m_oSB.Length = 0
  End Function ' formatOne
  Public Function formatArray(sFmt, aElms)
    m_oSB.AppendFormat_4 sFmt, (aElms)
    formatArray = m_oSB.ToString()
    m_oSB.Length = 0
  End Function ' formatArray
End Class ' cFormat

harness .NET formatting for VBScript via COM. Now you can do:

-------- Interpolation
Use    |Value1 is {0} and Value2 is {1}.|
to get |Value1 is zero and Value2 is one.|
from   |zero one|

Use    |{0} x 2 => {0}{0}|
to get |once x 2 => onceonce|
from   |once|

-------- Cherrypicking
Use    |{6,4}: [{0}, {2}, {4}]|
to get |even: [0, 2, 4]|
from   |0 1 2 3 4 5 even odd|

Use    |{7,4}: [{5}, {3}, {1}]|
to get | odd: [5, 3, 1]|
from   |0 1 2 3 4 5 even odd|

-------- Conversions
Use    ||{0:D}| |{0:X}| |{0:N3}| |{0:P2}| (german locale!)|
to get ||123| |7B| |123,000| |12.300,00%| (german locale!)|
from   |123|

Use    ||{0}| |{0:U}| |{0:u}||
to get ||29.06.2012 14:50:30| |Freitag, 29. Juni 2012 12:50:30| |2012-06-29 14:50:30Z||
from   |29.06.2012 14:50:30|

Use    ||{0}| |{0:E1}| |{0:N1}| |{0:N2}| |{0:N3}||
to get ||1234,56| |1,2E+003| |1.234,6| |1.234,56| |1.234,560||
from   |1234,56|

-------- Alignment
Use    ||{0,1:D}| |{0,2:D}| |{0,-2:D}| |{0,5:D}| |{0,-5:D}||
to get ||12| |12| |12| |   12| |12   ||
from   |12|

If you are interested in the test/demo script to do some experiments of your own:

Option Explicit

' Class cFormat ...

Dim oFormat : Set oFormat = New cFormat
Dim aTests  : aTests      = Array( _
    Array("Interpolation" _
      , Array( _
            Array(True,  "Value1 is {0} and Value2 is {1}.", Array("zero", "one")) _
          , Array(False, "{0} x 2 => {0}{0}"               , "once"              ) _
        } _
    ) _
  , Array("Cherrypicking" _
      , Array( _
            Array(True , "{6,4}: [{0}, {2}, {4}]", Array(0, 1, 2, 3, 4, 5, "even", "odd")) _
          , Array(True , "{7,4}: [{5}, {3}, {1}]", Array(0, 1, 2, 3, 4, 5, "even", "odd")) _
        } _
    ) _
  , Array("Conversions" _
      , Array( _
            Array(False, "|{0:D}| |{0:X}| |{0:N3}| |{0:P2}| (german locale!)", 123      ) _
          , Array(False, "|{0}| |{0:U}| |{0:u}|"                             , Now     ) _
          , Array(False, "|{0}| |{0:E1}| |{0:N1}| |{0:N2}| |{0:N3}|"         , 1234.56 ) _
        } _
    ) _
  , Array("Alignment" _
      , Array( _
            Array(False, "|{0,1:D}| |{0,2:D}| |{0,-2:D}| |{0,5:D}| |{0,-5:D}|", 12 ) _
        } _
    ) _
)
Dim sFormat : sFormat = "Use    |{0}|{3}to get |{1}|{3}from   |{2}|{3}"
Dim aData   : aData   = Array(0, 1, 2, vbCrLf)
Dim aTest
For Each aTest In aTests
    WScript.Echo "--------", aTest(0)
    Dim aSample
    For Each aSample In aTest(1)
        aData(0) = aSample(1)
        If aSample(0) Then
           aData(1) = oFormat.formatArray(aSample(1), aSample(2))
           aData(2) = Join(aSample(2))
        Else
           aData(1) = oFormat.formatOne(  aSample(1), aSample(2))
           aData(2) = aSample(2)
        End If
        WScript.Echo oFormat.formatArray(sFormat, aData)
    Next
    WScript.Echo
Next

To learn about formatting in .NET, start with StringBuilder.AppendFormat Method (String, Object) and Formatting Types.

See here and here for ideas to include (not Copy&Paste) such a Class into your script.

score 1 · Answer 4 · answered Dec 03 '09 at 16:59

Here's a nice little function that works something like the .NET string.Format function. I did this quickly so adding err handling is up to you. I did this in VB6 and added a reference to Microsoft VBScript Regular Expressions 5.5

Public Function StringFormat(ByVal SourceString As String, ParamArray Arguments() As Variant) As String
   Dim objRegEx As RegExp  ' regular expression object
   Dim objMatch As Match   ' regular expression match object
   Dim strReturn As String ' the string that will be returned

   Set objRegEx = New RegExp
   objRegEx.Global = True
   objRegEx.Pattern = "(\{)(\d)(\})"

   strReturn = SourceString
   For Each objMatch In objRegEx.Execute(SourceString)
      strReturn = Replace(strReturn, objMatch.Value, Arguments(CInt(objMatch.SubMatches(1))))
   Next objMatch

   StringFormat = strReturn

End Function

Example:

StringFormat("Hello {0}. I'd like you to meet {1}. They both work for {2}. {0} has worked for {2} for 15 years.", "Bruce", "Chris", "Kyle")

Returns:

Hello Bruce. I'd like you to meet Chris. They both work for Kyle. Bruce has worked for Kyle for 15 years.

A few adjustments might be made for VBScript, but this function looks like it might be versatile than just a simple Replace function. — Chris, Dec 03 '09 at 19:04

score 0 · Answer 5 · answered Dec 03 '09 at 15:47

Why not? This code works here:

value1 = "1"
value2 = "2"

strFormat = "Value1 is {0} and Value2 is {1}."
strFormat = Replace (strFormat, "{0}", value1)  
strFormat = Replace (strFormat, "{1}", value2)

MsgBox strFormat

Note I update my strFormat value for every replace.

If you needs a more flexible implementation, you can go with a regular expression, but doesn't seems required now.

score 0 · Answer 6 · answered Mar 25 '22 at 23:33

I really liked the functionality of @Ekkehard.Horner's StringBuilder-based solution, but it seemed more complicated than necessary.

For my purposes, I definitely do not need the ceremony of a whole class.

I pared it down to this single function:

Function FormatString(format, args)
    dim resultBuilder

    set resultBuilder = CreateObject("System.Text.StringBuilder")
    
    if IsArray(args) Then
        resultBuilder.AppendFormat_4 format, (args)
    else
        resultBuilder.AppendFormat format, args
    end if

    FormatString = resultBuilder.ToString()
End Function

WScript.Echo FormatString("Hello, {0}!", "World")
WScript.Echo FormatString("Hello, {0}! It is {1:H:mm tt}, and we are {2:P2} through the day on {1:dddd, d MMMM, yyyy}.", Array("World", Now, Timer/(24*60*60)))

VBScript: What is the simplest way to format a string?

6 Answers6

Linked