Is better way to zoom windows in Vim than ZoomWin?

Question

I used to use ZoomWin: https://github.com/vim-scripts/ZoomWin for toggle between one and multiple windows in Vim. But this plugin has one big issue. When I`m trying to restore multiple windows(vertical split) there is about 2-4 sec delay.

Do you know how to avoid that lag? Or maybe is better solution for that.

Version 25 solved problem: https://github.com/regedarek/ZoomWin

The lag makes zoomwin a no-go for me. – arcseldon Nov 07 '17 at 15:23 — arcseldon, Nov 07 '17 at 15:23
BenC answer below has the perf. needed. – arcseldon Nov 07 '17 at 15:29 — arcseldon, Nov 07 '17 at 15:29

ljs.dev · Accepted Answer · 2015-05-21T03:51:03.063

I try to use vim without any plugins as I don't want to rely on them when I work on another system. Coming upon this same issue now, I can propose some 'better ways' (alternative ways) as requested by the OP:

c-w-| to have window take over (if using vsplits). c-w-= to restore. c-w-_ for horizontal splits
close the other window(s), thereby making current one fullscreen. Split and re-open from buffer to restore
use tmux if available and run multiple instances of vim, c-b-z to switch between fullscreen for the current pane

I have listed these in order of my perceived practicality. Experience will of course be better with a dedicated plugin, but that is not always an option.

Nice, but C-w-= does not restore but splits in the _middle_ (whereas the original split might have been different). — Eric O. Lebigot, Aug 06 '18 at 11:46

score 56 · Answer 2 · answered Oct 24 '14 at 15:22

56

A simple alternative (which may be enough depending on what you need):

" Zoom / Restore window.
function! s:ZoomToggle() abort
    if exists('t:zoomed') && t:zoomed
        execute t:zoom_winrestcmd
        let t:zoomed = 0
    else
        let t:zoom_winrestcmd = winrestcmd()
        resize
        vertical resize
        let t:zoomed = 1
    endif
endfunction
command! ZoomToggle call s:ZoomToggle()
nnoremap <silent> <C-A> :ZoomToggle<CR>

answered Oct 24 '14 at 15:22

BenC

8,729
3
49
68

This is pretty good actually! Note that you might need to remap `` to something else if you're already using this combination with tmux =) – Abdo Nov 12 '14 at 10:49
1

@Abdo: indeed, I mapped it to `` since I use `` for tmux ;-) – BenC Nov 12 '14 at 14:41
Haha, nice! :-) I mapped it to `E` since I have `cmd shift e` as my shortcut to expand windows in my OSX =) – Abdo Nov 12 '14 at 14:48
4

A corresponding plugin using the same technique: https://github.com/szw/vim-maximizer – blueyed Nov 12 '15 at 23:13
2

Great solution. Works like a charm. – rgin Jun 07 '16 at 16:22
1

Your amazing! . – IvRRimUm Dec 06 '16 at 13:19
Thanks a ton ! Your script does exactly what i wanted & along with a mapping of z => It makes it similar to the zoom in tmux ! – Rahul Gupta Jul 29 '17 at 19:04
1

Ideal. Thank you! – arcseldon Nov 07 '17 at 15:29
1

this comment should be accepted answer, it works like a charm. – Luan Pham Dec 29 '20 at 04:41
Using this mapping allows you to use the same familiar CTRL-W vim reflex, but with a Z at the end (akin to tmux) (CTRL-W-Z): `nnoremap :ZoomToggle` – jaywilliams Mar 04 '21 at 15:20

score 15 · Answer 3 · answered Dec 07 '18 at 13:50

15

I have another method that I've used for years; allows me to 'zoom' the current buffer to a new tab, and then quickly close it again, so that I can go back to my original multi-window layout:

" "Zoom" a split window into a tab and/or close it
nmap <Leader>,zo :tabnew %<CR>
nmap <Leader>,zc :tabclose<CR>

answered Dec 07 '18 at 13:50

JESii

4,678
2
39
44

1

great solution. – pinoyyid May 31 '22 at 21:09

score 13 · Answer 4 · answered Nov 02 '12 at 12:05

13

The ZoomWin version 24 introduced saving of window-local variables. When I've tried it out, I found the performance unacceptable, probably because of the various other plugins that I have installed and which install various event handlers.

I've reported my issues to the plugin author and he replied that

v25a of ZoomWin has the g:zoomwin_localoptlist and noautocmd stuff.

So, either try reverting to version 23 (which I did), or try out the latest version with the mentioned setting turned off from http://drchip.org/astronaut/vim/index.html#ZOOMWIN

answered Nov 02 '12 at 12:05

Ingo Karkat

167,457
16
250
324

5

Thank you! Version 25 Works excellent. I just pushed newest version to my Github account. https://github.com/regedarek/ZoomWin – tomekfranek Nov 02 '12 at 12:40
Yes, I've just tried with v25d, and, though not as fast as v23, the delay on my old laptop is ~200 ms, which I think I can live with. – Ingo Karkat Nov 02 '12 at 20:52
Is the original author not maintaining it anymore? Do you have his permission? – Steven Lu Jun 04 '13 at 03:21

score 12 · Answer 5 · answered Sep 18 '16 at 20:34

12

Another simple way is :tab split. The upside is that it doesn't change the layout of the current tab. The downside is that it requires Vim 7.0 or above for tab support.

nnoremap <leader>t :call TabToggle()<cr>
function! TabToggle()
  if tabpagewinnr(tabpagenr(), '$') > 1
    " Zoom in when this tab has more than one window
    tab split
  elseif tabpagenr('$') > 1
    " Zoom out when this tab is not the last tab
    if tabpagenr() < tabpagenr('$')
      tabclose
      tabprevious
    else
      tabclose
    endif
  endif
endfunction

answered Sep 18 '16 at 20:34

Hanhong Xue

121
1
2

I like this one! I wrote my own almost exactly like BenC's, but attempted before to do something with tabe % and this is what I was after at that point. Good alternative. – ata Mar 11 '20 at 16:13
This solution has the advantage not scrolling your terminal splits all the way to the bottom when you zoom in on your code and then zoom out (which is what happens to me with C-w+_ and C-w+= – Yordan Grigorov Dec 13 '20 at 15:16
For those that just this without the remap, one way is to `Ctrl+w s` to copy the split into a new buffer, then `Ctrl+w T` to break it out into a new tab. When you're done, just close the new tab and the original layout is restored. – user1717828 Jun 16 '21 at 12:31

ata · Answer 6 · 2020-03-11T16:41:21.893

I wrote one really similar to BenC's version (had not seen it before so it was giggle-worthy to see that one)

I think the only difference is the autocmd that restores the layout if you want to move to another window in the same tab, so it creates an "auto-unzoom" effect:

function! ToggleZoom(toggle)
  if exists("t:restore_zoom") && (t:restore_zoom.win != winnr() || a:toggle == v:true)
      exec t:restore_zoom.cmd
      unlet t:restore_zoom
  elseif a:toggle
      let t:restore_zoom = { 'win': winnr(), 'cmd': winrestcmd() }
      vert resize | resize
  endi
endfunction
nnoremap <silent> <Leader>+ :call ToggleZoom(v:true)<CR>
augroup restorezoom
    au WinEnter * silent! :call ToggleZoom(v:false)
augroup END

score 1 · Answer 7 · answered Jan 27 '23 at 00:29

1

I replaced ZoomWin with the excellent Zen Mode.

answered Jan 27 '23 at 00:29

mxgrn

1,733
16
20

Is better way to zoom windows in Vim than ZoomWin?

7 Answers7