How to calculate time taken by all threads

Question

I am using Following .NET Code

 Class MonitorSample
  Shared Sub RunMonitor()
    Dim o As New Object()
    For i As Integer = 0 To 99
    ThreadPool.QueueUserWorkItem(Function()
       Try
       Monitor.Enter(o)
       Console.WriteLine("Thread {0} acquired lock...working", Thread.CurrentThread.ManagedThreadId)
       Console.WriteLine("Thread {0} performing some I/O operation so yielding the lock temporarily...", Thread.CurrentThread.ManagedThreadId)
       Monitor.PulseAll(o)
       Monitor.Wait(o)
       Console.WriteLine("Thread {0} reacquired lock", Thread.CurrentThread.ManagedThreadId)
       Finally
       Console.WriteLine("Thread {0} released lock", Thread.CurrentThread.ManagedThreadId)
       Monitor.PulseAll(o)
       Monitor.Exit(o)
       End Try
     Return Nothing
   End Function
  )
  Next
  Console.ReadLine()
 End Sub
 Shared Sub Main()
 Dim stopwatch As New Stopwatch()
   stopwatch.Start()
   RunMonitor()
   stopwatch.Stop()
   Console.WriteLine("Time elapsed: {0}", stopwatch.Elapsed)
 End Sub
End Class

In the main method is this the right method to calculate time consuemd by thread or we should calculate in some otherway.

Actually the step to print time consumed get printed first while threads get executed later.

It isn't clear, what are you trying to calculate. – Dennis Sep 05 '12 at 09:03 — Dennis, Sep 05 '12 at 09:03
I am calculating time consumed to run all threads – Abhishek Gupta Sep 05 '12 at 10:13 — Abhishek Gupta, Sep 05 '12 at 10:13

score 1 · Accepted Answer · edited May 23 '17 at 10:24

Your Sub won't do as you want - there are 2 issues here

There is a Console.Readline which will also wait for the user's input inside the StopWatch
You aren't synchronizing your threads properly - fortunately, the threads usually finish while waiting for user input, but this won't allow you to time the threads.

The following should fix this by moving the stopwatch tightly around the threads, and also providing a CountDownEvent to allow each thread to indicate when it has completed.

    Shared Sub RunMonitor()
        Dim stopwatch As New Stopwatch()
        stopwatch.Start()
        Dim o As New Object()
        Const numThreads As Integer = 10
        ' Create an Event which signals when we are finished
        Dim allDoneEvent As New CountdownEvent(numThreads)
        For i As Integer = 0 To numThreads - 1
            ThreadPool.QueueUserWorkItem(Function()
                                             Try
                                                 Monitor.Enter(o)
                                                 Console.WriteLine("Thread {0} acquired lock...working", Thread.CurrentThread.ManagedThreadId)
                                                 Console.WriteLine("Thread {0} performing some I/O operation so yielding the lock temporarily...", Thread.CurrentThread.ManagedThreadId)
                                                 Monitor.PulseAll(o)
                                                 Monitor.Wait(o)
                                                 Console.WriteLine("Thread {0} reacquired lock", Thread.CurrentThread.ManagedThreadId)
                                             Finally
                                                 Console.WriteLine("Thread {0} released lock", Thread.CurrentThread.ManagedThreadId)
                                                 Monitor.PulseAll(o)
                                                 Monitor.Exit(o)
                                                 ' This thread indicates that it has finished its work
                                                 allDoneEvent.Signal()
                                             End Try
                                             Return Nothing
                                         End Function
          )
        Next
        ' Wait for all events to finish, or after a timeout
        allDoneEvent.Wait(10000)
        ' Stop the stopwatch before the readline
        stopwatch.Stop()
        Console.WriteLine("Time elapsed: {0}", stopwatch.Elapsed)
        Console.ReadLine()
    End Sub

Why u call Signal from finallyand what to do if code is not having try catch finally , I have to put similar counters in various similar progs like Monitor, Mutex, ReaderWriterLock, Semaphore not all codes are having same try finally code block although concept of ThreadPool.Queue is same and all code examples ahave same amount of threads i.e. 100 — Abhishek Gupta, Sep 05 '12 at 11:57
@AbhishekGupta You don't necessarily need to put the signal in finally, but it is usually the best place, because we want to ensure that we flag our thread as complete on good or bad exits from the code. I would also suggest that you wait with a timeout, e.g. `allDoneEvent.Wait(10000)` — StuartLC, Sep 05 '12 at 12:04

How to calculate time taken by all threads

1 Answers1