How to set the global variable in a function for cmake?

Question

I'm writing a CMakeLists.txt to generate files and compile the generated files. I create a function to add some file path strings to a global list variable.

My CMakeLists.txt:

set(source_list "nothing")
function(test file_path)
    list(APPEND source_list ${file_path})
endfunction(test)
test(abc.txt)
test(def.txt)
message("At last, the source_list is:\"${source_list}\"")

The cmake output:

At last, the source_list is:"nothing"

Someone suggested that to use macro instead of function, but I do need use local variable, so I need to use the function instead of macro.

How can I correctly set the global variable source_list in the function test()? Can't cmake do it in a simple and normal way?

Ding-Yi Chen · Answer 1 · 2016-06-14T05:37:29.957

43

PARENT_SCOPE is only for parent, it won't work if you have other non-parent script that want to see it as well.

You need cache for the true "global-like" variable. In your case, use:

SET(source_list  "${source_list}" CACHE INTERNAL "source_list")

edited Jun 14 '16 at 05:37

answered Aug 05 '14 at 03:05

Ding-Yi Chen

2,830
33
27

4

It doesn't work for second run of cmake, because value is already in cache. You must clean before build. – Maxim Suslov Feb 25 '16 at 07:23
2

`INTERNAL` implied `FORCE`, which means: Use the ``FORCE`` option to overwrite existing entries. – Ding-Yi Chen Feb 25 '16 at 22:49

score 24 · Answer 2 · answered Sep 25 '17 at 19:54

Another approach is to use global properties. Once you set it:

set_property(GLOBAL PROPERTY source_list_property "${source_list}")

you can read it from everywhere:

get_property(source_list GLOBAL PROPERTY source_list_property)

I used in examples above the different names for property (source_list_property) and for variable (source_list). Maybe it is better to use the same name. But point is to use a property as global variables, and not about naming.

Such global properties aren't in cache.

score 23 · Accepted Answer · edited Oct 01 '18 at 11:00

23

You need to use set instead of list to affect the variable in the parent scope.

So replace your list command with:

set(source_list ${source_list} ${file_path} PARENT_SCOPE)

edited Oct 01 '18 at 11:00

Tsyvarev

60,011
17
110
153

answered Apr 05 '12 at 16:25

Fraser

74,704
20
238
215

6

It's not global though, siblings will not see. – 0xbaadf00d Apr 04 '17 at 06:32
@JoachimW: Why incorporate two answers into the single one? You seems to misunderstand Question/Answer model on Stack Overflow. We do NOT tend to have **all solutions** in the **single accepted answer**. Instead, having **one answer per solution** is perfect. And an answer's quality is primarily measured by the **voting**, good answers needn't to be marked with the green accept mark. Please, revert this answers merging. – Tsyvarev Oct 01 '18 at 10:37

score 11 · Answer 4 · answered Nov 29 '17 at 10:30

Building upon Maxim Suslov's answer, the following code worked for a similar problem I faced:

set_property(GLOBAL PROPERTY source_list)
function(add_source)
    get_property(tmp GLOBAL PROPERTY source_list)
    foreach(arg ${ARGV})
        set(tmp "${tmp} ${arg}")
    endforeach()
    set_property(GLOBAL PROPERTY source_list "${tmp}")
endfunction(add_source)

add_source(a_file)
add_source(b_file c_file)

get_property(local_prop GLOBAL PROPERTY source_list)
message("list: ${local_prop}")

Function add_source can be called from inside any sub-directory.

score 4 · Answer 5 · answered Feb 18 '20 at 08:22

4

Another way to address this issue is using macro instead of function - this way all variables inside macro will be evaluated in context of caller.

answered Feb 18 '20 at 08:22

Andrey Starodubtsev

5,139
3
32
46

Role · Answer 6 · 2022-11-17T08:41:46.060

1

You can also work with environment variables.

  SET(ENV{SOURCE_LIST} "$ENV{SOURCE_LIST} newSource")

Test:

  message(STATUS "GLOBAL: $ENV{SOURCE_LIST}")
  -- GLOBAL: newSource /unittest/demo1 /unittest/demo2

edited Nov 17 '22 at 08:41

answered Nov 17 '22 at 08:33

Role

86
4

How to set the global variable in a function for cmake?

6 Answers6

Linked

Related