groovy upload jar to nexus

Question

I have some jar file (custom) which I need to publish to Sonatype Nexus repository from Groovy script.

I have jar located in some path on machine where Groovy script works (for instance: c:\temp\module.jar).

My Nexus repo url is http://:/nexus/content/repositories/

On this repo I have folder structure like: folder1->folder2->folder3

During publishing my jar I need to create in folder3:

1. New directory with module's revision (my Groovy script knows this revision)
2. Upload jar to this directory
3. Create pom, md5 and sha1 files for jar uploaded

After several days of investigation I still have no idea how to create such script but this way looks very clear instead of using direct uploading.

I found http://groovy.codehaus.org/Using+Ant+Libraries+with+AntBuilder and some other stuff (stackoverflow non script solution).

I got how to create ivy.xml in my Groovy script, but I don't understand how to create build.xml and ivysetting.xml on the fly and setup whole system to work.

Could you please help to understand Groovy's way?

UPDATE: I found that the following command works fine for me:

curl -v -F r=thirdparty -F hasPom=false -F e=jar -F g=<my_groupId> -F a=<my_artifactId> -F v=<my_artifactVersion> -F p=jar -F file=@module.jar -u admin:admin123 http://<my_nexusServer>:8081/nexus/service/local/repositories

As I understand curl perform POST request to Nexus services. Am I correct?

And now I'm trying to build HTTP POST request using Groovy HTTPBuilder.

How I should transform curl command parameters into Groovy's HTTPBuilder request?

Answer 1

Found a way to do this with the groovy HttpBuilder.

based on info from sonatype, and a few other sources.

This works with http-builder version 0.7.2 (not with earlier versions) And also needs an extra dependency: 'org.apache.httpcomponents:httpmime:4.2.1'

The example also uses basic auth against nexus.

import groovyx.net.http.Method
import groovyx.net.http.ContentType;
import org.apache.http.HttpRequest
import org.apache.http.HttpRequestInterceptor
import org.apache.http.entity.mime.MultipartEntity
import org.apache.http.entity.mime.content.FileBody
import org.apache.http.entity.mime.content.StringBody
import org.apache.http.protocol.HttpContext
import groovyx.net.http.HttpResponseException;

class NexusUpload {
  def uploadArtifact(Map artifact, File fileToUpload, String user, String password) {
    def path = "/service/local/artifact/maven/content"
    HTTPBuilder http = new HTTPBuilder("http://my-nexus.org/")
    String basicAuthString = "Basic " + "$user:$password".bytes.encodeBase64().toString()

    http.client.addRequestInterceptor(new HttpRequestInterceptor() {
      void process(HttpRequest httpRequest, HttpContext httpContext) {
        httpRequest.addHeader('Authorization', basicAuthString)
      }
    })
    try {
      http.request(Method.POST, ContentType.ANY) { req ->
        uri.path = path

      MultipartEntity entity = new MultipartEntity()
      entity.addPart("hasPom", new StringBody("false"))
      entity.addPart("file", new FileBody(fileToUpload))
      entity.addPart("a", new StringBody("my-artifact-id"))
      entity.addPart("g", new StringBody("my-group-id"))
      entity.addPart("r", new StringBody("my-repository"))
      entity.addPart("v", new StringBody("my-version"))
      req.entity = entity

      response.success = { resp, reader ->
        if(resp.status == 201) {
          println "success!"
        }
      }
    }

    } catch (HttpResponseException e) {
      e.printStackTrace()
    }
  }
}

`

Answer 2

Ivy is an open source library, so, one approach would be to call the classes directly. The problem with that approach is that there are few examples on how to invoke ivy programmatically.

Since groovy has excellent support for generating XML, I favour the slightly dumber approach of creating the files I understand as an ivy user.

The following example is designed to publish files into Nexus generating both the ivy and ivysettings files:

import groovy.xml.NamespaceBuilder
import groovy.xml.MarkupBuilder

// Methods
// =======
def generateIvyFile(String fileName) {
    def file = new File(fileName)

    file.withWriter { writer ->
        xml = new MarkupBuilder(writer)

        xml."ivy-module"(version:"2.0") {
            info(organisation:"org.dummy", module:"dummy")
            publications() {
                artifact(name:"dummy", type:"pom")
                artifact(name:"dummy", type:"jar")
            }
        }
    }

    return file
}

def generateSettingsFile(String fileName) {
    def file = new File(fileName)

    file.withWriter { writer ->
        xml = new MarkupBuilder(writer)

        xml.ivysettings() {
            settings(defaultResolver:"central")
            credentials(host:"myrepo.com" ,realm:"Sonatype Nexus Repository Manager", username:"deployment", passwd:"deployment123")
            resolvers() {
                ibiblio(name:"central", m2compatible:true)
                ibiblio(name:"myrepo", root:"http://myrepo.com/nexus", m2compatible:true)
            }
        }
    }

    return file
}

// Main program
// ============
def ant = new AntBuilder()
def ivy = NamespaceBuilder.newInstance(ant, 'antlib:org.apache.ivy.ant')

generateSettingsFile("ivysettings.xml").deleteOnExit()
generateIvyFile("ivy.xml").deleteOnExit()

ivy.resolve()
ivy.publish(resolver:"myrepo", pubrevision:"1.0", publishivy:false) {
    artifacts(pattern:"build/poms/[artifact].[ext]")
    artifacts(pattern:"build/jars/[artifact].[ext]")
}

Notes:

• More complex? Perhaps... however, if you're not generating the ivy file (using it to manage your dependencies) you can easily call the makepom task to generate the Maven POM files prior to upload into Nexus.
• The REST APIs for Nexus work fine. I find them a little cryptic and of course a solution that uses them cannot support more than one repository manager (Nexus is not the only repository manager technology available).
• The "deleteOnExit" File method call ensures the working files are cleaned up properly.