The problem you are running into stems from the fact that A86 is a single pass assembler. When you use symbols like testz and second before defining them A86 has to guess what they are. It assumes that they will be immediate values, but later on it discovers that they're actually labels. A multi-phase assembler might go back and change the decision it made earlier, but A86 doesn't do that. It simply barfs forth an error (#16). This is why the error appears in the source file near the definition: that's where A86 was when it discovered the problem.
You can use the directives offset, d, w, and so on to tell A86 explicitly what you want it to do, so it won't have to make guesses.
The A86 manual explains: "IMPORTANT: you must understand the distinction between a label and a variable, because you may generate a different instruction than you intended if you confuse them. For example, if you declare XXX: DW ?, the colon following the XXX means that XXX is a label; the instruction MOV SI,XXX moves the immediate constant address of XXX into the SI register. On the other hand, if you declare XXX DW ? with no colon, then XXX is a word variable; the same instruction MOV SI,XXX now does something different: it loads the run-time value of the memory word XXX into the SI register. You can override the definition of a symbol in any usage with the immediate-value operator OFFSET or the memory-variable operators B,W,D,Q, or T. Thus, MOV SI,OFFSET XXX loads the immediate value pointing to XXX no matter how XXX was declared; MOV SI,XXX W loads the word-variable at XXX no matter how XXX was declared."
This should answer your second question: When A86 sees add bl, [second] it assumes that second will be an immediate byte sized operand since bl is a byte sized register.
Your next line mov bx, second expects second to be an immediate word sized operand, but A86 has already made a note that second will be a byte, so you get error #13.
You can get what you want by doing this instead:
add bl, second b ; add the byte at memory location ds:second to bl
mov bx, offset second
Generally, these problems will disappear if you define your symbols before using them. For example, this will work:
name example1 ; good code
code segment
org 0100h
main: ; - MACHINE CODE
mov bx, main ; BB0001 - put 0100h in bx
mov bx, offset main ; BB0001 - put 0100h in bx
; ^ offset directive not needed here
; A86 already knows what to do
mov bx, [main] ; 8B1E0001 - put 00BBh in bx
; ^ brackets work fine to dereference main here
mov bx, main w ; 8B1E0001 - put 00BBh in bx
; ^ w does the same thing as brackets
org 0150h
goodbye:
int 020h
code ends
end main
but this will not work:
name example2 ; will not assemble
code segment
org 0100h
main: ; - MACHINE CODE
mov bx, goodbye ; BB5001 - put 0150h in bx
; ^ A86 assumes goodbye is an immediate value. This assumption
; turns out to be a good one, so this line works OK
mov bx, offset goodbye; BB5001 - put 0150h in bx
; ^ offset directive tells A86 that goodbye will be an immediate
; value. You can skip it, since A86 assumes that anyway
mov bx, [goodbye] ; this line is the culprit!
; ^ A86 doesn't know what to do about these brackets
mov bx, goodbye w ; 8B1E5001 - put 20CDh (`int 020h`) in bx
; ^ w directive tells A86 that goodbye will be a word
; variable
org 0150h
goodbye: ; label goodbye not defined until way down here!
int 020h
code ends
end main
