Valid filename check. What is the best way?

Question

See subject of positing for question.

1) I recall seeing a really cool option in VB.NET using LINQ to match using "LIKE%'

2) I know regular expressions will work and I suspect that will result in the shortest code and probably won't be too hard to read for such a simple test.

Here's what I did. Warning: You're gonna hate it.

Private Shared Function FileNameIsOk(ByVal fileName As String) As Boolean

    For Position As Integer = 0 To fileName.Length - 1

        Dim Character As String = fileName.Substring(Position, 1).ToUpper
        Dim AsciiCharacter As Integer = Asc(Character)

        Select Case True

            Case Character = "_" 'allow _
            Case Character = "." 'allow .
            Case AsciiCharacter >= Asc("A") And AsciiCharacter <= Asc("A") 'Allow alphas
            Case AsciiCharacter >= Asc("0") AndAlso AsciiCharacter <= Asc("9") 'allow digits

            Case Else 'otherwise, invalid character
                Return False

        End Select

    Next

    Return True

End Function

Joel Coehoorn · Accepted Answer · 2020-05-26T00:12:28.433

15

Old now, but I saw this and just had to add a new answer. The current accepted and other answers are way more complicated than needed. In fact, it can be reduced to a single line:

Public Shared Function FilenameIsOK(ByVal fileName as String) as Boolean
    Return Not (Path.GetFileName(fileName).Intersect(Path.GetInvalidFileNameChars()).Any() OrElse Path.GetDirectoryName(fileName).Intersect(Path.GetInvalidPathChars()).Any()) 
End Function

Though I wouldn't recommend writing it that way. Break it up just a little bit to improve readability:

Public Shared Function FilenameIsOK(ByVal fileName as String) as Boolean
    Dim file As String = Path.GetFileName(fileName)
    Dim directory As String = Path.GetDirectoryName(fileName)

    Return Not (file.Intersect(Path.GetInvalidFileNameChars()).Any() _
                OrElse _ 
                directory.Intersect(Path.GetInvalidPathChars()).Any()) 
End Function

One other point here, is often the best way to deal with file system issues is to let the file system tell you: try to open or create the file in question, and deal with the exception. This works especially well, because you'll likely have to do this anyway. Any other validation you do here is duplicated effort for work you'll still have to put into an exception handler.

edited May 26 '20 at 00:12

answered Dec 30 '13 at 07:10

Joel Coehoorn

399,467
113
570
794

1

Never to late to improve. Thanks. – Chad Jan 17 '14 at 21:48
2

If I might, the purpose of this function is to test valid characters in filename. But if it contains invalid characters, it will crash on first line : Path.GetFileName(fileName) – David Sep 16 '16 at 14:36
*"The array returned from this method is not guaranteed to contain the complete set of characters that are invalid in file and directory names. The full set of invalid characters can vary by file system. For example, on Windows-based desktop platforms, invalid path characters might include ASCII/Unicode characters 1 through 31, as well as quote ("), less than (<), greater than (>), pipe (|), backspace (\b), null (\0) and tab (\t)."* https://msdn.microsoft.com/en-us/library/system.io.path.getinvalidfilenamechars(v=vs.110).aspx – mbomb007 Nov 15 '17 at 15:39
@mbomb007 Hence the last paragraph. – Joel Coehoorn Nov 15 '17 at 15:43
@JoelCoehoorn I just thought I'd site a source for it, especially since this is the documentation for the function shown. – mbomb007 Nov 15 '17 at 16:20
It's not duplicated effort when your intent is to avoid creating a security vulnerability by passing unsanitized inputs to vulnerable methods. If you are passing a filename string to an external function the exception you are trying to "deal with" could be malicious arbitrary code execution. https://msdn.microsoft.com/en-us/library/8cd7yaws(v=vs.100).aspx – HackSlash Jul 13 '18 at 15:56
The function could be stuck due to exceptions. Thus, it is required to be enclosed in the Try Catch block. If any failure occurs, then just return False. – klados Aug 17 '18 at 09:43

score 10 · Answer 2 · answered Jun 18 '09 at 18:20

10

How about Path.GetInvalidFileNameChars and Path.GetInvalidPathChars?

Public Shared Function FilenameIsOK(ByVal fileNameAndPath as String) as Boolean
    Dim fileName = Path.GetFileName(fileNameAndPath)
    Dim directory = Path.GetDirectoryName(fileNameAndPath)
    For each c in Path.GetInvalidFileNameChars()
        If fileName.Contains(c) Then
            Return False
        End If
    Next
    For each c in Path.GetInvalidPathChars()
        If directory.Contains(c) Then
            Return False
        End If
    Next
    Return True
End Function

answered Jun 18 '09 at 18:20

Bob King

25,372
6
54
66

how can this possibly work? Because if the filename already has invalid characters in it, then attempting to get the Filename (line 1) is going to exception, because GetFilename calls CheckInvalidPathChars and therefore throws the exception – Paul Farry Sep 13 '10 at 02:18
1

I know this is an old question but the comment by Paul Farry above made me doubt the solution given, so I'd like to correct it in case anyone else has the same doubts. If you look at the definition for CheckInvalidPathChars it really only looks for 5 possible invalid characters while GetInvalidFileNameChars() returns a significantly longer list of invalid characters. So the method above is definitely going to catch all the issues while relying on Path.GetFilename to call CheckInvalidPathChars is not. – Paul Sainsbury Apr 28 '11 at 10:45
Does not work with files that have Cantonese characters in name. I should probably start a new thread with a specific separate question; was hoping this would work. – chaltahai Oct 22 '13 at 19:50

score 2 · Answer 3 · answered Jun 18 '09 at 18:14

2

It is a regex and C# but:

using System;
using System.Text.RegularExpressions;

/// <summary>
/// Gets whether the specified path is a valid absolute file path.
/// </summary>
/// <param name="path">Any path. OK if null or empty.</param>
static public bool IsValidPath( string path )
{
    Regex r = new Regex( @"^(([a-zA-Z]\:)|(\\))(\\{1}|((\\{1})[^\\]([^/:*?<>""|]*))+)$" );
    return r.IsMatch( path );
}

answered Jun 18 '09 at 18:14

TWA

12,756
13
56
92

Is this OS independent? I'd be cautious just if the app ever gets run under Mono. – Bob King Jun 22 '09 at 13:46
1

+1 for being a two lines solutions, -1 for being English compatible only... :) – Hertzel Guinness Dec 01 '10 at 14:47

score 2 · Answer 4 · answered Nov 22 '17 at 05:15

2

I cannot take credit for this one (well two) liner. I found it whilst googling-cant remember where I found it.

    Dim newFileName As String = "*Not<A>Good:Name|For/\File?"
    newFileName = String.Join("-", fileName.Split(IO.Path.GetInvalidFileNameChars))

answered Nov 22 '17 at 05:15

Kon

21
1

simple and easy ! I got this into a function that returns the fixed file name directly. – Youssef Apr 09 '18 at 22:44

score 1 · Answer 5 · answered Jun 18 '09 at 18:09

1

Frankly, I'd just use the FileInfo object built in to .NET, and check for an exception for invalidity. See this reference for details.

answered Jun 18 '09 at 18:09

Paul Sonier

38,903
3
77
117

The code might be trying to validate a path that it doesn't have access to though. – patjbs Jun 18 '09 at 18:11
3

Using exceptions to handle control flow is bad practice! – Bob King Jun 19 '09 at 13:27
1

@BobKing: tell it to microsoft; it'd be great to have a validate() method on their FileInfo, but they've chosen to go with the exception route. – Paul Sonier Jun 19 '09 at 18:05
Use File.Exists or Directory.Exists – Chad Oct 05 '14 at 23:31

score 1 · Answer 6 · answered Oct 03 '14 at 08:29

Based on Joel Coehoorns well written solution, I added some additional functionality for validation.

    ''' <summary>
    ''' Check if fileName is OK
    ''' </summary>
    ''' <param name="fileName">FileName</param>
    ''' <param name="allowPathDefinition">(optional) set true to allow path definitions. If set to false only filenames are allowed</param>
    ''' <param name="firstCharIndex">(optional) return the index of first invalid character</param>
    ''' <returns>true if filename is valid</returns>
    ''' <remarks>
    ''' based on Joel Coehoorn answer in 
    ''' http://stackoverflow.com/questions/1014242/valid-filename-check-what-is-the-best-way
    ''' </remarks>
    Public Shared Function FilenameIsOK(ByVal fileName As String, _
                                        Optional ByVal allowPathDefinition As Boolean = False, _
                                        Optional ByRef firstCharIndex As Integer = Nothing) As Boolean

        Dim file As String = String.Empty
        Dim directory As String = String.Empty

        If allowPathDefinition Then
            file = Path.GetFileName(fileName)
            directory = Path.GetDirectoryName(fileName)
        Else
            file = fileName
        End If

        If Not IsNothing(firstCharIndex) Then
            Dim f As IEnumerable(Of Char)
            f = file.Intersect(Path.GetInvalidFileNameChars())
            If f.Any Then
                firstCharIndex = Len(directory) + file.IndexOf(f.First)
                Return False
            End If

            f = directory.Intersect(Path.GetInvalidPathChars())
            If f.Any Then
                firstCharIndex = directory.IndexOf(f.First)
                Return False
            Else
                Return True
            End If
        Else
            Return Not (file.Intersect(Path.GetInvalidFileNameChars()).Any() _
                        OrElse _
                        directory.Intersect(Path.GetInvalidPathChars()).Any())
        End If

    End Function

score 1 · Answer 7 · answered Sep 13 '10 at 03:32

Even though this is quite old, it's still valid, and I ended up here looking for the solution to how to check the filename for invalid characters. I looked at the accepted answer and found a few holes.

Hopefully these modifications are of some use to someone else.

Public Function FilenameIsOK(ByVal fileNameAndPath As String) As Boolean
    Dim fileName As String = String.Empty
    Dim theDirectory As String = fileNameAndPath

    Dim p As Char = Path.DirectorySeparatorChar

    Dim splitPath() As String
    splitPath = fileNameAndPath.Split(p)
    If splitPath.Length > 1 Then
        fileName = splitPath(splitPath.Length - 1)
        theDirectory = String.Join(p, splitPath, 0, splitPath.Length - 1)
    End If

    For Each c As Char In Path.GetInvalidFileNameChars()
        If fileName.Contains(c) Then
            Return False
        End If
    Next

    For Each c As Char In Path.GetInvalidPathChars()
        If theDirectory.Contains(c) Then
            Return False
        End If
    Next
    Return True
End Function

score 1 · Answer 8 · answered Feb 23 '11 at 17:00

1

try this

Public Function IsValidFileName(ByVal fn As String) As Boolean
    Try
        Dim fi As New IO.FileInfo(fn)
    Catch ex As Exception
        Return False
    End Try
    Return True
End Function

answered Feb 23 '11 at 17:00

Hedi Guizani

21
1

1

You should never plan to use exceptions as part of the normal operation of your application - When passed an invalid filename, this would cause the CLR to generate a full stack trace (amongst other things) [which is expensive](http://stackoverflow.com/a/4648011/156755). – Basic Jan 07 '13 at 10:06
Bad practise or computational expense never stopped Microsoft! – gls123 Jan 11 '13 at 09:45
While I wouldn't write this function this way, I would say this is the best way to ultimately handle the problem: just create the file already, and handle the exception if you have a problem... afer all, you'll have to write the exception handler anyway because of the volatile nature of the file system. – Joel Coehoorn Aug 02 '16 at 17:13

score 0 · Answer 9 · answered Dec 30 '13 at 06:58

Ok. Good ideas. But manual iteration of 'invalid' chars is not the best way, when you work with thousands of files.

Public BadChars() As Char = IO.Path.GetInvalidFileNameChars

For m = 0 To thousands_of_files - 1
    '..
    if currFile.Name.ToCharArray.Intersect(BadChars).Count > 1 Then
         ' the Name is invalid - what u gonna do? =)
    end if
    '..
    '..
Next

score 0 · Answer 10 · edited Dec 30 '21 at 19:47

Try this

Function IsValidFileNameOrPath(ByVal name As String) As Boolean

    Dim i As Integer
    Dim dn, fn As String

    i = InStrRev(name, "\") : dn = Mid(name, 1, i) : fn = Mid(name, i + 1)
    MsgBox("directory = " & dn & " : file = " & fn)

    If name Is Nothing Or Trim(fn) = "" Then
        MsgBox("null filename" & fn)
        Return False
    Else
        For Each badchar As Char In Path.GetInvalidFileNameChars
            If InStr(fn, badchar) > 0 Then
                MsgBox("invalid filename" & fn)
                Return False
            End If
        Next
    End If

    If dn <> "" Then
        If InStr(dn, "\\") > 0 Then
            MsgBox("duplicate \ =  " & dn)
            Return False
        End If
        For Each badChar As Char In Path.GetInvalidPathChars
            If InStr(dn, badChar) > 0 Then
                MsgBox("invalid directory=  " & dn)
                Return False
            End If
        Next
        If Not System.IO.Directory.Exists(dn) Then
            Try
                Directory.CreateDirectory(dn)
                'Directory.Delete(dn)
            Catch
                MsgBox("invalid path =  " & dn)
                Return False
            End Try
        End If
    End If
    Return True
End Function

score 0 · Answer 11 · answered Dec 14 '17 at 11:22

0

Public Function IsValidFileName(nFile As String) As Boolean
    Try
        Dim S As String = Path.GetFileName(nFile)
    Catch
        Return False
    End Try
    Return True
End Function

answered Dec 14 '17 at 11:22

elparadise

1

3

Be more descriptive while posting any answer – Satendra Dec 14 '17 at 11:46

score -1 · Answer 12 · answered May 06 '21 at 13:10

-1

This is a easy way works, even on folders:

    Try
        My.Computer.FileSystem.WriteAllText("aux", "Hello World!", False)
    Catch ex As Exception
        'do nothing or inform the user
    End Try

answered May 06 '21 at 13:10

codiee

31
4

Valid filename check. What is the best way?

12 Answers12

Linked