if exist check with case sensitive in batch

Question

I need to check whether the given file is exist or not with case sensitive, out.txt(all are small letters) file is present in location where i running the script.

Code:

Case1:
filename=out.txt
 if exist %filename% (
    echo file exist...
) else echo File doesn't exist...

Case2:
filename=OUT.TXT
if exist %filename% (
    echo file exist...
) else echo File doesn't exist...

For both case it showing file exist... output. But i need to check with case sensitive. It should show "File doesn't exist" msg for OUT.TXT

Thanks in advance

Stephan · Accepted Answer · 2017-12-22T12:25:29.287

2

take filename from parameter:

@echo off 
dir /b /a-d "%~1"|find "%~1" >nul
if %errorlevel% == 0 (echo found) else (echo fail)

diris in fact not case sensitive - but find is...

edited Dec 22 '17 at 12:25

answered Jun 24 '13 at 11:21

Stephan

53,940
10
58
91

2

Safer to use `dir /b /a-d "%~1"|find "%~1" >nul` – dbenham Jun 24 '13 at 19:24
two improvements in one line - not bad! – Stephan Jun 24 '13 at 19:27
What about `dir /B /A:-D "%~1" | findstr /X /C:"%~1" > nul`? – aschipfl Dec 18 '17 at 17:32
1

@aschipfl no need for `/X`, as `dir`already filters the files. Also no need for `findstr /C`, because `find` already handles strings with spaces. But will implement the other suggestions (already made by dbenham) – Stephan Dec 22 '17 at 12:25

foxidrive · Answer 2 · 2013-06-24T10:28:11.467

1

Added file list parsing:

@echo off
for /f "delims=" %%z in ('type "namelist.txt" ') do (
if not exist "%%~z" echo "%%~z" not found
if     exist "%%~z" for %%a in ("%%~z") do if "%%a"=="%%~z" (echo "%%~z" is the right case) else (echo "%%~z" is the wrong case "%%a found")
)
pause

edited Jun 24 '13 at 10:28

answered Jun 24 '13 at 10:01

foxidrive

40,353
10
53
68

Thanks... but here the script getting file names from another script as input.. we don't know the file name here to compare like "OUT.TXT". If we compare like, for %%a in (%filename%) do if "%%a"=="%filename%" echo file exists... the result is same like "if exist %filename%" – user1553605 Jun 24 '13 at 10:15
@user1553605 If you wanted to parse a list of filenames then say so. My code did what you asked. See the change above for file parsing. – foxidrive Jun 24 '13 at 10:28

if exist check with case sensitive in batch

2 Answers2

Linked