TIdHTTP exception handling

Question

I created a program that automatically connects to our local server and downloads updates, here is the code:

// Connect to web server and download ToBeInstalled.ini
Url := 'http://'+IPAdd+'/ToBeInstalled.ini';
MS := TMemoryStream.Create
  try
    try
      http.Get(url, MS);
      code := http.ResponseText;
    except
      on E: EIdHTTPProtocolException do
        code := http.ResponseCode; 
    end;
    MS.SaveToFile(UserPath + 'ToBeInstalled.ini');
  finally
    http.Free();
  end;

The program works quite well while in the office but when users are home and cannot reach the server or the server is not available the get "socket error # 10061'

enter image description here

I have no idea how to catch that one and the worse is that the program stop execution all together after that error message is displayed. Do you have any idea how to fix that. Thank you so much.

You should better use a file stream if all you do is saving the data to a file. The only downside is that you have to take care of a 0-byte-file in case the request fails. — maf-soft, Nov 05 '18 at 14:39

score 11 · Accepted Answer · answered Apr 28 '13 at 23:02

Your exception handler is only catching EIdHTTPProtocolException exceptions specifically, but there are several other types of exceptions that can be raised as well, including EIdSocketError. You need to update your handler accordingly, or just have it catch all possible exceptions instead of looking for specific types. Since you say an uncaught exception caused your entire app to fail (which means you have bigger problems to deal with than just TIdHTTP), you should also update the code to handle exceptions raised by TMemoryStream as well.

Try this:

// Connect to web server and download ToBeInstalled.ini
Url := 'http://'+IPAdd+'/ToBeInstalled.ini';
try
  MS := TMemoryStream.Create
  try
    http.Get(url, MS);
    code := http.ResponseText;
    MS.SaveToFile(UserPath + 'ToBeInstalled.ini');
  finally
    MS.Free;
  end;
except
  on E: EIdHTTPProtocolException do begin
    code := http.ResponseCode; 
  end;
  on E: Exception begin
    // do something else
  end;
end;

Something more about `TIdHTTP` exceptions you may find [`here`](http://stackoverflow.com/a/13954599/960757). [+1] — TLama, Apr 29 '13 at 06:46

score 0 · Answer 2 · answered Oct 16 '22 at 10:25

I used this way:

uses
  IdStack, IdStackConsts;

  Result.ResponseCode:= -1;
  try
    Result.Content:= FHTTP.Get(Url);   
    Result.ResponseCode:= FHTTP.ResponseCode;
  except
    on E: EIdSocketError do
        begin
          case e.LastError of
            Id_WSAETIMEDOUT:
              begin
                Result.ResponseCode:= 408;
                Result.Message:= 'زمان ارتباط به پایان رسید';
              end;
            Id_WSAEACCES:
              begin
                Result.ResponseCode:= 403;
                Result.Message:= 'دسترسی وجود ندارد';
              end;
            else
              begin
                Result.ResponseCode:= e.LastError;
                Result.Message:= e.Message;
              end;
          end;
        end;
      on E: Exception do
        Result.Content:= E.ClassName + ': ' + E.Message;
  end;

TIdHTTP exception handling

2 Answers2

Linked

Related