grails validate nested command object not working

Question

I'm using grails 2.2.1 and attempting to validate a nested command structure. Here is a simplified version of my command objects:

@Validateable
class SurveyCommand {

    SectionCommand useful
    SectionCommand recommend

    SurveyCommand() {
        useful = new SectionCommand(
                question: 'Did you find this useful?',
                isRequired: true)
        recommend = new SectionCommand(
                question: 'Would you recommend to someone else?',
                isRequired: false)
    }
}

@Validateable
class SectionCommand {
    String question
    String answer
    boolean isRequired

    static constraints = {
        answer(validator: answerNotBlank, nullable: true)
    }

    static answerNotBlank = { String val, SectionCommand obj ->
        if(obj.isRequired) {
            return val != null && !val.isEmpty()
        }
    }
}

When I try to validate an instance of SurveyCommand it always returns true no matter the section values and my custom validator in SectionCommand (answerNotBlank) is never called. From the grails documentation, it seems that this kind of nested structure is supported (deepValidate defaults to true). However, maybe this rule only applies to domain objects and not Command objects? Or am I just missing something here?

score 6 · Answer 1 · edited Aug 03 '15 at 13:06

6

For Grails 2.3 and later I've found that the Cascade Validation Plugin solves this problem nicely. It defines a new validator type called cascade which does exactly what you'd expect. Once installed your example would become:

class SurveyCommand {
    ...

    static constraints = {
        useful(cascade: true)
        recommend(cascade: true)
    }
}

edited Aug 03 '15 at 13:06

gogognome

727
8
24

answered Jan 18 '15 at 22:43

jgibson

1,013
11
9

The only available version right now is: `compile ":cascade-validation:0.1.4"` – chill appreciator Dec 30 '20 at 13:08
When running a unit test, the cascade constraint isn't registered with grails. To work around this issue, the following code must be added to the setup() method of the test: `ConstrainedProperty.registerNewConstraint(CascadeValidationConstraint.NAME, CascadeValidationConstraint)`. Source: https://github.com/rmorrise/grails-cascade-validation – chill appreciator Jan 02 '21 at 23:07

score 4 · Accepted Answer · answered Apr 24 '13 at 02:41

You could add a custom validator to your main command object

@Validateable
class SurveyCommand {

    SectionCommand useful
    SectionCommand recommend

    static subValidator = {val, obj ->
        return val.validate() ?: 'not.valid'
    }

    static constraints = {
        useful(validator: subValidator)
        recommend(validator: subValidator)
    }

    SurveyCommand() {
        useful = new SectionCommand(
            question: 'Did you find this useful?',
            isRequired: true)
        recommend = new SectionCommand(
            question: 'Would you recommend to someone else?',
            isRequired: false)
    }
}

nice! works great, however is there a more DRY way instead of explicitly defining a constraint for each sub property? — Chris Montgomery, Apr 24 '13 at 15:29

score 2 · Answer 3 · edited May 23 '17 at 12:02

2

If you are trying to test validation from unit tests using mockForConstraintsTest() then you should register the command objects inConfig.groovy instead of using @Validateable because of an existing Grails Bug. Refer this SO question/answers for details.

You can register the validateable class as below in Config.groovy

grails.validateable.classes = 
           [yourpackage.SurveyCommand, yourpackage.SectionCommand]

edited May 23 '17 at 12:02

Community

1
1

answered Apr 24 '13 at 05:26

dmahapatro

49,365
7
88
117

it *seems* to work fine (in 2.2.1) to test a `@Validatable` command class's `.validate()` method by simply calling `mockCommandObject` before instantiating it, e.g. `mockCommandObject SurveyCommand` – Chris Montgomery Apr 24 '13 at 15:26
Agree. That was my approach to the SO question/answer I mentioned earlier. `mockCommandObject` works but `mockForConstraintsTest` fails. – dmahapatro Apr 24 '13 at 15:31
ah, got it, thanks for clarifying. Obviously I didn't read close enough – Chris Montgomery Apr 24 '13 at 15:36

grails validate nested command object not working

3 Answers3

Linked