How to catch any Javascript exception in Clojurescript?

Question

In my communication layer I have a need to be able to catch ANY javascript exception, log it down and proceed as I normally would do. Current syntax for catching exceptions in Clojurescript dictates that I need to specify the type of the exception being caught.

I tried to use nil, js/Error, js/object in the catch form and it doesn't catch ANY javascript exception (which can have string as the type of the object).

I would appreciate any hints how this can be done natively in Clojurescript.

Hi Dima! Do you think my response fix your problem? – tangrammer Oct 21 '13 at 12:10 — tangrammer, Oct 21 '13 at 12:10

score 53 · Answer 1 · answered Jan 17 '14 at 10:34

53

I found another possible answer in David Nolen "Light Table ClojureScript Tutorial"

;; Error Handling
;; ============================================================================

;; Error handling in ClojureScript is relatively straightforward and more or
;; less similar to what is offered in JavaScript.

;; You can construct an error like this.

(js/Error. "Oops")

;; You can throw an error like this.

(throw (js/Error. "Oops"))

;; You can catch an error like this.

(try
  (throw (js/Error. "Oops"))
  (catch js/Error e
    e))

;; JavaScript unfortunately allows you to throw anything. You can handle
;; this in ClojureScript with the following.

(try
  (throw (js/Error. "Oops"))
  (catch :default e
    e))

answered Jan 17 '14 at 10:34

tangrammer

3,041
17
24

This is now the proper way to do it. – johnbakers May 11 '14 at 10:28
`:default` does not currently exist in "regular" (Java-based) Clojure, but there is a proposal to add it to that as well: http://dev.clojure.org/jira/browse/CLJ-1293 – Hutch Moore Mar 22 '17 at 17:26
`#?(:cljs :default :clj Throwable)` instead of `:default` will work for both clj and cljs, in a cljc file – Chris Murphy Oct 28 '20 at 08:42

score 6 · Answer 2 · answered Feb 28 '13 at 17:26

It looks like js/Object catches them all (tested on https://himera.herokuapp.com):

cljs.user> (try (throw (js/Error. "some error")) (catch js/Object e (str "Caught: " e)))
"Caught: Error: some error"
cljs.user> (try (throw "string error") (catch js/Object e (str "Caught: " e)))
"Caught: string error"
cljs.user> (try (js/eval "throw 'js error';") (catch js/Object e (str "Caught: " e)))
"Caught: js error"

One thing to watch out for is lazy sequences. If an error is thrown in a lazy sequence that part of the code might not be executed until after you've exited the try function. For example:

cljs.user> (try (map #(if (zero? %) (throw "some error")) [1]))
(nil)
cljs.user> (try (map #(if (zero? %) (throw "some error")) [0]))
; script fails with "Uncaught some error"

In that last case, map creates a lazy sequence and the try function returns it. Then, when the repl tries to print the sequence to the console, it's evaluated and the error gets thrown outside of the try expression.

you can catch them with `:default` too which is probably more idiomatic — olieidel, Jan 30 '18 at 16:18

score 4 · Answer 3 · answered Sep 11 '13 at 15:24

I think I've just found the solution in this link https://groups.google.com/forum/#!topic/clojure/QHaTwjD4zzU

I copy the contents here: This solution was published by Herwig Hochleitner

try in clojurescript is actually a macro that uses the builtin try* and adds type dispatch. So to catch everything, just use (try* ... (catch e ...)). This maps directly to javascript's try.

And here is my implementation working now:

(defn is-dir? [the_dir]
  (try*
    (if-let [stat (.statSync fs the_dir )]
      (.isDirectory stat)
      false)
    (catch  e 
      (println "catching all exceptions, include js/exeptions")
      false
      )
    )
  )

I hope it helps you
Juan

try* is now deprecated. Use the :default as in your other answer — johnbakers, May 11 '14 at 10:10

How to catch any Javascript exception in Clojurescript?

3 Answers3

Linked