Bugfix for BorderWidth > 0 in combination with a scroll bar?

Question

During writing a custom control, while trying to implement the default BorderWidth property correctly, I seem to have stumbled upon a bug in the painting behaviour when scroll bars are shown: the spaces between the scroll bars and the control's extent are not painted.

To reproduce the bug, implement the following OnCreate handler for the main form of a new project:

procedure TForm1.FormCreate(Sender: TObject);
begin
  AutoScroll := True;
  BorderWidth := 20;
  SetBounds(10, 10, 200, 200);
  with TGroupBox.Create(Self) do
  begin
    SetBounds(300, 300, 50, 50);
    Parent := Self;
  end;
end;

The results for D7 and XE2:

enter image description here

It seems that this is fixed at last in Delphi XE2. Likely, this bug would reside in TWinControl.WMNCPaint, but looking at Controls.pas, I cannot find any significant differences in the implementation between D7 and XE2.

I would like to get answers on:

How to write a bugfix for this oddity,
From which Delphi version this bug seems to be fixed.

score 4 · Accepted Answer · edited Jun 20 '20 at 09:12

4

From which Delphi version fixed?

The search results in QualityCentral on BorderWidth shows that this bug is not reported before. Bug QC 2433 (which was resolved in D2010, update 4) seems related, but from the comments I understand the bug in question does not exist in D2007.

Verification from the community here is more needed though.

How to fix for versions < D2007?

Override the WM_NCPAINT message handler:

  private
    procedure WMNCPaint(var Message: TWMNCPaint); message WM_NCPAINT;

procedure TForm1.WMNCPaint(var Message: TWMNCPaint);
{$IF CompilerVersion < 19}
var
  DC: HDC;
  WindowStyle: Longint;
  TotalBorderWidth: Integer;
{$IFEND}
begin
{$IF CompilerVersion < 19}
  DC := GetWindowDC(Handle);
  try
    WindowStyle := GetWindowLong(Handle, GWL_STYLE);
    if WindowStyle and WS_VSCROLL <> 0 then
      TotalBorderWidth := (Width - ClientWidth - GetSystemMetrics(SM_CXVSCROLL)) div 2
    else
      TotalBorderWidth := (Width - ClientWidth) div 2;
    if WindowStyle and WS_HSCROLL <> 0 then
      FillRect(DC, Rect(0, Height - TotalBorderWidth, Width, Height), Brush.Handle);
    if WindowStyle and WS_VSCROLL <> 0 then
      FillRect(DC, Rect(Width - TotalBorderWidth, 0, Width, Height), Brush.Handle);
  finally
    ReleaseDC(Handle, DC);
  end;
{$IFEND}
  inherited;
end;

The two drawn rects are intentionally too large, giving better results at resizing.

edited Jun 20 '20 at 09:12

Community

1
1

answered Feb 10 '13 at 13:29

NGLN

43,011
8
105
200

2

Not able to duplicate with D2007. – Sertac Akyuz Feb 10 '13 at 13:35
@Ser But you dó have the bug from [QC 2433](http://qc.embarcadero.com/wc/qcmain.aspx?d=2433)? – NGLN Feb 10 '13 at 13:44
I'm not sure. When I set the color before the form is shown, then there's no problem. If I change it at runtime, borders do not comply with the new color. Resizing, as told in the report, causes the borders to be painted with the correct color. – Sertac Akyuz Feb 10 '13 at 13:48
@Ser That's the bug. Well, then this from OP is another one. – NGLN Feb 10 '13 at 13:55
@NGLN - I disagree, the report has no mention of changing the color after the form is shown. But I'd easily agree that they're connected.. – Sertac Akyuz Feb 10 '13 at 13:59
Same bug with D5. But no `Self.TotalBorderWidth` there. – kobik Feb 10 '13 at 14:27
@kobik Ah tanks, that was sloppy of me. Fixed. – NGLN Feb 10 '13 at 16:54
@NGLN, Cool, but I would call `GetWindowLong` only one time. – kobik Feb 10 '13 at 17:05
Can use `[Horz|Vert]ScrollbarVisible` instead of style checking? – Sertac Akyuz Feb 10 '13 at 17:23
1

@Ser `TControlScrollBar.IsScrollBarVisible` does the same. But I didn't use that because this fix shouldn't only work for `TScrollingWinControl` descendants, but for every `TWinControl` descendant. – NGLN Feb 10 '13 at 18:26
1

@kobik Yes, that's better. Done. – NGLN Feb 10 '13 at 18:45

Bugfix for BorderWidth > 0 in combination with a scroll bar?

1 Answers1

From which Delphi version fixed?

How to fix for versions < D2007?

Linked