Iterate through String with multiple lines

Question

I got some data:

def data = "# some useless text\n"+
        "# even more\n"+
        "finally interesting text"

How can I get the "interesting part" of that? So basically all lines, NOT starting with #.

score 14 · Accepted Answer · answered Jan 22 '13 at 00:14

One Groovy option would be:

def data = '''# some useless text
             |# even more
             |finally interesting text'''.stripMargin()

List lines = data.split( '\n' ).findAll { !it.startsWith( '#' ) }

assert lines == [ 'finally interesting text' ]

score 13 · Answer 2 · answered Mar 31 '15 at 20:10

13

data.eachLine {
    if (!it.startsWith( '#' )
        println it
}

answered Mar 31 '15 at 20:10

jozh

2,412
2
15
15

score 9 · Answer 3 · answered Jan 22 '13 at 00:05

9

Use split method to get substrings then check each one starts with "#" or not. For example:

String[] splitData = data.split("\n");
for (String eachSplit : splitData) {
  if (!eachSplit.startWith("#")) {
    print(eachSplit);
  }
}

answered Jan 22 '13 at 00:05

SJ Z

91
1

score 1 · Answer 4 · answered Jan 22 '13 at 00:03

1

How's about splitting the string with \n character via the split function

Now you can just test each string if it starts with # or not via String.startsWith("#") .

answered Jan 22 '13 at 00:03

sradforth

2,176
2
23
37

score 1 · Answer 5 · answered Jan 22 '13 at 18:38

Here is a solution by using Groovy's meta programming feature (http://groovy.codehaus.org/JN3525-MetaClasses):

def data = "# some useless text\n"+
    "# even more\n"+
    "finally interesting text"

String.metaClass.collectLines = { it ->
    delegate.split('\n').findAll it
}

def result = data.collectLines{ !it.startsWith( '#' )}

assert result == ["finally interesting text"]

supersam654 · Answer 6 · 2013-01-22T00:30:33.933

0

I would split the string based on the newline character (\n) and then ignore the lines that start with "#".

String[] lines = data.split("\n");
for (String line : lines) {
    if (line.startsWith("#") {
        continue;
    }
    //Do stuff with the important part
}

Note that this is pure Java.

edited Jan 22 '13 at 00:30

answered Jan 22 '13 at 00:03

supersam654

3,126
33
34

this will split on the literal `"\n"`, not the newline character `\n` – Peter Elliott Jan 22 '13 at 00:24

score 0 · Answer 7 · answered Jan 22 '13 at 00:40

A regexp-based solution that does not require to convert the input string into a list is:

def data = '''\
# some useless text
# even more
finally interesting text'''

assert data.replaceAll(/#.*\n/, '') == 'finally interesting text'

If you need to split the input into lines anyways, you can still use regexps if you want to, using the Collection#grep method:

assert data.split('\n').grep(~/[^#].*/) == ['finally interesting text']

PS: Regexps FTW! =P

Iterate through String with multiple lines

7 Answers7

Linked