Duplicate Element x number of times with XSLT

Question

I have a strange transformation that I'm trying to do.

XML looks like this:

<?xml version="1.0" standalone="yes"?>
<Parent>
    <RecordCount>4</RecordCount>
    <Record name="1">
        <Child1>Value 1</Child1>
        <Child2>Value 2</Child2>
    </Record>
</Parent>

And this is what it needs to look like:

<?xml version="1.0" standalone="yes"?>
<Parent>
    <RecordCount>4</RecordCount>
    <Record name="1">
        <Child1>Value 1</Child1>
        <Child2>Value 2</Child2>
    </Record>
    <Record name="2">
        <Child1>Value 1</Child1>
        <Child2>Value 2</Child2>
    </Record>
    <Record name="3">
        <Child1>Value 1</Child1>
        <Child2>Value 2</Child2>
    </Record>
    <Record name="4">
        <Child1>Value 1</Child1>
        <Child2>Value 2</Child2>
    </Record>
</Parent>

Is something like this even possible with XSLT or should I rather just handle this in code?

See here for how to iterate from 1 to N: http://stackoverflow.com/questions/8701011/for-loop-in-xslt-page/8703214#8703214 — LarsH, Jul 08 '13 at 18:55

score 1 · Answer 1 · answered Jul 08 '13 at 19:27

Try following xlst

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

    <xsl:template match="/Parent">
        <Parent>
            <xsl:variable name="count" select="RecordCount" />
            <xsl:call-template name="multiply">
                <xsl:with-param name="maxCount" select="$count" />
                <xsl:with-param name="nodeToCopy" select="Record" />
            </xsl:call-template>
        </Parent>
    </xsl:template>

    <xsl:template name="multiply">
        <xsl:param name="maxCount" />
        <xsl:param name="i" select="1" />
        <xsl:param name="nodeToCopy" />

        <xsl:choose>
            <xsl:when test="$i &lt;= $maxCount">
                <xsl:element name="{name($nodeToCopy)}">
                    <xsl:attribute name="name">
                        <xsl:value-of select="$i" />
                    </xsl:attribute>
                    <xsl:copy-of select="$nodeToCopy/child::*" />
                </xsl:element>

                <xsl:call-template name="multiply">
                    <xsl:with-param name="maxCount" select="$maxCount" />
                    <xsl:with-param name="nodeToCopy" select="$nodeToCopy" />
                    <xsl:with-param name="i" select="$i+1" />
                </xsl:call-template>
            </xsl:when>
            <xsl:otherwise />
        </xsl:choose>

    </xsl:template>
</xsl:stylesheet>

It is based on recursive calling of named template with increasing of "iterating" value. If would be something unclear just write a comment.

Thanks. I didn't believe this would be possible with XSLT 2.0, didn't even dream of trying it in 1.0. — Tone, Jul 09 '13 at 07:36

score 1 · Accepted Answer · answered Jul 08 '13 at 20:26

Here's another way using XSLT 2.0...

XML Input

<Parent>
    <RecordCount>4</RecordCount>
    <Record name="1">
        <Child1>Value 1</Child1>
        <Child2>Value 2</Child2>
    </Record>
</Parent>

XSLT 2.0

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="RecordCount">
        <xsl:variable name="record" select="../Record"/>
        <xsl:copy-of select="."/>
        <xsl:for-each select="1 to .">
            <xsl:apply-templates select="$record" mode="replicate">
                <xsl:with-param name="cnt" select="."/>
            </xsl:apply-templates>
        </xsl:for-each>
    </xsl:template>

    <xsl:template match="Record" mode="replicate">
        <xsl:param name="cnt"/>
        <Record name="{$cnt}">
            <xsl:apply-templates select="@* except @name|node()"/>
        </Record>
    </xsl:template>

    <xsl:template match="Record"/>

</xsl:stylesheet>

Output

<Parent>
   <RecordCount>4</RecordCount>
   <Record name="1">
      <Child1>Value 1</Child1>
      <Child2>Value 2</Child2>
   </Record>
   <Record name="2">
      <Child1>Value 1</Child1>
      <Child2>Value 2</Child2>
   </Record>
   <Record name="3">
      <Child1>Value 1</Child1>
      <Child2>Value 2</Child2>
   </Record>
   <Record name="4">
      <Child1>Value 1</Child1>
      <Child2>Value 2</Child2>
   </Record>
</Parent>

This is fantastic I really didn't believe it was possible. Thank you. — Tone, Jul 09 '13 at 07:32

Duplicate Element x number of times with XSLT

2 Answers2

Linked