Show output from child scripts in the parent console window

Question

I'm calling VBScripts from inside of a VBScript and I want their console output to appear in the window from which I'm calling them. So when I have this code

WScript.Stdout.WriteLine( "Checking out unit tests" )

ObjWshShell.Run "%comspec% \c checkoutUnitTests.vbs", 0, True

the the only output I see is

Checking out unit tests

when I want to see all the output from checkoutUnitTests.vbs concatenated onto that output in the same window. How do I do this?

score 4 · Accepted Answer · edited May 23 '17 at 10:09

4

You should try to use .Exec and .Stdout.Readline() as in this bare bone demo script:

mother.vbs

Option Explicit

Dim oWS : Set oWS = CreateObject("WScript.Shell")
WScript.Echo "A", "mother starts child"
Dim oEx : Set oEx = oWS.Exec("cscript child.vbs")
Do Until oEx.Stdout.AtEndOfStream
   WScript.Echo oEx.Stdout.ReadLine()
Loop
WScript.Echo "B", "mother done"

child.vbs:

Option Explicit

Dim n
For n = 1 To 5
    WScript.Echo n, "child"
Next

output:

cscript mother.vbs
A mother starts child
1 child
2 child
3 child
4 child
5 child
B mother done

Added:

see Pythonic version

edited May 23 '17 at 10:09

Community

1
1

answered Jun 25 '13 at 16:32

Ekkehard.Horner

38,498
2
45
96

doesn't work for me, opens a new window & all output is in that new window. – coding_idiot Sep 30 '14 at 06:47
I ran `cscript mother.vbs` in console, which in turn runs `cscript child.vbs`, this `child.vbs` opens a new cmd. A new thing here is that `child.vbs` expects user-input. – coding_idiot Sep 30 '14 at 08:57
Ask a new question (perhaps referencing to this answer); publish (the important parts of) your child.vbs. – Ekkehard.Horner Sep 30 '14 at 10:18

Show output from child scripts in the parent console window

1 Answers1

Linked