Extract details from dir output in Windows XP using for loop (batch script)

Question

I am trying to understand the for loop in batch scripting; in particular with skip and tokens parameters. I have found a great example in this answer followed by this nice read.

I would like to see how I can extract the date and time from a dir in Windows XP which has a slightly different dir output (see below example outputs) compared to Windows 7. In other words, how to extract creation date of a specific folder in Windows XP.

The following modified code from the above mentioned links correctly extracts the date and time of a DIR in Windows 7 but fails (i.e. extracts other characters) in Windows XP:

SETLOCAL ENABLEDELAYEDEXPANSION
set "path_of_folder=C:\folderA\folderB"

for /f "skip=5 tokens=1,2,4 delims= " %%a in (
 'dir /ad /tc "%path_of_folder%\."') do IF "%%c"=="." (
  set "dt=%%a"
  set dirdate=%%a
  set dirtime=%%b
  echo !dirdate!, !dirtime!
  set dirday=!dirdate:~0,2!
  echo !dirday!
)

In Windows 7 the dir command in the command prompt outputs something similar to:

   Directory of C:\Windows    
12/21/2016  12:56    <DIR>          . 
12/21/2016  12:56    <DIR>          .. 
09/18/2017  07.42            678    config

In Windows XP the dir command in the command prompt outputs something similar to:

   Directory of C:\WINDOWS

12/21/2016  12:56 PM    <DIR>          . 
12/21/2016  12:56 PM    <DIR>          .. 
09/18/2017  07.42 PM            678    config

The only difference (as far as I can notice) is the PM column(?) which does not exist in Windows 7 but does exist in Windows XP.

I know this is probably a trivial question but I am new in batch scripting and seeing a specific example using a complex for loop would help my understanding. Assume use of delayed expansion.

Answer 1

The different OS is not your problem, unfortunately the output of the DIR command is not consistent, it can differ between users. The simplest fix is to use an alternative method of retrieving the data you wish to capture, npocmaka's answer uses JScript and the following answer uses another built-in tool, WMIC.exe.

@Echo Off

Set "_dp=C:\folderA\folderB"

Echo  Directory of %_dp% & Echo(
For %%A In ("%_dp%\*") Do (Set "_pf=%%~fA"
    SetLocal EnableDelayedExpansion
    For /F "UseBackQ Skip=1 Delims=" %%B In (`WMIC DataFile Where^
        "Drive='%%~dA' And Name='!_pf:\=\\!'" Get CreationDate^,FileSize`
    ) Do For /F "Tokens=1-2*" %%C In ("%%~B") Do (Set "_dt=%%~nxC"
        Set "_d=!_dt:~4,2!/!_dt:~6,2!/!_dt:~,4!"
        Set "_t=!_dt:~8,2!:!_dt:~10,2!" & Echo !_d! !_t!    %%D "%%~nxA")
        EndLocal)
Pause

---

Edit

It seems, you were looking for data from a directory. (I was mistaken in believing you meant the dir command).

Here is some updated code to reflect that fully:

@Echo Off

Set "_dp=C:\folderA\folderB"

Echo  Directory of %_dp% & Echo(
For /D %%A In ("%_dp%\*") Do (Set "_pf=%%~fA"
    SetLocal EnableDelayedExpansion
    For /F "Skip=1 Delims=" %%B In ('
        "WMIC FSDir Where (Drive='%%~dA' And Name='!_pf:\=\\!') Get CreationDate"
    ') Do For /F %%C In ("%%~B") Do (Set "_dt=%%~nxC"
        Set "_d=!_dt:~4,2!/!_dt:~6,2!/!_dt:~,4!"
        Set "_t=!_dt:~8,2!:!_dt:~10,2!" & Echo !_d! !_t!    "%%~nxA")
        EndLocal)
Pause

---

From memory, the very first time you run WMIC in XP there may be an initialisation delay

The output layout can be manipulated, as I have done…

Answer 2

The dir command time format is dependent on the settings in the control panel. To get the directory creation time independent from the control panel settings you can use dirtimejs.bat:

@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
set "path_of_folder=C:\folderA\folderB"

for /f "tokens=1* delims=:" %%a in ('dirtimejs.bat "%path_of_folder%" ^| find "Created :"') do (
    for /f "tokens=1,2,3,4,5,6 delims=:- " %%A in ("%%b") do (
        echo dir year: %%A
        echo dir month : %%B
        echo dir day :  %%C 
    )
)

To see what information dirtimejs try with dirtimejs.bat "%path_of_folder%".

Answer 3

Time formats provided in windows listings depend on user-settings. Unfortunately, you've posted doctored listings, not actual data (evidence - exactly the same time and date for each of the data elements listed, bar the PM flag, despite their being allegedly on different systems)

fix : Easy way is to align the systems' UI settings - use the same format on both machines.

code to cope:

@ECHO Off
SETLOCAL ENABLEDELAYEDEXPANSION

SET "required_format=12"

for /f "tokens=1-5 delims= " %%a in (
 'type q44964366.txt^|FINDSTR /L /E /c:" ."') do (
 set "dt=%%a"
 set dirdate=%%a
 set dirtime=%%b
 IF "%%e"=="." (
  REM reading 12-hr format - convert to 24-hr
  IF "!dirtime:~0,2!"=="12" (
   IF /i "%%c"=="PM" (
    SET "dirtime=12!dirtime:~2!"
   ) else (
    SET "dirtime=00!dirtime:~2!"
   )
  ) ELSE (
   IF /i "%%c"=="PM" (
    SET /a $=2!dirtime:~0,2!-88
    SET "dirtime=!$:~-2!!dirtime:~2!"
   )
  )
 ) 
 REM else is in 24-hr format already
 IF %required_format%==12 (
  SET /a $=1!dirtime:~0,2!
  IF !$!==100 SET "dirtime=12!dirtime:~2! AM"
  IF !$! gtr 100 IF !$! leq 111 SET "dirtime=!dirtime! AM"
  IF !$!==112 SET "dirtime=12!dirtime:~2! PM"
  IF !$! gtr 112 SET /a $=$-12&SET "dirtime=!$:~-2!!dirtime:~2! PM"
 )
 echo !dirdate!, !dirtime!
 set dirday=!dirdate:~0,2!
 echo !dirday!
)

GOTO :EOF

For testing, I used a file containing typical dir lines. You would need to substitute the dir command from the original for the type q44964366.txt

The caret (^) before the pipe (|) tells cmd that the pipe is part of the command to be executed. The pipe outputs the data (from the dir command) and filds all those lines which /L Literally /E end /c:"string" with the constant string - note that this is Space. which neatly filters out all but the . directoryname, so proceeding with the analysis of the processing on the . name - which is the only name the findstr will allow through...

Since we now are using tokens=1-5 then %%e can only be set to . if the line is in 12-hr format, else it's in 24-hr format. To convert to 24-hr format, we need to see whether %%c is PM (else it's AM) and if so, add 12 to the hours digits except for 12 in the hours digits, when we need to set the hours digits to 00 for AM and 12 for PM.

The last of these conversions is obvious, but for non-12:xx PM, we take the two hours digits and append them to 2 making a string 2hh. cmd mathematics treats any numeric starting 0 as octal, so 09:xx would create an error. 209 it can cope with as it's decimal. From that, subtract 88, which is 100-12. This produces a 3-digit number which batch treats as a string, and we need the last 2 of the characters.

You don't specify your preferred format, so we may need to conver to 12-hr (in the code, if that has been chosen in required_format)

In 12-hr mode, we need to subtract 12 hours if the time is PM, and take care of the special values 12:xx and 00:xx. This is again done by stringing the first 2 digits of the time with a constant to form a nice 3-digit decimal value. 100 means 12:xx AM 112 means 12:xx PM 101-111 means we simply need to add AM and if it's greater than 112 (eg 15:xx in 24-hour format) then we need to subtract 12 and take the last 2 characters of the result as the hours digits; then add PM.

And done.

---

type q44964366.txt replaced by the dir command from the original

'dir /ad /tc "%path_of_folder%."^|FINDSTR /L /E /c:" ."') do (