Get distinct attributes for XML nodes

Question

I`ve been trying to get distinct attribute values from the XML: dim i,xmlOx,arr(100) "xmlOx" has following xml structure

  <root>
    <a x="Animal" y="Bird"/>
    <a x="Animal" y="Bird"/>
    <a x="Country" y="Bird"/>
    <a x="Animal" y="Bird"/>
    </root>

asp:

for i=0  xmlOx.selectNodes("a").length-1
 arr(i)=xmlOx(i).selectNodes("a").getAttribute("x")
next

Like,here ive to get "x" attribute values but I dont need duplicates.Then I need to add the values to an array in vbscript.

Please someone tell me how we do it?

score 0 · Answer 1 · edited May 23 '17 at 12:18

0

The theory is here.

Code:

  Dim sXml : sXml = Join(Array( _
      "<root>" _
    , "<a x=""Animal"" y=""Bird""/>" _
    , "<a x=""Animal"" y=""Bird""/>" _
    , "<a x=""Country"" y=""Bird""/>" _
    , "<a x=""Animal"" y=""Bird""/>" _
    , "</root>" _
  ))
  Dim oXDoc : Set oXDoc = CreateObject("Msxml2.DOMDocument")
  oXDoc.loadXml sXml
  WScript.Echo oXDoc.xml

  Dim xObjXml  : Set xObjXml  = oXDoc.documentElement.childNodes
  Dim dicAttrs : Set dicAttrs = CreateObject("Scripting.Dictionary")
  Dim i
  For i = 0 To xObjXml.length - 1
      Dim a : a = xObjXml(i).getAttribute("x")
      dicAttrs(a) = dicAttrs(a) + 1
  Next
  Dim aAttrs : aAttrs = dicAttrs.Keys()
  WScript.Echo Join(aAttrs)

Output:

<root>
        <a x="Animal" y="Bird"/>
        <a x="Animal" y="Bird"/>
        <a x="Country" y="Bird"/>
        <a x="Animal" y="Bird"/>
</root>

Animal Country

edited May 23 '17 at 12:18

Community

1
1

answered Nov 22 '12 at 14:45

Ekkehard.Horner

38,498
2
45
96

Thanks for the answer.Please check my update to the post and reply back please.Use exact variables. – user1495475 Nov 22 '12 at 14:58
@user1495475 - sorry I can't do that, because your code fragment is meaningless. – Ekkehard.Horner Nov 22 '12 at 15:04
I can`t put all the code,so i`ve put some random xml,please see if you can help it. – user1495475 Nov 23 '12 at 05:44
Main Problem is it`s throwing error at "dicAttrs.Keys()" like "Microsoft VBScript runtime (0x800A01A8)Object required". – user1495475 Nov 23 '12 at 06:13

Get distinct attributes for XML nodes

1 Answers1

Linked