Stop Execution of Batch File after 20 Seconds and move to Next

Question

I have a small script that I got from the net. This script basically reads the information (ip addresses) from a file and pings them and then inserts the results in a text file. This script does exactly what I need but the issue is that instead of ping I need “pathping” which I can change in the script. The issue is that during pathping if there is a delay the script sits for like 3 minutes or maybe 5 minute depending on the response before moving to the next IP address.

All I want is some kind of time out basically maybe like 20 sec and move to the next record regardless of what the response is. Can someone please modify the script below so that the pathping command waits for like 30 sec and then move to the next row of information (independent of what the response is). Any tips or direction would be appreciated…Thanks.

I have checked the timeout -w or -p option does not work.

@echo off
cls
echo PathPing test in progress...

for /F %%i in (iplist.txt) do pathping %%i >> result.txt

echo .
echo .
echo Result is ready.

Thank you very much.

What happens when you use `-w`, like `-w 30000` for 30 seconds. — Bali C, Jan 21 '13 at 16:57
@BaliC: In the built-in help, it says: "-w timeout Wait timeout milliseconds for **each** reply." (emphasis mine) I suspect that `-w 30000` would make the actual delay even longer. — Andriy M, Jan 22 '13 at 07:49
@amirsd: Here's a very rough idea. Run `pathping` with the `start` command and immediately after it run another, internal, loop to check whether the `pathping` has finished (using something like `tasklist | find "pathping"`) or 30 seconds have passed (you could just set up a counter and use 1-second delays between the checks). — Andriy M, Jan 22 '13 at 08:00
i believe the easiest way to do this would be to monitor if the proccess in batch is running period. so make a new batch that 'ping localhost -n 20 >nul' and then 'tasklist /v | find cmd.exe | find (the title of the cmd ex. batch1)' then have it loop that with 'ERRORLEVEL' so 'if %ERRORLEVEL% LSS 1 taskkill cmd.exe' — cmd, May 29 '13 at 17:22

score 0 · Answer 1 · answered Jul 23 '18 at 16:58

I know this is an old post but I hope I can help others in the future. The script bellow will take each address from the iplist.txt file and will pathping each address for only 20 seconds. Each result will then be outputted to the result.txt file.

Now due to how the pathping command works, the only way to "stop" it is by terminating the CMD window it's self. Since you cannot have two lines running at a time due to how batch code is (Unlike C++ for example) we can summon two new windows using the start "" cmd /C "" command.

For each address we summon one pathping window and one taskkill window. The taskill window will use the Task PID # of the pathping window and wait 20 seconds before terminating it.

Mean while, the core batch file will wait 40 seconds for all the files to wright and close. It will then combine all the data into the result.txt file.

@ECHO OFF
@SETLOCAL enableextensions enabledelayedexpansion
@TITLE PathPing from textfile, cancel request for each x after 20s.
@GOTO :Start

:Start

echo WARN: Starting PathPing Script...
echo WARN: This may take some time...
goto :PathPing

:PathPing

:: Large number is for token gathering
set /a number=123456789
for /f "delims== tokens=1,2" %%G in (iplist.txt) do (

    :: Start The pathping's for each %%G
    start "!number!" cmd /C "pathping "%%G" >> "!number!.outputfile""

    :: Start Kill Window (Let process live for 20 seconds)
    FOR /F "tokens=2" %%# in ('tasklist /v ^| find "!number!" ^| find "Console"') do set PID=%%#
    start "" cmd /C "(PING localhost -n 20 >nul) & (taskkill /pid !PID! /t /f & goto :eof)"

    set /a number+=1
)

:: End of FOR statement. Now copy .outputfile to one file.
:: Wait 60 Seconds for the FOR statement to finish copy there files.
PING localhost -n 30 >nul

:: DEL is optional, remove it if you don't with to over-wright text file.
If exist "%~dp0\result.txt" (goto :Del) ELSE (goto :Skip)

:Del
Del /Q "%~dp0\result.txt"
Goto :Skip

:Skip
For %%A In (*.outputfile) DO (for /f "delims== tokens=1,2" %%G in (%%A) do echo %%G >> result.txt)

:: Clean up all .outputfile files.
For %%A In (*.outputfile) DO (DEL /Q "%~dp0\%%A")
Goto :Finish

:Finish
cls
echo WARN: Result is ready.
echo(
pause
goto :eof

Stop Execution of Batch File after 20 Seconds and move to Next

1 Answers1

Linked