JuicyPixels texture loading in Haskell OpenGL?

Question

How do I load a texture using Haskell, OpenGL and the JuicyPixels library?

I can get as far as this:

loadImage :: IO ()
loadImage = do image <- readPng "data/Picture.png"
               case image of 
                 (Left s) -> do print s
                                exitWith (ExitFailure 1)
                 (Right d) -> do case (ImageRGBA i) -> do etc...

How do I convert this to a TextureObject? I think I need to do a conversion between a Vector Word8 and PixelData (for OpenGL to recognize)

Note that this is partly what JuicyPixels-Repa was helpful for, but it needs updating for Repa-3.0 (GHC 7.4 or above). — Thomas M. DuBuisson, May 06 '12 at 18:22
Oops. I forgot I had already done some work to update JP-repa for the new repa. Yay. — Thomas M. DuBuisson, May 06 '12 at 18:30

score 8 · Accepted Answer · edited May 26 '14 at 20:37

You use the texImage2D function. You'd invoke it like this:

import Data.Vector.Storable (unsafeWith)

import Graphics.Rendering.OpenGL.GL.Texturing.Specification (texImage2D, Level, Border, TextureSize2D(..))
import Graphics.Rendering.OpenGL.GL.PixelRectangles.ColorTable (Proxy(..), PixelInternalFormat(..))
import Graphics.Rendering.OpenGL.GL.PixelRectangles.Rasterization (PixelData(..))

-- ...

(ImageRGBA8 (Image width height dat)) ->
  -- Access the data vector pointer
  unsafeWith dat $ \ptr ->
    -- Generate the texture
    texImage2D
      -- No cube map
      Nothing
      -- No proxy
      NoProxy
      -- No mipmaps
      0
      -- Internal storage format: use R8G8B8A8 as internal storage
      RGBA8
      -- Size of the image
      (TextureSize2D width height)
      -- No borders
      0
      -- The pixel data: the vector contains Bytes, in RGBA order
      (PixelData RGBA UnsignedByte ptr)

Note that Juicy doesn't always give back an RGBA image. You have to handle each of the different image variations:

ImageY8, ImageYA8, ImageRGB8, ImageRGBA8, ImageYCrCb8

Also, before this command, you have to have bound a texture object to store the texture data in.

import Data.ObjectName (genObjectNames)
import Graphics.Rendering.OpenGL.GL.Texturing.Objects (textureBinding)
import Graphics.Rendering.OpenGL.GL.Texturing.Specification (TextureTarget(..))

-- ...

-- Generate 1 texture object
[texObject] <- genObjectNames 1

-- Make it the "currently bound 2D texture"
textureBinding Texture2D $= Just texObject

BTW, many of those imports are added automatically when you import Graphics.Rendering.OpenGL; you don't have to import each thing individually if you don't want.

Thanks for the help! I think that it should be `UnsignedByte` rather than `Byte`. Other than that this worked. — Mark, May 06 '12 at 15:17
For OpenGL 3.x (haskell package version 3.x, not OpenGL version 3.x) replace first argument of `texImage2D` from `Nothing` to `Texture2D`. — kolen, May 08 '17 at 16:49

JuicyPixels texture loading in Haskell OpenGL?

1 Answers1