AppleScript and Mail.app: checking if new messages contain a string

Question

I'm writing a script to check if a particular web form has been submitted.

The script so far reads thusly:

tell application "Mail"
check for new mail
set newmail to get the unread count of inbox
repeat with msg in newmail
    if msg's subject contains "New newsletter built by" then
        return msg's subject
    end if
end repeat
end tell

I've got an unread email in my inbox for the script to work with, but I still get an error:

error "Mail got an error: Can’t make 1 into type specifier." number -1700 from 1 to specifier

Any help at all will be appreciated.

Cheers!

score 3 · Accepted Answer · answered Jun 06 '12 at 02:05

3

tell application "Mail"
    check for new mail
    repeat until (background activity count) = 0
        delay 0.5 --wait until all new messages are in the box
    end repeat
    try
        return subject of (first message of inbox whose read status is false and subject contains "New newsletter built by ")
    end try
end tell

answered Jun 06 '12 at 02:05

jackjr300

7,111
2
15
25

When I execute your repeat-loop I get an error message `error "Mail got an error: AppleEvent handler failed." number -10000` - do you know why? – d-b Oct 29 '22 at 20:28

score 1 · Answer 2 · answered Jun 05 '12 at 02:49

Applescript is a bit tricky. It looks like you're trying to parse the count of the inbox, not the actual inbox.

Try this script instead:

tell application "Mail"
    check for new mail
    -- instead of getting the unread count of inbox
    -- let's set an Applescript variable to every message of the inbox
    set myInbox to every message of inbox
    repeat with msg in myInbox
        -- and look at only the ones that are unread
        if read status of msg is false then
            -- and if the subject of the unread message is what we want 
            if msg's subject contains "New newsletter built by" then
                -- return it
                return msg's subject
            end if
        end if
    end repeat
end tell

score 0 · Answer 3 · answered Jun 06 '12 at 00:16

0

I've actually solved the issue, so I'm going to post it here should anyone else need help. Check it:

tell application "Mail"
check for new mail

set checker to (messages of inbox whose read status is false)
set neworder to number of items in checker

if neworder > 0 then
    repeat with i from 1 to number of items in checker
        set msg to item i of checker
        if msg's subject contains "New newsletter built by " then
            return msg's subject
        end if
    end repeat
end if
end tell

answered Jun 06 '12 at 00:16

t56k

6,769
9
52
115

Unless you receive all messages in less than a tenth of a second, your script will not work correctly every time, because the command `check for new mail` will not wait, so **Mail** won't have yet had time to login to the mail server and retrieve any pending messages. – jackjr300 Jun 06 '12 at 01:55

score 0 · Answer 4 · edited Jun 17 '13 at 23:19

adding to what jackjr300 said....

tell application "Mail"
    set x to unread count of inbox
    check for new mail
    delay 3
    set y to unread count of inbox
    set z to y - x
end tell

if x = y then
    say "There is nothing to report"
end if

if z = 1 then
    say "You have one new message"
end if

if z = 2 then
    say "You have two new messages"
end if

if z = 3 then
    say "You have three new messages"
end if
if z = 4 then
    say "You have four new messages"
end if
if z = 5 then
    say "You have five new messages"
end if
if z = 6 then
    say "You have six new messages"
end if
if z = 7 then
    say "You have seven new messages"
end if
if z = 8 then
    say "You have eight new messages"
end if

if z = 9 then
    say "You have nine new messages"
end if
if z = 10 then
    say "You have ten new messages"
else
    say "You have more than ten new messages"
end if

AppleScript and Mail.app: checking if new messages contain a string

4 Answers4

Linked