3

I'm trying to create a batch file that will change some input text and change them into their number counterparts of a=1,b=2,c=3 etc for example:

@echo off

set /p text=

echo :: %text% ::
echo Is this the expected text? //user can manually typo check
pause
cls

for /f delims=: %%i in ("%text%") do ( 
[something that changes the letters into numbers & store in variable]
)

::do stuff to numbers
Kara
  • 6,115
  • 16
  • 50
  • 57
user2483876
  • 129
  • 3
  • 13

2 Answers2

4

this can be done with cmd script language's associative arrays:

@ECHO OFF &SETLOCAL ENABLEDELAYEDEXPANSION
SET "text=This is my zero text example"
SET "alfa=0abcdefghijklmnopqrstuvwxyz"
FOR /l %%x IN (1,1,26) DO SET "$!alfa:~%%x,1!=%%x"
SET /a count=0
:loop
SET "char=!text:~%count%,1!"
SET "code=!$%char%!
SET /a count+=1
IF DEFINED char SET "line=!line!%code% "&GOTO :loop
ECHO %text%
ECHO %line%

Output:

This is my zero text example
20 8 9 19  9 19  13 25  26 5 18 15  20 5 24 20  5 24 1 13 16 12 5
Endoro
  • 37,015
  • 8
  • 50
  • 63
2

Here is significantly more efficient method to get Endoro's result. It will encode any length text in only 26 iterations.

@echo off
setlocal enableDelayedExpansion
set "text=This is my zero text example"
set "code=!text!"
set "chars=0abcdefghijklmnopqrstuvwxyz"
for /l %%N in (1 1 26) do for /f %%C in ("!chars:~%%N,1!") do set "code=!code:%%C=%%N !"
echo !text!
echo !code!

But please note that both solutions fail to distinguish between upper and lower case. In addition, my simple substitution algorithm would be difficult to extend to support numeric characters in the input.

Way back when I wrote a library of batch string processing routines called CHARLIB.BAT. One of the routines efficiently converts a character into its ASCII code. Development of the library is documented at new functions: :chr, :asc, :asciiMap . The final code can be downloaded from https://sites.google.com/site/dbenhamfiles.

I have also developed a library of batch macros that is even more efficient at dealing with ASCII codes: Batch macros to convert between ASCII code and character. Batch macros are a specialized technique to pass arguments to batch code that is stored in environment variables. It totally avoids the relatively slow process of the CALL command. A group of us developed the technique at DosTips.

dbenham
  • 127,446
  • 28
  • 251
  • 390