objselection.font.name changes to calibri

Question

I've got a bit of a problem that is giving me a headache. I've built a VBScript signature creation script to pull user information from AD and apply it as a signature for all of our users. It works beautifully and I am very happy with it. Except for one problem. I have searched and - while I have found someone else with the same issue - I have not been able to find any solution.

---

First, some background about the script:

The script is setup to use the following object to configure the signature, as per Microsoft's article here.

Word.Application.EmailOptions.EmailSignature.EmailSignatureEntries

Then, throughout the script, I have to change the font several times. To do that I use lines like this:

objSelection.Font.Name = "Times New Roman"

This works just fine for me and most of our users. However, one of my technicians had previously changed his default font in Word to Times New Roman. When I run the script for him, the lines that are supposed to be TNR, instead appear as Calibri. As we are running Office 2007, the original default font in Word is Calibri. I tested changing the default font on my own PC and another PC and I was able to duplicate the problem both times.

The technet poster I linked to earlier noted that the original document had all of the fonts correct. It was only when "EmailSignatureEntries" saved it to RTF and HTML to be used as a signature that the fonts got mixed up.

I'm really stumped on this. Any help would be appreciated! :)

Answer 1

I stumbled upon the same problem while creating a new, auto AD populated, signature for my company. From what I've found on the internet, and what also suggest, is that the problem occurs when the signature is being made in the same font as Word has in it's Normal.dot(m).

For example; My company wanted Arial 10 as default font in Word, Excel and Outlook. So of course I modified all the needed files and arranged a GPO to accomplish this. Everything went ok and Word etc had Arial as default Font.

Now when I ran my signature.vbs script which also stated that the font should be Arial the outcome would always be Calibri as font strangely enough. I played around with this for a bit and noticed I could use any other font than Arial and it would work, except for Arial.

This was driving me nuts for 2 days and then it hit me; - What if i place a Temporary normal.dot(m) (with Calibri as default font) in the userprofile, THEN create the signature with VBS and THEN place the proper Normal.dot(m) in the profile?

As it turns out, this did the trick. So I took out the file placement GPO for Normal.dot(m) and integrated the temporary copy, run vbs, final copy, in my batchscript which also fired the signature.vbs.

Here is my code for the batch which you will probably have to adapt to your own needs but it gives the basic idea. I've added an English translation of the remarks so you won't have to learn Dutch:)

Hope this helps you and anyone still looking for a 'solution'.

@echo off
REM Verwijder alle default word templates in het userprofile (niet meer via GPO)
REM Remove all default Word templates in the userprofile (no longer through GPO)
DEL /F /Q %userprofile%\AppData\Roaming\Microsoft\Sjablonen\Normal.dotm
DEL /F /Q %userprofile%\AppData\Roaming\Microsoft\Templates\Normal.dotm
DEL /F /Q %userprofile%\AppData\Roaming\Microsoft\Sjablonen\NormalEmail.dotm
DEL /F /Q %userprofile%\AppData\Roaming\Microsoft\Templates\NormalEmail.dotm

REM Check of het Handtekeningscript al gelopen heeft, zoja ga over tot plaatsen juiste normal.dotm
REM Check if the signaturescript already ran, if so copy the proper normal.dotm
IF EXIST %homeshare%\pvfsig.txt goto copynormal

REM Plaats een tijdelijke Normal.dotm ivm een conversie issue als je default Arial hebt (wordt Calibri)
REM Copy a temporary Normal.dotm in the profile so the conversion problem with the Default font won't occur.
COPY /Y /Z \\pvf\netlogon\Scripts\huisstijl\normal_met_calibri\Normal.dotm %userprofile%\AppData\Roaming\Microsoft\Sjablonen\Normal.dotm
COPY /Y /Z \\pvf\netlogon\Scripts\huisstijl\normal_met_calibri\Normal.dotm %userprofile%\AppData\Roaming\Microsoft\Templates\Normal.dotm
COPY /Y /Z \\pvf\netlogon\Scripts\huisstijl\normal_met_calibri\NormalEmail.dotm %userprofile%\AppData\Roaming\Microsoft\Sjablonen\NormalEmail.dotm
COPY /Y /Z \\pvf\netlogon\Scripts\huisstijl\normal_met_calibri\NormalEmail.dotm %userprofile%\AppData\Roaming\Microsoft\Templates\NormalEmail.dotm

REM Start Handtekening VBS script om de handtekening te genereren
REM Start signature VBS script to generate the signature
cscript \\pvf\netlogon\scripts\huisstijl\outlooksig_new.vbs

REM Verwijder tijdelijke Normal.dotm bestanden
REM Remove the temporary Normal.dotm files
DEL /F /Q %userprofile%\AppData\Roaming\Microsoft\Sjablonen\Normal.dotm
DEL /F /Q %userprofile%\AppData\Roaming\Microsoft\Templates\Normal.dotm
DEL /F /Q %userprofile%\AppData\Roaming\Microsoft\Sjablonen\NormalEmail.dotm
DEL /F /Q %userprofile%\AppData\Roaming\Microsoft\Templates\NormalEmail.dotm

REM Creeer een check bestand op de Homedirectory v/d gebruiker
REM Create a checkfile in the users homedirectory
echo pvf standaard handtekening is aangemaakt > %homeshare%\pvfsig.txt

REM Kopieeren van juiste normal.dotm bestanden (met Arial)
REM Copy the proper normal.dotm files into place
:copynormal
COPY /Y /Z \\pvf\netlogon\Scripts\huisstijl\normal_pvf_huisstijl\Normal.dotm %userprofile%\AppData\Roaming\Microsoft\Sjablonen\Normal.dotm
COPY /Y /Z \\pvf\netlogon\Scripts\huisstijl\normal_pvf_huisstijl\Normal.dotm %userprofile%\AppData\Roaming\Microsoft\Templates\Normal.dotm
COPY /Y /Z \\pvf\netlogon\Scripts\huisstijl\normal_pvf_huisstijl\NormalEmail.dotm %userprofile%\AppData\Roaming\Microsoft\Sjablonen\NormalEmail.dotm
COPY /Y /Z \\pvf\netlogon\Scripts\huisstijl\normal_pvf_huisstijl\NormalEmail.dotm %userprofile%\AppData\Roaming\Microsoft\Templates\NormalEmail.dotm

:end
EXIT