Check type of node in XSL template

Question

Is it possible to check the type of a node I matched with a template inside the same template? In case it is, how can I do it? For example I would like to do something like this:

<xsl:template match="@*|node()">
    <xsl:choose>
        <xsl:when test="current() is an attribute">
        <!-- ... -->
        </xsl:when>
        <xsl:when test="current() is an element">
        <!-- ... -->
        </xsl:when>
        <xsl:otherwise>
        <!-- ... -->
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

Tim has given a nice answer but I wonder why you need to do this inside the template and why you do not just write more specific match patterns with separate templates for the different node types. — Martin Honnen, Jan 02 '13 at 09:46
I am interested in it for educational purposes. I am building an XSL transformation to highlight nodes that are matched by XPath expressions in an XML document. In an actual application I would not do it. — hielsnoppe, Jan 02 '13 at 10:12

score 21 · Accepted Answer · edited May 23 '17 at 11:46

Take a look at this answer here, as this should give you the information you need:

Difference between: child::node() and child::*

This gives the following xsl:choose to test all the nodes, including the document node.

<xsl:choose>
  <xsl:when test="count(.|/)=1">
    <xsl:text>Root</xsl:text>
  </xsl:when>
  <xsl:when test="self::*">
    <xsl:text>Element </xsl:text>
    <xsl:value-of select="name()"/>
  </xsl:when>
  <xsl:when test="self::text()">
    <xsl:text>Text</xsl:text>
  </xsl:when>
  <xsl:when test="self::comment()">
    <xsl:text>Comment</xsl:text>
  </xsl:when>
  <xsl:when test="self::processing-instruction()">
    <xsl:text>PI</xsl:text>
  </xsl:when>
  <xsl:when test="count(.|../@*)=count(../@*)">
    <xsl:text>Attribute</xsl:text>
  </xsl:when>
</xsl:choose>

Good, but you missed namespace nodes. – Dimitre Novatchev Jan 02 '13 at 13:49 — Dimitre Novatchev, Jan 02 '13 at 13:49

score 7 · Answer 2 · answered Apr 04 '14 at 11:20

7

I highly recommend you to use the expressions on sequence types introduced in XPath 2.0. For example:

. instance of document-node()
. instance of element()

answered Apr 04 '14 at 11:20

shapiy

1,117
12
14

as in `` – toddmo Oct 21 '22 at 21:54

score 6 · Answer 3 · answered Jan 02 '13 at 14:00

A more precise way to determine if the node $node is a root node:

not(count($node/ancestor::node()))

The expression in TimC's answer tests the type of the current node:

count(.|/)=1

but isn't applicable in the case when we want to determine the type of a node in a variable -- which may belong to another document -- not to the current document.

Also, a test for a namespace node:

count($node | $node/../namespace::*) = count($node/../namespace::*)

Check type of node in XSL template

3 Answers3

Linked

Related