Replacement for "If object = Nothing Then" in Strict Mode VB.NET

Question

I have a function which has a selectedID parameter of type "object".

If my parameter is the default for the underlying type: i.e. Integer default is zero, I want some action to take place.

Without "Strict On", I can use:

If selectedID = Nothing Then
    'Do Something
End If

Do I have to do something like:

If (TypeOf selectedID Is Integer AndAlso selectedID.Equals(0)) _
OrElse (TypeOf selectedID Is String AndAlso selectedID.Equals(Nothing)) _
OrElse .. other types go here .. Then
    'Do something
End If

Or is there a simpler method that I'm missing?

The underlying helper method is Microsoft.VisualBasic.CompilerServices.Operators::ConditionalCompareObjectEqual(). There is an *enormous* amount of code underneath it. — Hans Passant, Feb 25 '13 at 17:52
@MarcinJuraszek yes I did, but 0 is not nothing, so that doesn't work. — Jonathan, Feb 26 '13 at 08:52
Checking for `selectedID` equals `0` by writing `selectedID = Nothing` is something really aberrant. — Teejay, Feb 26 '13 at 13:33

Jonathan · Accepted Answer · 2013-03-22T11:01:15.497

I eventually implemented Neolisk's suggestion, which had the advantage of being short, all-encompassing and very re-usable:

Public Function IsDefaultObject(obj As Object) As Boolean
    Return obj.Equals(GetDefaultValue(obj.GetType()))
End Function

Public Function GetDefaultValue(t As Type) As Object
    If (t.IsValueType) Then Return Activator.CreateInstance(t)
    Return Nothing
End Function

I originally went with the solution of creating a function IsDefaultObject(obj) which tells me if an object has had a default value assigned. I planned to add to it as more types got noticed.

Private Function IsDefaultObject(obj As Object) As Boolean
    If obj Is Nothing Then Return True
    If String.IsNullOrEmpty(obj.ToString()) Then Return True
    If obj.Equals(0) Then Return True
    If obj.Equals(New Date()) Then Return True
    Return False
End Function

Of course, I could have used the solution in Hans Passant's comment:

Private Function IsDefaultObject(obj As Object) As Boolean
    Return Microsoft.VisualBasic.CompilerServices.Operators.
        ConditionalCompareObjectEqual(obj, Nothing, False)
End Function

I get your struggle here, and see why you went with the above clunky approach. However, can you indicate why utilizing ConditionalCompareObjectEqual(), as Hans Passant suggests, isn't suitable? — rskar, Feb 26 '13 at 14:00
It is imminently suitable, but I didn't realise it. I assumed that it was inaccessible, and that Hans was just letting me know that a lot of work had been done on functionality that I couldn't use. — Jonathan, Feb 26 '13 at 15:46

score -1 · Answer 2 · answered Feb 26 '13 at 13:21

-1

You can also use a nullable type for this.

Dim selectedID As Integer? = nothing

...

if selectedID isnot nothing then

    dim value as integer = selectedID.value
    ...

end if

Another way you can check the nullable type has been assigned a value.

if selectedID.hasValue = true then

   dim value as integer = selectedID.value
   ...

end if

answered Feb 26 '13 at 13:21

Ceres

3,524
3
18
25

Sadly, I can't guarantee it'll be an integer. It may be a date or a string, or some other type entirely. – Jonathan Feb 26 '13 at 15:38

Replacement for "If object = Nothing Then" in Strict Mode VB.NET

2 Answers2