How to check if the user input ends with a specific string in batch (.bat) script

Question

I am writing a batch script where if user input is empty or doesnot ends with "DTO" I need to ask user to enter DTO name again.

:INPUT
SET /P INPUTDTO=Enter the DTO:

IF "%INPUTDTO%"=="" (
      IF "%INPUTDTO%" ??????? (
             GOTO NODTO
      )
)

:NODTO
ECHO ERROR: Please enter a valid DTO.
GOTO INPUT

How to check if the user input ends with "DTO"

score 22 · Accepted Answer · answered Oct 03 '12 at 17:09

22

The existing INPUTDTO value should probably be cleared because SET /P will preserve the existing value if the user does not enter anything.

@echo off
set "INPUTDTO="
:INPUT
SET /P INPUTDTO=Enter the DTO:
if "%INPUTDTO:~-3%" neq "DTO" (
  ECHO ERROR: Please enter a valid DTO.
  goto INPUT
)

Add the /I switch to the IF statement if you want the comparison to be case insensitive.

answered Oct 03 '12 at 17:09

dbenham

127,446
28
251
390

Why are the quotes in `set "INPUTDTO="` needed? Thank you. – Sabuncu Jan 15 '15 at 12:49
2

@Sabuncu - when formatted like I have it, with the opening quote before the variable name, then any text after the last quote is ignored. It prevents inadvertent white space from being included in the assignment. Not necessary if the line ends where it should, but a good safe guard. – dbenham Jan 15 '15 at 13:12

Sean Vaughn · Answer 2 · 2012-10-03T17:22:38.573

The logic is simple, first remove any occurrences of "DTO" from your original string and store it into another variable. Then compare it with the original INTPUTDTO variable adding a "DTO" at the end.

:INPUT
SET /P INPUTDTO=Enter the DTO:
SET NEWINPUTDTO=%INPUTDTO:DTO=%

IF "%INPUTDTO%"=="" (
      IF NOT "%NEWINPUTDTO%DTO"=="%INPUTDTO%"  (
             GOTO NODTO
      )
)

:NODTO
ECHO ERROR: Please enter a valid DTO.
GOTO INPUT

Also, if you don't care about script complexity, then just use this:

IF NOT "%INPUTDTO:DTO=%DTO"=="%INPUTDTO%"

score 1 · Answer 3 · answered Oct 03 '12 at 17:17

If you are open to using other Software, you can use grep from GnuWin32. It will set you back 1.5MB

@echo off
:INPUT
SET /P INPUTDTO=Enter the DTO:


echo %INPUTDTO% | grep .*DTO\b

IF %ERRORLEVEL%==1 (
 goto NODTO
)
goto:eof
:NODTO
 ECHO ERROR: Please enter a valid DTO.
 GOTO INPUT

score 0 · Answer 4 · edited May 23 '17 at 10:27

0

Maybe you can use the substring-ing capabilities as described here:What is the best way to do a substring in a batch file?.

Then compare that substring agains "DTO".

edited May 23 '17 at 10:27

Community

1
1

answered Oct 03 '12 at 17:11

Anssssss

3,087
31
40

How to check if the user input ends with a specific string in batch (.bat) script

4 Answers4