How to create subsets of a single set of elements with XSLT?

Question

I have an xml of the form:

<Set>
   <Element name="Superset1_Set1_Element1"/>
   <Element name="Superset1_Set1_Element2"/>
   <Element name="Superset1_Set2_Element1"/>
   <Element name="Superset2_Set1_Element1"/>
   <Element name="Superset2_Set2_Element1"/>
</Set>

I wish to transform it to an xml of the form:

<Superset name="Superset1">
   <Set name="Set1">
       <Element name="Element1"/>
       <Element name="Element2"/>
   </Set>
   <Set name="Set2">
       <Element name="Element1"/>
   </Set>
</Superset>
<Superset name="Superset2">
   <Set name="Set1">
       <Element name="Element1"/>
   </Set>
   <Set name="Set2">
       <Element name="Element1"/>
   </Set>
</Superset>

How can this be done with XSLT?

Thanks a lot in advance!

Answer 1

This can be solved with the following XSLT 1.0 transformation:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:output method="xml" indent="yes" />

  <!-- this key selects elements by their "Superset" name -->
  <xsl:key name="kElementBySuperset" match="Element" use="
    substring-before(@name, '_')" 
  />

  <!-- this key selects elements by their "Superset_Set" name -->
  <xsl:key name="kElementBySet" match="Element" use="
    concat(
      substring-before(@name, '_'), 
      '_',
      substring-before(substring-after(@name, '_'), '_')
    )
  " />

  <!--- initalize output (note the template modes) -->
  <xsl:template match="Set">
    <xsl:apply-templates select="Element" mode="Superset">
      <xsl:sort select="@name" />
    </xsl:apply-templates>
  </xsl:template>

  <!-- output <Superset> elements, grouped by name -->
  <xsl:template match="Element" mode="Superset">
    <xsl:variable name="vSupersetName" select="
      substring-before(@name, '_')
    " />

    <xsl:if test="
      generate-id() 
      = 
      generate-id(key('kElementBySuperset', $vSupersetName)[1])
    ">
      <Superset name="{$vSupersetName}">
        <xsl:apply-templates 
          select="key('kElementBySuperset', $vSupersetName)" 
          mode="Set"
        >
          <xsl:sort select="@name" />
        </xsl:apply-templates>
      </Superset>
    </xsl:if>
  </xsl:template>

  <!-- output <Set> elements, grouped by name -->
  <xsl:template match="Element" mode="Set">
    <xsl:variable name="vSetName" select="
      concat(
        substring-before(@name, '_'), 
        '_',
        substring-before(substring-after(@name, '_'), '_')
      )"
    />

    <xsl:if test="
      generate-id() 
      = 
      generate-id(key('kElementBySet', $vSetName)[1])
    ">
      <Set name="{substring-after($vSetName, '_')}">
        <xsl:apply-templates 
          select="key('kElementBySet', $vSetName)" 
          mode="Element"
        >
          <xsl:sort select="@name" />
        </xsl:apply-templates>
      </Set>
    </xsl:if>
  </xsl:template>

  <!-- output <Element> elements -->
  <xsl:template match="Element" mode="Element">
    <xsl:variable name="vElementName" select="
      substring-after(
        substring-after(@name, '_'), 
        '_'
      )
    " />

    <Element name="{$vElementName}" />
  </xsl:template>

</xsl:stylesheet>

Output on my system when applied to your input document:

<Superset name="Superset1">
  <Set name="Set1">
    <Element name="Element1" />
    <Element name="Element2" />
  </Set>
  <Set name="Set2">
    <Element name="Element1" />
  </Set>
</Superset>
<Superset name="Superset2">
  <Set name="Set1">
    <Element name="Element1" />
  </Set>
  <Set name="Set2">
    <Element name="Element1" />
  </Set>
</Superset>

It is worth noting that this solution is case-sensitive. I assume that is desirable (or at least not harmful) in your case. If case-insensitivity is required, then sprinkling a handful of these would become necessary (where "…" must of course be replaced by the missing letters):

translate($anyvalue, 'ABC…XYZ', 'abc…xyz')

I avoided that because it is very repetitive and makes the solution (even more) obscure.

Further reading: One of my solutions that does a similar two-step grouping using two <xsl:key>s is here:

XSLT 3-level grouping on attributes

It is a bit more verbose on the internals, and it contains a lengthy explanation of <xsl:key> that I'd like to avoid repeating here. ;-)

Answer 2

Preserved for reference, but I strongly suggest the use of templates (i.e. Tomalak's solution) where possible for readability alone...

---

Certainly possible, but actually harder than I anticipated because of the second order sets and the double underscores - the following could certainly be improved if the "name" values were of a friendlier format.

<xsl:key name="supers" match="Set/Element" use="substring-before(@name,'_')"/>
<xsl:key name="sets" match="Set/Element" use="concat(substring-before(@name,'_'),'_',substring-before(substring-after(@name,'_'),'_'))"/>

<xsl:template match="/">
    <xsl:for-each select="Set/Element[generate-id() = generate-id(key('supers',substring-before(@name,'_'))[1])]">      
        <xsl:variable name="super" select="substring-before(@name,'_')"/>
            <Superset name="{$super}">          
            <xsl:for-each select="//Set/Element[generate-id() = generate-id(key('sets',concat($super,'_',substring-before(substring-after(@name,'_'),'_')))[1])]">
            <Set name="{substring-before(substring-after(@name,'_'),'_')}">
                <xsl:variable name="set" select="concat($super,'_',substring-before(substring-after(@name,'_'),'_'))"/>
                <xsl:for-each select="//Set/Element[starts-with(@name,$set)]">
                    <Element name="{substring-after(substring-after(@name,'_'),'_')}"/>
                </xsl:for-each>
            </Set>
            </xsl:for-each>
            </Superset>
    </xsl:for-each>
</xsl:template>

The trick is just muenchian grouping and capturing the right key values.

It's really not pretty, so I'm sure there's a better solution available but I'm jetlagged :P