Escaping parentheses within parentheses for batch file

Question

This is what I am trying to do:

(
@echo This is some code that is
@echo Important to echo exactly as-is
@echo Even if I use parenthesis
@echo for something (like this)
)|clip

So having that copied into clipboard. I have tried the following:

(
@echo This is some code that is
@echo Important to echo exactly as-is
@echo Even if I use parenthesis
@echo for something ^(like this^)
)|clip

But this seems to affect my WANTED parentheses as well because I receive an error. To test this, I simply done:

(
@echo This is some code that is
@echo Important to echo exactly as-is
@echo Even if I use parenthesis
@echo for something ^(like this^)
FFF
)|clip

Hey! This almost works, the text is copied all the way to the "s" in "this". It does not copy the last parentheses, or obviously the F's. Any ideas?

I don't understand the problem. What error are you receiving? If I use `@echo for something ^(like this^)`, it echos out `for something (like this)`. — LittleBobbyTables - Au Revoir, Oct 19 '12 at 14:30
That comment by itself is fine. The escape character seems to also affect the second parentheses, the one for ")|clip". If you try using that entire code you'll see what I mean. I receive ) was unexpected at this time. — user1759622, Oct 19 '12 at 14:32

score 63 · Accepted Answer · edited May 23 '17 at 11:55

63

It's obvious that you need three carets there :-)

(
@echo This is some code that is
@echo Important to echo exactly as-is
@echo Even if I use parenthesis
@echo for something (like this^^^)
)|clip

Why? That is a bit tricky...

First the parser parses the block and escapes the part this^^^) to this^), the parenthesis was escaped here the first time.

But as you used a pipe, the complete block will be translated and transfered to a new cmd.exe instance.
C:\Windows\system32\cmd.exe /S /D /c" ( @ echo This is some code is ... & @ echo for something (like this^) )"

And in the new instance it is necessary again to escape the closing parenthesis.
That's all!

And for more information you could read a similar question
SO: why does delayed expansion fail when inside a piped block of code

edited May 23 '17 at 11:55

Community

1
1

answered Oct 19 '12 at 14:52

jeb

78,592
17
171
225

4

Hah, I tried with two carats and it didn't work either, and I didn't get around to trying three carats. Also, I think you want `@echo for something ^(like this^^^)`. – LittleBobbyTables - Au Revoir Oct 19 '12 at 14:54
3

@LittleBobbyTables - No, you only need carets for the closing parenthesis – jeb Oct 19 '12 at 15:01
Thanks man, you're the best. I wish I understood how that works, but anyway, thanks for the answer! – user1759622 Oct 19 '12 at 15:01
12

Srsly, Microsoft. What the actual F. – DaveRandom Jan 20 '15 at 15:48

score 6 · Answer 2 · answered Jun 01 '17 at 19:41

If you get confused by the caret count, remember that it is always a power of 2 minus 1. Alternatively, remember that the first time you add 2, the second time 4, the third time 8, ...

For example, (tested on XP)

(
for /f "tokens=* delims=" %%S in (
'echo X^^^^^^^^^^^^^^^& ^^^^^^^^^^^^^^^| ^^^| find " "'
) do @echo %%S
) | find "X"

The echo statement gets read first normally when DOS parses the batch file (1), second because it is a piped internal command (DOS seems to want programs in pipes, and internal commands are not programs) (3), third because it is in a 'for /f' command-driven word list (see for /?) (7), and a fourth time for reasons already given in this thread (15).

I may also note that personally, I consider it sloppy coding to leave proper escaping of hot characters away just because DOS happens to ignore the missing escaping in that particular case. So if I wanted to echo a literal pair of parentheses in the above example, I would give each 15 carets, even if the opening parenthesis does not need it. Then anyone reading my code does not have to wonder why one parenthesis is quoted and the other is not. And how to modify the quoting under code modification.

score 1 · Answer 3 · edited Aug 22 '13 at 23:56

1

The triple-caret does not work in all situations. take the following:

IF EXIST file.txt (
ECHO ...OK
) ELSE (
ECHO TEST THIS: (SOME WORDING! ^^^)   > file.txt
)

the contents of file.txt are:

TEST THIS: (SOME WORDING! ^)

edited Aug 22 '13 at 23:56

Smern

18,746
21
72
90

answered Aug 22 '13 at 23:35

psm1034

11
1

2

Yes, but I described why the solution needs three carets, as the block is piped and therefore a single caret isn't enough – jeb Aug 23 '13 at 20:44

Sirach Matthews · Answer 4 · 2015-12-05T02:17:52.193

1

My solution when I need to use a closing parenthesis in my encapsulated echos is to create a variable named %endPar% at the beginning of my script, something like this:

@set "endPar=)"
@echo This is some code that is>tmp
@echo Important to echo exactly as-is>>tmp
@echo Even if I use parenthesis>>tmp
@echo for something (like this%endPar%>>tmp
@type tmp|clip
@del tmp

I changed it a bit, and tested it twice.

The code simply outputs the echos to a file called tmp, you then pipe the contents of the file to clip, and it's ready for you to paste wherever you want.

edited Dec 05 '15 at 02:17

answered Dec 04 '15 at 03:45

Sirach Matthews

147
13

1

But it doesn't work. The closing parenthesis is missing – jeb Dec 04 '15 at 18:34
@jeb - you're absolutely correct, it didn't work. Silly me. I changed it up a bit, and tested it a few times. Try it now. – Sirach Matthews Dec 05 '15 at 02:19
1

Now it works, but it doesn't answer the question anymore. How to escape parenthesis inside of parenthesis – jeb Dec 05 '15 at 10:27
@jeb Too true. My original answer works fine in most cases without the pipe, but once piping is involved, triple-carrots all the way. Were my reputation high enough, I'd up-vote your answer in a heart-beat. – Sirach Matthews Dec 06 '15 at 05:14

Escaping parentheses within parentheses for batch file

4 Answers4

Linked

Related