By Emacs, how to join two lines into one?

Question

I am new to Emacs. I have googled this but no good answer there. One of them is Ctrl-n Ctrl-a Backspace This works but is stupid. Is there a quick and simple way to join a block of lines into a single line?

Actually, I can use Esc-q to auto-fill a paragraph now, but how could I get it to revert without UNDO?

The command "undo" is usually bound to C-_ (control-underscore)... — dmckee --- ex-moderator kitten, Jul 02 '09 at 13:37

score 197 · Answer 1 · answered Jan 22 '10 at 01:17

197

Place point anywhere on the last line of the group of lines that need joining and call

M-^

repeatedly until all the lines are merged.

Note: It leaves one space between all of the now joined lines.

answered Jan 22 '10 at 01:17

Ray

187,153
97
222
204

2

What is M-^ usually bound to? – stsquad Jun 16 '15 at 11:14
stsquad: you need to press Meta + Shift + 6 (Shift + 6 will give you ^) – Rafal Spacjer Dec 04 '15 at 06:47
1

Ah, the joys of day by day improving my Emacsfu. Only it can make me wonder about having different join lines functions: one with an extra space, one without it. – Charles Roberto Canato May 13 '16 at 18:13
4

And if you want to join from the ***first*** line, it's (intuitively enough), `C-u M-^` (which tends to be a lot more useful imho). – gypsydave5 Jul 02 '18 at 11:49
In my setup ^ is used to compose characters like â and thus M-^ does not work. And, on my German keyboard, ^ is not shift-6, also. Is there a trick for me here (aside from defining a key binding of my own)? – Dirk Herrmann Nov 05 '18 at 12:58
1

@DirkHerrmann `M-^` on a german keyboard is best input as `ESC ^ SPC` – JohnDoe Apr 08 '22 at 10:50
mark region and then issue M-^ to join multiple lines with space – Talespin_Kit Jan 06 '23 at 14:15

score 39 · Answer 2 · answered Jul 02 '09 at 05:38

39

M-x join-line will join two lines. Just bind it to a convenient keystroke.

answered Jul 02 '09 at 05:38

pgs

13,385
2
25
17

Yes. It works. However, it is of no use to a block of several lines(3 lines or more). Any useful command for this purpose? – jcadam Jul 02 '09 at 05:48
8

But if you go to the last line of the block and hit M-^ (the key binding for join-line) several times you will have the same effect. Goes pretty fast, so unless you have hundreds of lines to join I would prefer it over the fill-column hack. Otherwise do as Tal suggests, mark the block and replace newline (C-Q C-J) with nothing. – danielpoe Jul 02 '09 at 06:37
I have tried to bind join-line to M-1. It works fine also. As you you suggested, many solutions here for the purpose, so I'll try to use them all in a flexible way. Thank you very much! – jcadam Jul 03 '09 at 08:31
2

This is exactly the same thing as pressing `M-^`, because `join-line` is aliased to `delete-indentation`, which is bound to `M-^`. – Vicky Chijwani Jan 12 '13 at 03:27
With my emacs version (29.0.50) this worked for more 2 lines. I highlighted all the lines then ran M-x join-line – krm Apr 14 '23 at 10:22

score 12 · Answer 3 · answered Mar 22 '14 at 23:45

12

Multiple Cursors combined with M-^ will collapse all selected lines into one with all extraneous white-space removed.

For example to select an entire buffer, invoke multiple cursors mode, collapse into one line, and then disable multiple cursors mode:

C-x h
M-x mc/edit-lines
M-^
C-g

answered Mar 22 '14 at 23:45

huntar

1,072
11
9

My love for multiple cursors grows. – Bae Aug 11 '17 at 02:58
Thanks for the nice tip! works like magic. – ychaouche Sep 26 '22 at 13:41

Micah Elliott · Answer 4 · 2020-11-18T22:13:01.590

11

The Emacs conventional name for "join" is "fill". Yes, you can join two lines with M-^ -- and that's handy -- but more generally you'll want to join n lines. For this, see the fill* commands, such as fill-region, fill-paragraph, etc.

See this for more info on selecting things which can then be filled.

Also, you can join multiple lines with M-^ by selecting those lines first. (Note that the universal argument does not work with this.)

edited Nov 18 '20 at 22:13

answered Aug 14 '17 at 05:16

Micah Elliott

9,600
5
51
54

2

Would vote this to be the idiomatically correct answer – JohnDoe Sep 24 '17 at 11:12
`fill-region` worked well, but not `M-^` (nor `C-j` as a matter of fact) even when selecting the region first. – ychaouche Sep 26 '22 at 13:44
Also, not sure that fill=join. fill is join to a certain limit defined by `fill-width`. – ychaouche Sep 26 '22 at 13:59

score 9 · Answer 5 · answered Jul 02 '09 at 05:36

9

Just replace newlines with nothing.

answered Jul 02 '09 at 05:36

Tal Pressman

7,199
2
30
33

score 5 · Answer 6 · answered Jul 16 '13 at 17:09

5

I like the way Sublime text Join line with Command J so I do it this way:

(defun join-lines (arg)
  (interactive "p")
  (end-of-line)
  (delete-char 1)
  (delete-horizontal-space)
  (insert " "))

answered Jul 16 '13 at 17:09

Mark

51
1
1

Nice, but how not to insert space when line below consisted only white spaces or was empty? – rofrol Aug 06 '21 at 17:04

score 4 · Accepted Answer · answered Jul 02 '09 at 06:14

4

You could define a new command for this, temporarily adjusting the fill width before using the the Esc-q command:

;; -- define a new command to join multiple lines together --
(defun join-lines () (interactive)
 (setq fill-column 100000)
 (fill-paragraph nil)
 (setq fill-column 78)
)

Obviously this only works, if your paragraph has less than 100000 characters.

answered Jul 02 '09 at 06:14

Ralph

5,154
1
21
19

10

Without clobbering fill-column, that would be (defun join-lines () (interactive) (let ((fill-column 999999)) (fill-paragraph nil))) – huaiyuan Jul 02 '09 at 10:31
Yeah. This should be more graceful. – jcadam Jul 03 '09 at 08:33
What about this ? (defun unfill-paragraph () "Does the opposite of fill-paragraph" (interactive) (let ((fill-column (point-max))) (fill-paragraph nil))) – Gyom Jul 09 '09 at 01:37
1

Ray Vega's answer (below) should be the accepted one tbh. – gypsydave5 Jul 02 '18 at 11:53

score 3 · Answer 8 · edited May 23 '17 at 12:09

3

I use the following function and bind it to 'M-J'.

(defun concat-lines ()
  (interactive)
  (next-line)
  (join-line)
  (delete-horizontal-space))

If you prefer to keep your cursor position, you can use save-excursion.

edited May 23 '17 at 12:09

Community

1
1

answered Oct 08 '15 at 01:35

yuki morphs

31
3

nishidh41 · Answer 9 · 2018-04-11T15:41:09.097

2

The most simplest way ever:

Select paragraph/lines by M-h or C-SPC

Press M-q

Witness the Emagics (Emacs Magic)!!

edited Apr 11 '18 at 15:41

answered Apr 11 '18 at 09:08

nishidh41

31
4

score 2 · Answer 10 · answered Sep 19 '18 at 02:33

Because join-line will left one space between two lines, also it only support join two lines. In case of you want to join plenty of lines without one space left, you can use "search-replace" mode to solve, as follows:

C-%
Query: input C-q C-j Enter
Replace: Enter
Run the replacement. Enter

Done.

score 1 · Answer 11 · answered Feb 21 '22 at 18:12

Two ways come to mind:

Once you think of it, the most obvious (or at least easiest to remember) way is to use M-q format-paragraph with a long line length C-x-f 1000.
There is also a built-in tool M-^ join-line. More usefully, if you select a region then it will combine them all into one line.

score 0 · Answer 12 · answered Jan 19 '15 at 09:06

"how could I get it to revert without UNDO?":

(defun toggle-fill-paragraph ()
  ;; Based on http://xahlee.org/emacs/modernization_fill-paragraph.html
  "Fill or unfill the current paragraph, depending upon the current line length.
When there is a text selection, act on the region.
See `fill-paragraph' and `fill-region'."
  (interactive)
  ;; We set a property 'currently-filled-p on this command's symbol
  ;; (i.e. on 'toggle-fill-paragraph), thus avoiding the need to
  ;; create a variable for remembering the current fill state.
  (save-excursion
    (let* ((deactivate-mark nil)
           (line-length (- (line-end-position) (line-beginning-position)))
           (currently-filled (if (eq last-command this-command)
                                 (get this-command 'currently-filled-p)
                               (< line-length fill-column)))
           (fill-column (if currently-filled
                            most-positive-fixnum
                          fill-column)))
      (if (region-active-p)
          (fill-region (region-beginning) (region-end))
        (fill-paragraph))
      (put this-command 'currently-filled-p (not currently-filled)))))
(global-set-key (kbd "M-q") 'toggle-fill-paragraph)

score 0 · Answer 13 · answered Mar 25 '18 at 11:40

From EmacsWiki: Unfill Paragraph

 ;;; Stefan Monnier <foo at acm.org>. It is the opposite of fill-paragraph    
    (defun unfill-paragraph (&optional region)
      "Takes a multi-line paragraph and makes it into a single line of text."
      (interactive (progn (barf-if-buffer-read-only) '(t)))
      (let ((fill-column (point-max))
            ;; This would override `fill-column' if it's an integer.
            (emacs-lisp-docstring-fill-column t))
        (fill-paragraph nil region)))

score 0 · Answer 14 · answered Apr 03 '20 at 02:27

A basic join of 2 lines:

(delete-indentation)

I like to line below to be joined to the current without moving the cursor:

("C-j" .
  (lambda (iPoint)
    "Join next line onto current line"
    (interactive "d")
    (next-line)
    (delete-indentation)
    (goto-char iPoint)))

rofrol · Answer 15 · 2021-08-06T18:08:23.143

This one behaves like in vscode. So it add space only if join line consisted something else than whitespace. And I bind it to alt+shift+j.

Shorter version based on crux-top-join-line:

(global-set-key (kbd "M-J") (lambda () (interactive) (delete-indentation 1)))

Longer version based on https://stackoverflow.com/a/33005183/588759.

;; https://stackoverflow.com/questions/1072662/by-emacs-how-to-join-two-lines-into-one/68685485#68685485
(defun join-lines ()
  (interactive)
  (next-line)
  (join-line)
  (delete-horizontal-space)
  (unless (looking-at-p "\n") (insert " ")))

(global-set-key (kbd "M-J") 'join-lines)

By Emacs, how to join two lines into one?

15 Answers15