Using the Indy TidHttp component to send email file attachments through sendgrid

Question

I am using the Indy TIdHTTP component and am successfully able to send emails via the sendgrid API using the following function. The sendgrid api documentation can be found here.

Now I am tasked with including file attachments. In the API documentation it states: The file contents must be part of the multipart HTTP POST

I have attempted to modify my function to include the TIdMultipartFormDataStream with no success.

How should I modify the code to support file attachments?

procedure SendGridEmailProc;
var
  IdHTTP1: TIdHTTP;
  IdSSLIOHandlerSocket1: TIdSSLIOHandlerSocketOpenSSL;
  mString: string;
  mParams: TStringList;
  i: Integer;
begin
  try
    mParams := TStringList.Create;
    IdHTTP1 := TIdHTTP.create(nil);
    IdSSLIOHandlerSocket1 := TIdSSLIOHandlerSocketOpenSSL.create(nil);
    with IdSSLIOHandlerSocket1 do begin
      SSLOptions.Method := sslvSSLv3;
      SSLOptions.Mode :=  sslmUnassigned;
      SSLOptions.VerifyMode := [];
      SSLOptions.VerifyDepth := 2;
    end;
    with IdHTTP1 do begin
      IOHandler := IdSSLIOHandlerSocket1;
    end;


    mParams.Add('api_user=xxxxx');
    mParams.Add('api_key=xxxxx');
    mParams.Add('to=xxxxxx');
    mParams.Add('from=xxxxx');

    mParams.Add('subject=test:'+datetimetostr(now));

    mParams.Add('text=this is a test');

    IdHTTP1.Post('https://sendgrid.com/api/mail.send.xml',mParams);


  finally
    mParams.Free;
    idhttp1.free;
    IdSSLIOHandlerSocket1.Free;
  end;
end;

Anyway, [SendGrid has SMTP support](http://sendgrid.com/docs/Integrate/index.html), so I'm quite wondering, why are you trying to use web requests for this. — TLama, Jan 29 '13 at 02:03
Good point. Ironically I am porting this from TIdSMTP. Having known they have a SMTP component all I would have needed to do was to substitute some server values and credentials! Anyways, I hope others find this useful. — M Schenkel, Jan 29 '13 at 05:14

TLama · Accepted Answer · 2013-01-29T03:06:17.933

Try to do it this way (note, that it's untested):

uses
  IdException, IdHTTP, IdSSLOpenSSL, IdMultipartFormData;

procedure SendGridEmailProc;
var
  HTTPClient: TIdHTTP;
  Parameters: TIdMultiPartFormDataStream;
  SSLHandler: TIdSSLIOHandlerSocketOpenSSL;
begin
  HTTPClient := TIdHTTP.Create(nil);
  try
    SSLHandler := TIdSSLIOHandlerSocketOpenSSL.Create(nil);
    try
      SSLHandler.SSLOptions.Method := sslvSSLv3;
      SSLHandler.SSLOptions.Mode := sslmUnassigned;
      SSLHandler.SSLOptions.VerifyMode := [];
      SSLHandler.SSLOptions.VerifyDepth := 2;
      HTTPClient.IOHandler := SSLHandler;

      Parameters := TIdMultiPartFormDataStream.Create;
      try
        Parameters.AddFormField('api_user', 'xxxxx');
        Parameters.AddFormField('api_key', 'xxxxx');
        Parameters.AddFormField('to', 'xxxxxx');
        Parameters.AddFormField('from', 'xxxxx');
        Parameters.AddFormField('subject', 'test:' + DateTimeToStr(Now));
        Parameters.AddFormField('text', 'this is a test');

        // note, that you need to use the same file name for the files[]
        // identifier and that you should explicitly specify the content 
        // type for a file field to meet the HTTP dump shown in the help
        Parameters.AddFile('files[file.jpg]', 'c:\file.jpg', 
          'application/octet-stream');

        try
          HTTPClient.Post('https://sendgrid.com/api/mail.send.xml', 
            Parameters);
        except
          on E: EIdException do
            ShowMessage(E.ClassName + ': ' + E.Message);
        end;
      finally
        Parameters.Free;
      end;
    finally
      SSLHandler.Free;
    end;
  finally
    HTTPClient.free;
  end;
end;

I am now trying to get this function to support html based emails. But it is failing (basdically adding a new AddFormField with paramters 'html' and the actual html). Will this not work with html based emails? — M Schenkel, Jan 31 '13 at 00:53
I even wanted to test this code, but I can't, since I don't have own domain, which is needed for successful provisioning of my account (which I've created, when I've been writing this post). So, I'm afraid I won't be able to help you more. But anyway, what is the failure you're getting ? — TLama, Jan 31 '13 at 01:26
Does anyone have an example similar to the above that works with version 3 of SendGrid ? Thanks all :-) — user1355041, Jan 10 '17 at 07:57

Using the Indy TidHttp component to send email file attachments through sendgrid

1 Answers1

Linked