Batch file to perform start, run, %TEMP% and delete all

Question

looking for a way to perform the following:

Start > Run > "%TEMP% > Delete everything (skipping any conflicts).

so Far I have

@echo off
start %TEMP%
DEL *.*

I suppose I could use CD to get to the folder, the thing I'm wondering is if there are any instances where it cannot delete an a dialog box comes up, I want to skip these.

Thanks for the help! Liam

Joey · Accepted Answer · 2018-03-12T08:11:55.870

32

del won't trigger any dialogs or message boxes. You have a few problems, though:

start will just open Explorer which would be useless. You need cd to change the working directory of your batch file (the /D is there so it also works when run from a different drive):
```
cd /D %temp%
```
You may want to delete directories as well:
```
for /d %%D in (*) do rd /s /q "%%D"
```
You need to skip the question for del and remove read-only files too:
```
del /f /q *
```

so you arrive at:

@echo off
cd /D %temp%
for /d %%D in (*) do rd /s /q "%%D"
del /f /q *

edited Mar 12 '18 at 08:11

answered May 23 '12 at 09:23

Joey

344,408
85
689
683

Thanks mate! Works a charm, can now schedule it weekly with task scheduler! – Liam Coates May 23 '12 at 09:41
Thanks for step by step explanation!! – Paritosh Jun 28 '13 at 06:02
One issue I am facing. "The process cannot access the file because it is being used by another process." when trying for second time. Do we need to kill something? – Satish Patro Nov 04 '20 at 14:01
Why would you need to loop thru all the directories in the batch when RD can do it by itself? @echo off del %temp% /f /s /q >nul rd %TEMP% /S /Q>nul – arana May 05 '23 at 20:01
@arana: Because `RD` will also remove the directory you specified along with anything beneath it. That may be fine in some cases, but typically I avoid this, as re-creating the directory could lead to issues (different ACLs, etc.). – Joey Jun 05 '23 at 06:36

score 10 · Answer 2 · edited May 13 '17 at 10:55

The following batch commands are used to delete all your temp, recent and prefetch files on your System.

Save the following code as "Clear.bat" on your local system

*********START CODE************

@ECHO OFF

del /s /f /q %userprofile%\Recent\*.*

del /s /f /q C:\Windows\Prefetch\*.*

del /s /f /q C:\Windows\Temp\*.*

del /s /f /q %USERPROFILE%\appdata\local\temp\*.*


/Below command to Show the folder after deleted files

Explorer %userprofile%\Recent

Explorer C:\Windows\Prefetch

Explorer C:\Windows\Temp

Explorer %USERPROFILE%\appdata\local\temp


*********END CODE************

score 4 · Answer 3 · answered May 23 '12 at 09:30

4

If you want to remove all the files in the %TEMP% folder you could just do this:

del %TEMP%\*.* /f /s /q

That will remove everything, any file with any extension (*.*) and do the same for all sub-folders (/s), without prompting you for anything (/q), it will just do it, including read only files (/f).

Hope this helps.

answered May 23 '12 at 09:30

Bali C

30,582
35
123
152

1

It won't remove directories, though. – Joey May 23 '12 at 10:21
@Joey True, your answer is better :) – Bali C May 23 '12 at 10:41

Na Nonthasen · Answer 4 · 2017-01-31T05:15:35.437

3

@echo off
RD %TEMP%\. /S /Q

::pause
explorer %temp%

This batch can run from anywhere. RD stands for Remove Directory but this can remove both folders and files which available to delete.

edited Jan 31 '17 at 05:15

answered Jan 31 '17 at 05:02

Na Nonthasen

172
2
4

score 2 · Answer 5 · answered Jan 31 '15 at 23:08

2

cd C:\Users\%username%\AppData\Local rmdir /S /Q Temp

del C:\Windows\Prefetch*.* /Q

del C:\Windows\Temp*.* /Q

del C:\Users\%username%\AppData\Roaming\Microsoft\Windows\Recent Items*.* /Q pause

answered Jan 31 '15 at 23:08

pepivlad

21
1

score 0 · Answer 6 · edited Feb 11 '18 at 16:39

@echo off    
del /s /f /q %windir%\temp\*.*    
rd /s /q %windir%\temp    
md %windir%\temp    
del /s /f /q %windir%\Prefetch\*.*    
rd /s /q %windir%\Prefetch    
md %windir%\Prefetch    
del /s /f /q %windir%\system32\dllcache\*.*    
rd /s /q %windir%\system32\dllcache    
md %windir%\system32\dllcache    
del /s /f /q "%SysteDrive%\Temp"\*.*    
rd /s /q "%SysteDrive%\Temp"    
md "%SysteDrive%\Temp"    
del /s /f /q %temp%\*.*    
rd /s /q %temp%    
md %temp%    
del /s /f /q "%USERPROFILE%\Local Settings\History"\*.*    
rd /s /q "%USERPROFILE%\Local Settings\History"    
md "%USERPROFILE%\Local Settings\History"    
del /s /f /q "%USERPROFILE%\Local Settings\Temporary Internet Files"\*.*    
rd /s /q "%USERPROFILE%\Local Settings\Temporary Internet Files"    
md "%USERPROFILE%\Local Settings\Temporary Internet Files"    
del /s /f /q "%USERPROFILE%\Local Settings\Temp"\*.*    
rd /s /q "%USERPROFILE%\Local Settings\Temp"    
md "%USERPROFILE%\Local Settings\Temp"    
del /s /f /q "%USERPROFILE%\Recent"\*.*    
rd /s /q "%USERPROFILE%\Recent"    
md "%USERPROFILE%\Recent"    
del /s /f /q "%USERPROFILE%\Cookies"\*.*    
rd /s /q "%USERPROFILE%\Cookies"    
md "%USERPROFILE%\Cookies"

Welcome to Stack Overflow, please review: https://stackoverflow.com/help/how-to-answer — Daniel, Feb 11 '18 at 14:32

score 0 · Answer 7 · edited Nov 16 '18 at 15:05

@echo off
del /s /f /q c:\windows\temp\*.*
rd /s /q c:\windows\temp
md c:\windows\temp
del /s /f /q C:\WINDOWS\Prefetch
del /s /f /q %temp%\*.*
rd /s /q %temp%
md %temp%
deltree /y c:\windows\tempor~1
deltree /y c:\windows\temp
deltree /y c:\windows\tmp
deltree /y c:\windows\ff*.tmp
deltree /y c:\windows\history
deltree /y c:\windows\cookies
deltree /y c:\windows\recent
deltree /y c:\windows\spool\printers
del c:\WIN386.SWP
cls

score -1 · Answer 8 · edited Oct 28 '19 at 06:27

-1

Just use

del /f /q C:\Users\%username%\AppData\Local\temp

And it will work.

Note: It will delete the whole folder however, Windows will remake it as it needs.

edited Oct 28 '19 at 06:27

Community

1
1

answered Mar 12 '15 at 20:07

Ferre Vekemans

1

Batch file to perform start, run, %TEMP% and delete all

8 Answers8

Linked