Delphi: How to know when a TEdit changes size?

Question

i need to update items around an edit box when it changes size.

TEdit has no OnResize event.

An edit box can resize at various times, e.g.:

changing width/height in code
form scaled for DPI scaling
font changed

And i'm sure others i don't know about.

i need a single event to know when an edit box has changed its size. Is there a Windows message i can subclass the edit box for and grab?

You want to fire the OnResize when you change the code? How is that? — Havenard, Sep 14 '09 at 19:30
@Havenard: Ian means if the size changes in code at runtime, not if he actually changes the code at design time. — Bruce McGee, Sep 14 '09 at 21:22

score 9 · Accepted Answer · answered Sep 14 '09 at 19:45

9

OnResize is declared as a protected property of TControl. You could expose it using a so-called "cracker" class. It's a bit of a hack, though.

type
  TControlCracker = class(TControl);

...

procedure TForm1.FormCreate(Sender: TObject);
begin
  TControlCracker(Edit1).OnResize := MyEditResize;
end;

procedure TForm1.MyEditResize(Sender: TObject);
begin
  Memo1.Lines.Add(IntToStr(Edit1.Width));
end;

answered Sep 14 '09 at 19:45

Bruce McGee

15,076
6
55
70

2

Most elegant, and shows off leaky abstraction flaws in most OO libraries. – Ian Boyd Sep 16 '09 at 13:56

score 3 · Answer 2 · answered Sep 14 '09 at 19:45

Did you try something like this:

unit _MM_Copy_Buffer_;

interface

type
  TMyEdit = class(TCustomEdit)
  protected
    procedure Resize; override;
  end;

implementation

procedure TMyEdit.Resize;
begin
  inherited;
  if not (csLoading in ComponentState) then
  begin
    // react on new size
  end;
end;

end.

or this:

unit _MM_Copy_Buffer_;

interface

type
  TCustomComboEdit = class(TCustomMaskEdit)
  private
    procedure WMSize(var Message: TWMSize); message WM_SIZE;
  end;

implementation

procedure TCustomComboEdit.WMSize(var Message: TWMSize);
begin
  inherited;
  if not (csLoading in ComponentState) then
  begin
    // react on new size
  end;
  UpdateBtnBounds;
end;

end.

score 1 · Answer 3 · answered Sep 14 '09 at 20:31

1

Handle the wm_Size message. Subclass a control by assigning a new value to its WindowProc property; be sure to store the old value so you can delegate other messages there.

Delphi: How to know when a TEdit changes size?

3 Answers3

Linked