Split text file into 2 files by separator

Question

I am looking for a simple batch script that split my text file into two files. The text file is separated by with

============================================================================

Text file looks like this:

test
test1
test2
test5
test
test1
test2
test5
============================================================================
test
test1
test2
test5
test
test1

Endoro · Accepted Answer · 2013-05-17T07:56:14.550

3

try this:

@echo off&setlocal
set "file=file.txt"
for /f "delims=[]" %%i in ('^<"%file%" find /n "="') do set "split=%%i"
(for /f "tokens=1*delims=[]" %%i in ('^<"%file%" find /n /v ""') do if %%i lss %split% echo(%%j)>"%file%.new1"
<"%file%">"%file%.new2" more +%split%
type "%file%.new?"

..output is:

file.txt.new1


test
test1
test2
test5
test
test1
test2
test5

file.txt.new2


test
test1
test2
test5
test
test1

edited May 17 '13 at 07:56

answered May 17 '13 at 07:14

Endoro

37,015
8
50
63

I try to run this batch file but when I execute it, it hangs. I have to terminate it when I want to stop the executing. – user1809753 May 17 '13 at 07:32
This is a "bug" in `findstr`, your input file must end with a `CR/LF` on the very last line. – Endoro May 17 '13 at 07:34
I made an edit, the code now uses `find` and I hope, this will work for you. – Endoro May 17 '13 at 07:57
What if I want to split file by words not a full line? – Bharat Jan 08 '16 at 07:09

npocmaka · Answer 2 · 2013-05-17T07:46:26.930

2

@echo off
set /p file=FILE TO PROCESS : 
del /q /f out.file*
setlocal enableDelayedExpansion
set out_file_counter=1
for /f "usebackq delims=" %%L in ("%file%") do (
 set line=%%L
 if "!line:~0,5!" equ "=====" (
    set /a out_file_counter=out_file_counter+1

 ) else (
   echo !line!>>out.file.!out_file_counter!
  )
)
endlocal

edited May 17 '13 at 07:46

answered May 17 '13 at 07:09

npocmaka

55,367
18
148
187

Thank you for your reply. When I run this file, I'm not get any output. – user1809753 May 17 '13 at 07:35
you should change `(myfile.txt)` with your file path... – npocmaka May 17 '13 at 07:37
I've changed the script a little bit to be more easier for use – npocmaka May 17 '13 at 07:46

Split text file into 2 files by separator

2 Answers2

Linked