Hiding focusRectangle for a StringGrid : Delphi

Question

I'm trying to hide the border (focus rectangle) which Delphi draws around the currently selected cell in a StringGrid. I'm doing owner drawing to customize the appearance of the string grid. I've managed to get rid of everything but the selection.

I was using

 GR.Left := -1;
 GR.Top  := -1;
 GR.Right := -1;
 GR.Bottom := -1;
 StringGrid.Selection := GR;

But that gives errors if you set this really fast (I have this running in onMouseMove). What I mean by that is it works fine, but if I call this particular chunk of code fast enough I get an exception in the rendering of the StringGrid (thus I can't just chuck an try except around it).

Any ideas on how I can solve this reliably?

Hello Daietsu, have you tried TZColorStringGrid? It is a descendant of TStringGrid and it has abilities to personalize each cell. Maybe you can have a look: http://avemey.com/ — Cristian Vasuica, May 23 '13 at 08:00

score 3 · Answer 1 · answered May 23 '13 at 10:24

You can use a interposer class for TStringgrid and override the Paint procedure to remove a drawn focus rect.

unit Unit2;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, Grids;

type
  TStringgrid=Class(Grids.TStringGrid)
  private
    FHideFocusRect: Boolean;
  protected
     Procedure Paint;override;
  public
     Property HideFocusRect:Boolean Read FHideFocusRect Write FHideFocusRect;
  End;
  TForm2 = class(TForm)
    StringGrid1: TStringGrid;
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
  public
  end;

var
  Form2: TForm2;

implementation

{$R *.dfm}

procedure TStringgrid.Paint;
var
 L_Rect:Trect;
begin
  inherited;
   if HideFocusRect then
      begin
       L_Rect := CellRect(Col,Row);
       if DrawingStyle = gdsThemed then InflateRect(L_Rect,-1,-1);
       DrawFocusrect(Canvas.Handle,L_Rect)
      end;
end;

procedure TForm2.Button1Click(Sender: TObject);
begin
   StringGrid1.HideFocusRect := not StringGrid1.HideFocusRect;
end;

end.

Hi. Does not work for me. Any explanations on why InflateRect -1 should work? — Gabriel, Sep 05 '22 at 06:42

score 1 · Answer 2 · answered Mar 31 '15 at 01:28

In the OnDrawCell event add

with Sender as TStringgrid do
begin
    if (gdSelected in State) then
    begin
        Canvas.Brush.Color := Color;
        Canvas.Font.Color := Font.Color;
        Canvas.TextRect(Rect, Rect.Left +2,Rect.Top +2, Cells[Col,Row]);
    end;
end;

In the OnSelectCell event add

CanSelect := False

Wellington Telles Cunha · Answer 3 · 2021-11-24T19:10:01.200

1

Inside Stringrid properties change TabOrder to -1 and HitTest to False

edited Nov 24 '21 at 19:10

answered Nov 24 '21 at 18:48

Wellington Telles Cunha

326
2
16

HitTest is in Firemonkey. VCL StringGrid doesn't have that. – Eitan Arbel Jul 06 '22 at 19:14

score 0 · Answer 4 · answered Aug 21 '15 at 23:33

Set DefaultDrawing property to false and onDrawCell event draw the text something like this (this also alternates row color and center text in cell):

procedure GridDrawCell(Sender: TObject; ACol,ARow: Integer; Rect: TRect; State: TGridDrawState);
var S: string;
        c:TColor;
        SavedAlign: word;
begin
  S := Grid.Cells[ACol, ARow];
  SavedAlign := SetTextAlign(Grid.Canvas.Handle,TA_CENTER); 
  if (ARow mod 2 = 0)
  then c:=clWhite
  else c:=$00E8E8E8;
  // Fill rectangle with colour
  Grid.Canvas.Brush.Color := c;
  Grid.Canvas.FillRect(Rect);
  // Next, draw the text in the rectangle
  if (ACol=1) or (ACol=3) or (ACol=5) then
  begin
    Grid.Canvas.Font.Color := $005F5F5F; 
  end
  else
  begin
    Grid.Canvas.Font.Color := $005F5F5F;
  end;
    Grid.Canvas.TextRect(Rect,Rect.Left + (Rect.Right - Rect.Left) div 2, Rect.Top + 2, S);
    SetTextAlign(Grid.Canvas.Handle, SavedAlign);
end;

Hiding focusRectangle for a StringGrid : Delphi

4 Answers4