3

I am looking to make a nice demo of the problem I mentioned in Integration in Mathematica but it is very slow yet and the Manipulate is not smooth at all.

Considering the below, is there means by which I could improve the situation. That is see a more continuous dynamic. Also I can't get to have the Manipulator open using

Control->Manipulator[Appearance->Open]

arrows = ParallelTable[{
RandomVariate[NormalDistribution[0, Sqrt[1]]],
RandomVariate[NormalDistribution[0, Sqrt[1]]]}, {20000}];

Manipulate[
           Graphics[{
                     White, Rectangle[{-5, -5}, {5, 5}],
                     Red, Disk[{0, 0}, 1],
                     Black, Point /@ (arrows[[;; i]]), 
                     Text[Style[
                               Total[
                                     If[# < 1, 1, 0] & /@  
                       (EuclideanDistance[{0, 0}, #] & /@ 
                       arrows[[;; i]])]/Length@arrows[[;; i]] // N, 
                          Bold, 18, "Helvetica"], {-4.5, 4.5}]}, 
           ImageSize -> 800],
{i, Range[2, 20000, 1]},
ControlType -> Manipulator,
SaveDefinitions -> True]

enter image description here

Community
  • 1
  • 1
500
  • 6,509
  • 8
  • 46
  • 80
  • 1
    You need `{i, Range[2, 20000, 1], ControlType -> Manipulator, Appearance -> {"Open", "Labeled"}}` to get the `Manipulator` in open and labeled state – kglr Dec 20 '11 at 16:47

3 Answers3

8

The primary reason for the slowness is because you're calculating the EuclideanDistance of all the points till step i for every step i. You'll see a difference if you take this step out of the Manipulate.

prob = MapIndexed[#1/#2 &, Accumulate[
    EuclideanDistance[{0, 0}, #] < 1 & /@ arrows // Boole]] ~ N ~ 4;

Heike's solution is much smoother than yours or Nasser's so I'll use that as an example. You'd use the pre-calculated value of prob in it as:

Manipulate[
 Graphics[{White, Rectangle[{-5, -5}, {5, 5}], Red, Disk[{0, 0}, 1], 
   Black, Point[arrows[[;; i]]], 
   Text[Style[First@prob[[i]], Bold, 18, "Helvetica"], {-4.5, 4.5}]}, 
  ImageSize -> 200], {i, Range[2, 20000, 1]}, 
 ControlType -> Manipulator, SaveDefinitions -> True]

I've set the precision uniformly to 4 digits, because otherwise, you'll see the figure jump around when the number of significant digits changes.

abcd
  • 41,765
  • 7
  • 81
  • 98
  • Yes, your solution is smoother. I really did not even look at what the algorithm does. I just added SynchronousUpdating -> False, and added a Dynamic before the 'If' which also made little faster. As for what the code actually does, I did not look :) – Nasser Dec 20 '11 at 16:22
  • +1 for infix use that isn't a joke. :-) By the way, I favor the typesetting `a ~N~ b` over `a ~ N ~ b` as it is clear which term the function is. This is helpful if you start stringing infix. – Mr.Wizard Dec 20 '11 at 16:37
  • @Mr.Wizard Thanks, that certainly is a good tip! I have confused myself at times with even spacing when stringing them. – abcd Dec 20 '11 at 16:40
5

Maybe something like this

Manipulate[
 Graphics[{White, Rectangle[{-5, -5}, {5, 5}],
   Red, Disk[{0, 0}, 1],
   Black, Point[arrows[[;; i]]], 
   Text[Style[Count[arrows[[;; i]], a_ /; (Norm[a] < 1)]/i // N, Bold,
      18, "Helvetica"], {-4.5, 4.5}]}, ImageSize -> 800], {i, 
  Range[2, 20000, 1]}, ControlType -> Manipulator, 
 SaveDefinitions -> True]
Heike
  • 24,102
  • 2
  • 31
  • 45
  • 1
    Really fast and responsive - +1. You can improve the responsiveness somewhat further by using `Total[UnitStep[1 - #]& @Sqrt@Total[Transpose[arrows[[;; i]]^2]]]/i // N` for the counting, although that will be only a small addition to the speedup your code gives. – Leonid Shifrin Dec 20 '11 at 16:33
2

See if this is any better for you:

Manipulate[

 Graphics[{
   White,
   Rectangle[{-5, -5}, {5, 5}],
   Red,
   Disk[{0, 0}, 1],
   Black, Point /@ (arrows[[;; i]]), 
   Text[Style[
     Dynamic@Total[
         If[# < 1, 1, 0] & /@ (EuclideanDistance[{0, 0}, #] & /@ 
            arrows[[;; i]])]/Length@arrows[[;; i]] // N, Bold, 18, 
     "Helvetica"], {-4.5, 4.5}]}, ImageSize -> 200],

 {{i, 2, "i"}, 2, 20000, 1, Appearance -> "Labeled"},
 TrackedSymbols :> {i},
 SynchronousUpdating -> False,
 AppearanceElements -> All,


 Initialization :>
  (
   arrows = 
     ParallelTable[{RandomVariate[NormalDistribution[0, Sqrt[1]]], 
       RandomVariate[NormalDistribution[0, Sqrt[1]]]}, {20000}];
   )

 ]
Nasser
  • 12,849
  • 6
  • 52
  • 104
  • Seems to be better ! Thank You. But the Text is off. I tis suppose to converge to .39 rapidly. Also could dyou explain why it is better :-) ? – 500 Dec 20 '11 at 15:43
  • @500, which text is off? I did not touch the text stuff. see the diffs between this version and your version and you can see the changes that made it faster. – Nasser Dec 20 '11 at 15:49