What is the difference between lists and arrays?

Question

On this page, it shows how to initialize an array, and if you scroll down a bit, under the section called "The Lists" it "explains" what lists are and how they're different from arrays.

Except it uses an example that's just exactly the same as declaring an array, and doesn't explain it whatsoever.

What is the difference?

Answer 1

Take a look at perldoc -q "list and an array". The biggest difference is that an array is a variable, but all of Perl's data types (scalar, array and hash) can provide a list, which is simply an ordered set of scalars.

Consider this code

use strict;
use warnings;

my $scalar = 'text';
my @array = (1, 2, 3);
my %hash = (key1 => 'val1', key2 => 'val2');

test();
test($scalar);
test(@array);
test(%hash);

sub test { printf "( %s )\n", join ', ', @_ }

which outputs this

(  )
( text )
( 1, 2, 3 )
( key2, val2, key1, val1 )

A Perl subroutine takes a list as its parameters. In the first case the list is empty; in the second it has a single element ( $scalar); in the third the list is the same size as @array and contains ( $array[0], $array[1], $array[2], ...), and in the last it is twice as bug as the number of elements in %hash, and contains ( 'key1', $hash{key1}, 'key2', $hash{key2}, ...).

Clearly that list can be provided in several ways, including a mix of scalar variables, scalar constants, and the result of subroutine calls, such as

test($scalar, $array[1], $hash{key2}, 99, {aa => 1, bb => 2}, \*STDOUT, test2())

and I hope it is clear that such a list is very different from an array.

Would it help to think of arrays as list variables? There is rarely a problem distinguishing between scalar literals and scalar variables. For instance:

my $str = 'string';
my $num = 99;

it is clear that 'string' and 99 are literals while $str and $num are variables. And the distinction is the same here:

my @numbers = (1, 2, 3, 4);
my @strings = qw/ aa bb cc dd /;

where (1, 2, 3, 4) and qw/ aa bb cc dd / are list literals, while @numbers and @strings are variables.

Answer 2

Actually, this question is quite well answered in Perl's FAQ. Lists are (one of) methods to organize the data in the Perl source code. Arrays are one type of storing data; hashes are another.

The difference is quite obvious here:

my @arr = (4, 3, 2, 1);
my $arr_count  = @arr;
my $list_count = (4, 3, 2, 1);

print $arr_count, "\n"; # 4
print $list_count;      # 1

At first sight, there are two identical lists here. Note, though, that only the one that is assigned to @arr variable is correctly counted by scalar assignment. The $list_count stores 1 - the result of evaluating expression with comma operator (which basically gives us the last expression in that enumeration - 1).

Note that there's a slight (but very important) difference between list operators/functions and array ones: the former are kind-of omnivores, as they don't change the source data, the latter are not. For example, you can safely slice and join your list, like this:

print join ':', (4,2,3,1)[1,2]; 

... but trying to 'pop' it will give you quite a telling message:

pop (4, 3, 2, 1);
### Type of arg 1 to pop must be array (not list)...

Answer 3

An array is a type of variable. It contains 0 or more scalars at monotonously increasing indexes. For example, the following creates array @a:

my @a;

Being variables, you can manipulate arrays. You can add elements, change the values of elements, etc.

---

"List" means many things. The two primary uses for it are to refer to list values and instances of the list operator.

A list value is an ordered collection of zero or more scalars on the stack. For example, the sub in the following code returns a list to be assigned to @a (an array).

my @a = f();

List values can't be manipulated; they are absorbed in whole by any operator to which they are passed. They are just how values are passed between subs and operators.

---

The list operator (,) is an N-ary operator* that evaluates each of its operands in turn. In list context, the list operator returns a list consisting of an amalgamation of the lists returned by its operands. For example, the list operator in the following snippet returns a list value consisting of all the elements of arrays @a and @b:

my @c = ( @a, @b );

(By the way, parens don't create lists. They're just there to override precedence.)

You cannot manipulate a list operator since it's code.

---

* — The docs say it's a binary operator (at least in scalar context), but it's not true.

Answer 4

Simple demonstration of difference.

sub getarray{ my @x = (2,4,6); return @x; }

sub getlist { return (2,4,6); }

Now, if you do something like this:

 my @a = getarray();
 my @b = getlist();

Then @a and @b will both contain the same value - the list (2,4,6). However, if you do this:

my $a = getarray();
my $b = getlist();

Then $a will contain the value 3, while $b will contain the value 6.

So yes, you can say that arrays are variables containing list values, but that doesn't tell the whole story, because arrays and literal lists behave quite differently at times.

Answer 5

Lists are comma-separated values (csv) or expressions (cse) . Arrays (and hashes) are containers.

One can initialize an array or hash by a list:

@a = ("profession", "driver", "salary", "2000");
%h = ("profession", "driver", "salary", "2000");

One can return a list:

sub f {
    return "moscow", "tel-aviv", "madrid";
}

($t1, $t2, $t3) = f();
print "$t1 $t2 $t3\n";

($t1, $t2, $t3) is a list of scalar containers $t1, $t2, $t3.

Lists are a form of writing perl expressions (part of syntax) while arrays are data structures (memory locations).

Answer 6

The difference between lists and arrays confuses many. Perl itself got it wrong by misnaming its builtin function wantarray(): "This function should have been named wantlist() instead." There is an answer in perlfaq4, "What is the difference between a list and an array?", but it did not end my confusion.

I now believe these to be true:

• An array in scalar context becomes a count of its elements.
• The comma operator in scalar context returns the last element.
• You can't make a reference to a list; \(2, 4, 6) returns a list of references to the scalars in the list. You can use [2, 4, 6] to make a reference to an anonymous array.
• You can index a list (to get its nth element) without making an array if you make a list slice, so (2, 4, 6)[1] is 4.

But what if I want to count the elements in a list, or get the last element of an array? Should I convert between arrays and lists somehow?

You can always convert a list to an array with [...] syntax. One way to count the elements in a list is to make an anonymous array, then immediately dereference it in scalar context, like so:

sub list { return qw(carrot stick); }
my $count = @{[list()]};
print "Count: $count\n";  # Count: 2

Another way is to use the list assignment operator, like so:

sub list { return qw(carrot stick); }
my $count = (()=list());
print "Count: $count\n";  # Count: 2

There is no array in this code, but the list assignment operator returns the number of things being assigned. I assign them to an empty list of variables. In code golf, I write ()=$str=~/reg/g to count the regular expression matches in some string.

You need not convert an array to a list, because an array in list context is already a list. If you want the last element of an array, just say $array[-1].

The comma operator would return the last element of a list, but I can't use it to get the last element of an array. If I say ((),@array) in scalar context, then @array is in scalar context and I get the count.

You need not make an array to index a list. You can make an anonymous array, as in [list()]->[1], or you can make a list slice, as in (list())[1]. I had trouble with list slices because they have different syntax. A list slice needs parentheses! In C or Python or Ruby, func()[1] would do the array index on the function's return value, but in Perl, func()[1] is a syntax error. You must say (func())[1].

For example, I want to print the 3rd highest number in array. Because I'm lazy, I sort the array and take the 3rd last element:

my @array = (112, 101, 114, 108, 32, 104, 97, 99, 107);
print +(sort { $a <=> $b } @array)[-3], "\n";  # prints 108

The unary + prevents the print() function stealing my parentheses.

You can use a list slice on an array, as in (@array)[1]. This works because an array is a list. The difference between lists and arrays is that arrays can do $array[1].

Answer 7

An Array Vs A List

A list is a different kind of data structure from an array.

The biggest difference is in the idea of direct access Vs sequential access. Arrays allow both; direct and sequential access, while lists allow only sequential access. And this is because the way that these data structures are stored in memory.

In addition, the structure of the list doesn’t support numeric index like an array is. And, the elements don’t need to be allocated next to each other in the memory like an array is.

Arrays

An array is an ordered collection of items, where each item inside the array has an index.

Answer 8

here my answer about sigils and context

but main difference is this:

arrays have a scalar-context-value like count of elements.

lists have a scalar-context-value like LAST element in list.

so, you need to know about goat-operator: =()=.

Usage?

perl -e '$s =()= qw(a b c); print $s' # uh? 3? (3 elements, array context)

perl -e '$s = qw(a b cLastElementThatYouSee); print $s' # uh? cLastElementThatYouSee? (list context, last element returned)

as you see, =()= change context to array