Prolog - Multiply a list with an element results with a weird tail?

Question

I want to multiply two lists, where I take the left list and multiply it by each element of the right list.

For example:

?- multLists([3,4,2], [4,7,8], R).
R = [[12,16,8],[21,28,14],[24,32,16]].

For that I wrote a helper predicate that takes a list and multiplies it by a single scalar:

multListElem([], _, _).
multListElem([H|T], Result, Elem) :- 
    multListElem(T, W, Elem),
    Z is H*Elem,
    Result = [Z|W].

But now, when I run ?- multListElem([1,2,3], X, 3). I get:

1 ?- multListElem([1,2,3], X, 3).
X = [3, 6, 9|_G1840].

What is that weird tail _G1840?

Please do not change your question! It renders the existing answers useless. — false, Jan 16 '13 at 14:37

score 5 · Accepted Answer · edited May 23 '17 at 12:15

The bug is here: multListElem([],_,_). When the first list is empty, the result is empty, so you must write multListElem([],[],_).

When you work with lists, you can use functional idioms like maplist:

multLists(L1, L2, R) :-
    maplist(mult_one_list(L1), L2, R).

mult_one_list(L1, Elem, R) :-
    maplist(mult_2_numbers(Elem), L1, R).

mult_2_numbers(V1, V2, R) :-
    R is V1 * V2.

maplist applies the first argument to each element of each list (passed to it as an argument).

CapelliC · Answer 2 · 2013-01-12T19:17:53.030

3

your base case leave uninstantiated the tail: change to

multListElem([],[],_).

and it will work.

@Joel76 already addressed your problem, and exposed a better approach using maplist. If you have lambda.pl available here is a compact formula solving the problem

?- maplist(\A^B^maplist(\X^Y^(Y is X*A), [3,4,2], B), [4,7,8], R).
R = [[12, 16, 8], [21, 28, 14], [24, 32, 16]].

edit of course the proper interface would be

multLists(L1, L2, R) :-
    maplist(\A^B^maplist(\X^Y^(Y is X*A), L1, B), L2, R).

The second bug that @false pointed it's difficult to understand but easy to fix:

multLists(L1, L2, R) :-
    maplist(\A^maplist(\X^Y^(Y is X*A), L1), L2, R).

The first bug I would call a feature: it's very useful that lambda works with the closure, and A is declared then... Just my 2 cents...

edited Jan 12 '13 at 19:17

answered Jan 12 '13 at 08:41

CapelliC

59,646
5
47
90

1

A must be declared ; and B can be removed via partial application! – false Jan 12 '13 at 12:38
@false: it's great to learn Prolog with a *great* teacher. Thanks! – CapelliC Jan 12 '13 at 17:58
Use in place of Y is X*A rather than Y = X*A. And use as lists [A,B,C] and [X,Y,Z]: Thus, no ground terms... – false Jan 12 '13 at 19:08

Prolog - Multiply a list with an element results with a weird tail?

2 Answers2