coldfusion validate form number without generating error

Question

I have an ajax form that gets submitted to an iframe. On the server-side I want to validate an input as a valid integer, and if it is not validated set it to a default value of 0. Initial solution was:

<cfparam name="FORM.integerField" default="0" type="integer">

But, on form submit if string data was entered then the server throws an error. I don't want the error to be thrown, I want to check the datatype and set it to a default if it fails the check and then keep processing the from. I have also tried things like:

<cfqueryparam value="#atest#" cfsqltype="CF_SQL_NUMERIC"> <!-- inside my query -->

<cfif IsDefined(LSParseNumber(FORM.integerField))>

<cfif LSParseNumber(FORM.integerField)>

Any suggestions?

score 3 · Accepted Answer · answered Aug 08 '12 at 13:18

3

<cfif NOT isValid("integer",FORM.integerField)>
    <cfset FORM.integerField = 0>
</cfif>

I <3 "isValid()".

answered Aug 08 '12 at 13:18

Sharondio

2,605
13
16

1

isvalid has issues and shouldn't really be used. http://stackoverflow.com/questions/11535979/coldfusion-why-isvalidinteger-1-5-yes – nosilleg Aug 08 '12 at 13:56
If you are set on using `isValid()`, use it with `&& isNumeric()` – Mike Causer Aug 09 '12 at 12:17

nosilleg · Answer 2 · 2012-08-08T15:20:42.923

This might be overkill for what you want, but it'll do the job. Just supply the number argument.

<cffunction name="CastAsInteger" access="public" returntype="String" output="false" hint="Returns the provided number if it matches the bits and sign, otherwise returns 0">
    <cfargument name="number" type="any" required="true" hint="Any string that may be an integer">
    <cfargument name="bits" type="numeric" default="32" required="false" hint="Number of bits to determine the max size of the integer">
    <cfargument name="signed" type="boolean" default="true" required="false" hint="If the integer is signed or unsigned">

    <cfset local.ReturnInt = Arguments.Number>

    <!--- Make sure it's just a number --->
    <cfif REFind("^-?[1-9]+[0-9]*$", local.ReturnInt) EQ false>
        <cfset local.ReturnInt = 0>
    </cfif>

    <!--- Check size --->
    <cfif Arguments.signed EQ true>
        <cfif local.ReturnInt LT PrecisionEvaluate(-(2^(Arguments.bits - 1))) OR local.ReturnInt GT PrecisionEvaluate((2^(Arguments.bits - 1)) - 1)>
            <cfset local.ReturnInt = 0>
        </cfif>
    <cfelse>
        <cfif local.ReturnInt LT 0 OR local.ReturnInt GT PrecisionEvaluate((2^Arguments.bits) - 1)>
            <cfset local.ReturnInt = 0>
        </cfif>
    </cfif>

    <cfreturn local.ReturnInt>
</cffunction>

coldfusion validate form number without generating error

2 Answers2