Changing CreateParams dynamically?

Question

I have a custom button component that I have derived from TCustomButton.

To make it ownerdrawn I have overrided the CreateParams like so:

procedure TMyButton.CreateParams(var Params: TCreateParams);
begin
  inherited CreateParams(Params);
  with Params do
  begin
    Style := Style or BS_OWNERDRAW;
  end;
end;

My button works ok with my own painting etc, but what I would like to do is provide a Boolean Property in the Object Inspector which can be used to tell my button whether it should be ownerdrawn or not.

For example, if the Property is enabled the button paints with my own paint routines as an ownerdrawn button, if the Property is toggled off then it should paint as the themed Windows button style (like a regular TButton).

CreateParams tells my button it should be ownerdawn, but I want to provide an option to tell the button whether it should be ownerdrawn or not. By changing the property at designtime or through code at runtime, I want to tell my button whether to ownerdraw or not.

Is this possible to do and if so how?

score 10 · Accepted Answer · answered Feb 06 '13 at 16:54

Adding the property and make CreateParams behave accordingly is not the problem I suppose. Taking the new setting in effect immediately probably is.

Call RecreateWnd when the property is toggled. This will lead to dropping the current Windows handle, and recreating it, including making use of your overriden CreateParams routine.

All in all:

type
  TMyButton = class(TButtonControl)
  private
    FOwnerDraw: Boolean;
    procedure SetOwnerDraw(Value: Boolean);
  protected
    procedure CreateParams(var Params: TCreateParams); override;
  published
    property OwnerDraw: Boolean read FOwnerDraw write SetOwnerDraw
      default False;
  end;

procedure TMyButton.CreateParams(var Params: TCreateParams);
const
  OwnerDraws: array[Boolean] of DWORD = (0, BS_OWNERDRAW);
begin
  inherited CreateParams(Params);
  Params.Style := Params.Style or OwnerDraws[FOwnerDraw];
end;

procedure TMyButton.SetOwnerDraw(Value: Boolean);
begin
  if FOwnerDraw <> Value then
  begin
    FOwnerDraw := Value;
    RecreateWnd;
  end;
end;

David Heffernan · Answer 2 · 2013-02-06T17:13:38.453

6

You can do it like this:

Make an OwnerDraw property.
Test that property in CreateParams and switch behaviour accordingly.
Call RecreateWnd whenever the property changes.

Instead of item 3 you may be able to simply change the window style with a call to SetWindowLong. Do make sure that you test HandleAllocated before attempting to do this. No point forcing the window to be created needlessly. However, you presumably also need to force a paint cycle whenever this happens.

Personally, I think I'd be inclined to force window recreation.

edited Feb 06 '13 at 17:13

answered Feb 06 '13 at 16:56

David Heffernan

601,492
42
1,072
1,490

By `force a paint cycle` do you mean send a invalidate to the control? For what it's worth your answer and NGLN's was exactly what I need to know, RecreateWnd calls the CreateParams and changes it to the native style with a simple check to test the status of the property. – Feb 06 '13 at 17:06
2

`Invalidate` would force a paint cycle. Note that `RecreateWnd` does not call `CreateParams`. It simply destroys the window. When the control next needs a window handle, it will be created, and then `CreateParams` is called. Window handles are created on demand. – David Heffernan Feb 06 '13 at 17:09
I see thanks for clearing that up, looks like I learned yet another keyword today in `RecreateWnd` :) – Feb 06 '13 at 17:10
`RecreateWnd` must be part of Delphi because I found no information on MSDN - it sounded like a Windows API call. Anyway I will accept NGLN's answer as he posted a few minutes before you - though both answers provided the key information that I needed in `RecreateWnd`. – Feb 06 '13 at 18:05
Yes, it's a TWinControl method. – David Heffernan Feb 06 '13 at 18:36

Changing CreateParams dynamically?

2 Answers2