Forcing a list context in Perl

Question

I'm trying to understand Perl context and I tripped over a rock;

Given the code;

#!/usr/bin/perl

my $b = (33,22,11);
print "$b\n";

my $b = () = (33,22,11);
print "$b\n";

my @b = (33,22,11);
print "@b\n";

my @b = () = (33,22,11);
print "@b\n";

The results are (the last line is blank);

 11  

 3 

 33 22 11

 <>

Since the 2nd print returned the length of the list I was assuming that somewhere an array was generated since an array in a scalar context evaluates to its length. But the 4th print seems to belie that assumption. I was expecting to see '33 22 11' printed but got nothing instead. What's happening here?

Answer 1

You're confused because you think = is a single operator while it can result in two different operators: a list assignment operator or a scalar assignment operator. Mini-Tutorial: Scalar vs List Assignment Operator explains the differences.

my $b = (33,22,11);
------------------            Scalar assign in void context.
        ----------            List literal in scalar context. Returns last.

my @b = (33,22,11);
------------------            List assign in void context.
        ----------            List literal in list context. Returns all.

my $b = ( () = (33,22,11) );
---------------------------   Scalar assign in void context.
        -------------------   List assign in scalar context. Returns count of RHS
               ----------     List literal in list context. Returns all.

my @b = ( () = (33,22,11) );
---------------------------   List assign in void context.
        -------------------   List assign in list context. Returns LHS.
               ----------     List literal in list context. Returns all.

---

As for your title, forcing list context is impossible per se. If a function returns a list when a scalar is expected, it results in extra values on the stack, which leads to operators getting the wrong arguments.

You can, however, do something like:

( EXPR )[0]

or

( EXPR )[-1]

EXPR will be called in list context, but the whole will return just one element of the returned list.

Answer 2

List assignment in scalar context returns the number of elements on the right hand side (case 2). The case 4 first assigns (33, 22, 11) to (), and then assigns () (whose value has not changed) to @b.

Answer 3

Answering the implicit question in the title:

Perl provides a scalar builtin to force scalar context when it would not otherwise be used; a similar list builtin doesn't exist, I imagine largely because it could mean a number of different things, e.g.:

list { code to execute in list context };

might be defined:

sub list (&) { scalar( () = $_[0]->() ) } # return count of elements
sub list (&) { ( $_[0]->() )[0] } # return first element
sub list (&) { ( $_[0]->() )[-1] } # return last element
sub list (&) { for( $_[0]->() ) {} } # return nothing

Answering the body of the question:

When confused by context, remember that operators impose context on operands, not the reverse. In your problem case, you have a scalar assignment, assigning to a scalar the result of a list assignment, which puts the list assignment in a scalar context. To know what happens, simply look up what the list assignment will return in scalar context. (In general, operators return what makes the most common sense, which means there isn't an easy to remember rule that applies to all operators.)