I want to rename file name like "how-to-rename-file.jpg" to "how-to-reuse-file.jpg" by using a Windows batch file
I.e. I only want to replace one or two words in a file name.
Asked
Active
Viewed 1.1e+01k times
28
-
1Please add what you have tried. Also, we need more information. – BDM Apr 21 '13 at 07:25
-
Consider trying [Bulk Rename Here](http://www.bulkrenameutility.co.uk/Download.php). – Danny Beckett Apr 21 '13 at 07:27
-
@casperOne hmmm...a little too strict me thinks. – Steve Gon Nov 24 '17 at 01:01
2 Answers
57
@echo off
Set "Filename=how-to-rename-file.jpg"
Set "Pattern=rename"
Set "Replace=reuse"
REM Call Rename "%Filename%" "%%Filename:%Pattern%=%Replace%%%"
Call Echo %%Filename:%Pattern%=%Replace%%%
:: Result: how-to-reuse-file.jpg
Pause&Exit
I give you other example for a loop of files:
UPDATE:
I've missed some things in the syntax 'cause fast-typing my last edit, here is the corrected code:
@echo off
Setlocal enabledelayedexpansion
Set "Pattern=rename"
Set "Replace=reuse"
For %%# in ("C:\Folder\*.jpg") Do (
Set "File=%%~nx#"
Ren "%%#" "!File:%Pattern%=%Replace%!"
)
Pause&Exit
PS: You can read here to learn more about substring: http://ss64.com/nt/syntax-substring.html http://ss64.com/nt/syntax-replace.html
ElektroStudios
- 19,105
- 33
- 200
- 417
-
5The second code is exactly what i need. Thank you sooo much for your help. Also thanks for providing me link to learn more about strings I found this link very informative :-) – Varun Apr 21 '13 at 07:56
-
1Why did you use `Set "File=%%~nx#"` instead of a simple Set `"File=%%#"` ? – Marco Demaio Jan 14 '15 at 12:50
-
1@Marco Demaio To introduce new users in the reserved For modifiers. – ElektroStudios Jan 15 '15 at 02:01
-
@ElektroStudios sorry, but what do you mean by "introduce new users"? What users? – Marco Demaio Jan 15 '15 at 11:17
-
Everyone who is starting to learn, those who come here in search of a solution and finds a public code. – ElektroStudios Jan 15 '15 at 11:38
-
@ElektroStudios: ah ok, sorry, I thought you were talking about users' rights in Windows OS. Thanks! – Marco Demaio Jan 15 '15 at 12:15
-
1Unfortunately that doesn't seem to work to replace 'special' characters such as ç or õ. – Vinícius M Nov 30 '18 at 12:10
37
The code above doesn't rename the files - The paths are an issue and the source filename is incorrect.
This will work on files in the current folder - except those with ! in the names will be a problem.
@echo off
Setlocal enabledelayedexpansion
Set "Pattern=rename"
Set "Replace=reuse"
For %%a in (*.jpg) Do (
Set "File=%%~a"
Ren "%%a" "!File:%Pattern%=%Replace%!"
)
Pause&Exit
foxidrive
- 40,353
- 10
- 53
- 68
-
I know this is an old topic, but what should I add to define a folder instead of using the local folder? – Schuere Jan 05 '15 at 08:24
-
1Place `pushd "c:\folder"` above the loop, or use `cd /d "c:\folder"` – foxidrive Jan 06 '15 at 10:27
-
-
Just one note, I think `Set "File=%%~a"` can be replaced with `Set "File=%%a"` (with no ~) because the ~ is used with a parameter extension that you are not using. http://ss64.com/nt/syntax-args.html – Marco Demaio Jan 14 '15 at 12:47
-
@MarcoDemaio You are absolutely correct that the tilda is not needed, though it will never cause any issue there either. – foxidrive Jan 14 '15 at 14:28
-
@foxidrive Your solution is an absolute beauty. Very precise and simple to understand. Helped me a great deal. – nam Apr 12 '16 at 17:48
-
-
2This worked great. Now could you make it recursive on subfolders? – Scott Hutchinson Apr 04 '18 at 20:42
-
@RodrigoZuluaga I'm curious how you guys made it work. I tried all that is posted above. No luck for me. – Data Engineer May 25 '20 at 04:58
-
@enigma6205 create a in notepad a yourname.bat file, place that top code, and put the file where the files you're renaming are. If you don't wanna mess around with bat files u can download Bulk Rename Utility. I don't think im allowed to to place url here, so search it on google, the site is a .co.uk. I found this and replaced all my bat files for masive renaming. – Rodrigo Zuluaga May 25 '20 at 13:46