CMD script: Reading and saving the last word of each line (multiple lines)

Question

My question is about finding and saving the last word of each line.

I have multiple lines. This information is saved in a .txt file. Thus, I am required to build a CMD script that can scan through the txt file, find the last word of each line and save it to a new .txt document. The delimiters here will be the space.

For example:

It's a very small window<34>.
The small birds were singing softly.
There are three small rooms up stairs (4)
The house has but two small second story bedrooms.

The result I would like to see saved in a separate txt document needs to look like the following:

window<34>.
softly.
(4)
bedrooms.

I have tried many options and methods but unfortunately no luck.

*"I have tried many options [...]"* -- would you mind showing us?? — aschipfl, Jan 25 '17 at 17:27

score 2 · Answer 1 · answered Jan 25 '17 at 15:41

2

Give this a try. It uses a neat trick with the SET command. You can get a high level overview of this technique at dostips.com.

@echo off & setlocal enableextensions disabledelayedexpansion

FOR /F "delims=" %%G IN (test.txt) DO CALL :lasttoken "%%~G"
GOTO :EOF

:lasttoken
set "x=%~1"
set "x1=%x: =" & set "x2=%"
setlocal enabledelayedexpansion
>>newtest.txt echo !x2!
endlocal
goto :eof

answered Jan 25 '17 at 15:41

Squashman

13,649
5
27
36

Cool technique, but it can fail if string contains `"` and poison characters. – dbenham Jan 26 '17 at 03:41
@dbenham, yes. Not sure how to avoid all possible poison characters with a pure batch solution. Used delayed expansion just to get around the redirection symbols. – Squashman Jan 26 '17 at 04:30
Squashman, Thank you so much for your help. The solution works exactly as described. – Efstathios Efrintidis Jan 26 '17 at 05:06
Check out [my answer](http://stackoverflow.com/a/41867410/1012053) for a robust pure batch solution. – dbenham Jan 26 '17 at 05:27

score 2 · Answer 2 · edited May 23 '17 at 12:08

2

This pure Batch method correctly process all characters, but it is limited in the number of words per line (26 in this version), although such a limit may be increased via the usual tricks.

@echo off
setlocal DisableDelayedExpansion

for /F tokens^=1-26^ eol^= %%a in (input.txt) do (
   set "last="
   for %%T in (z y x w v u t s r q p o n m l k j i h g f e d c b a) do (
      if not defined last call :sub %%T
   )
)
goto :EOF

:sub token
for %%? in (-) do (
   set "last=%%%1"
   if defined last echo %%%1
)
exit /B

edited May 23 '17 at 12:08

Community

1
1

answered Feb 04 '17 at 17:21

Aacini

65,180
12
72
108

+1, Interesting and clever technique, but slow due to the excessive use of CALL. Your FOR /F options can be simplified to `"eol= tokens=1-26"`. – dbenham Feb 04 '17 at 18:12

score 1 · Answer 3 · edited May 23 '17 at 12:08

Squashman's answer can fail if the file contains quotes and poison characters.

It is possible to write a pure batch solution that reliably does the job, regardless of content.

@echo off
setlocal disableDelayedExpansion
>"output.txt" (
  for /f usebackq^ delims^=^ eol^= %%A in ("input.txt") do (
    set "s=%%A"
    setlocal enableDelayedExpansion
    set "s=!s:@=@a!"
    set "s=!s:\=@b!"
    set "s=!s:/=@f!"
    set "s=!s:.=@d!"
    set "s=!s: =.!"
    for /f "delims=" %%A in (".!s!") do (
      endlocal
      set "s=%%~xA"
      setlocal enableDelayedExpansion
      if defined s (
        set "s=!s:.= !"
        set "s=!s:@d=.!"
        set "s=!s:@f=/!"
        set "s=!s:@b=\!"
        set "s=!s:@a=@!"
        echo(!s:~1!
      )
      endlocal
    )
  )
)

But I would never use a pure batch solution. Instead I would use JREPL.BAT - a hybrid batch/Jscript utility that efficiently performs regular expression search and replace on text. It isn't pure batch, but it is pure script that runs natively on any Windows machine from XP onward - no 3rd party .exe file required.

call jrepl "(\S+)\s*$" "$txt=$1" /jmatchq /f input.txt /o output.txt

One nice thing about both solutions is that they give the correct result even if there are spaces after the last "word". And they don't print anything if the line does not contain any "word"

EDIT - Fixed a bonehead mistake in the JREPL solution. – dbenham Jan 26 '17 at 13:45 — dbenham, Jan 26 '17 at 13:45

CMD script: Reading and saving the last word of each line (multiple lines)

3 Answers3

Linked