How can I resolve MSI paths in VBScript?

Question

I am looking for resolving the paths of files in an MSI with or without installing (whichever is faster) from outside an MSI, using VBScript.

I found a similar query using C# instead and Christpher had provided a solution, below: How can I resolve MSI paths in C#?

I am going through the very same pain now but is there anyway to achieve this using WindowsInstaller object in VBScript, rather than go with endless queries through SQL Tables of MSI back and forth to achieve the same. Though any direction would be welcoming as I have tried tested whatever I can with very limited success.

score 5 · Accepted Answer · edited Aug 07 '14 at 19:09

yes there is a solution without installing the msi and using vbscript. there is a very good example in the Windows Installer SDK called "WiFilVer.vbs"

using that example i've thrown together an quick example script that does exactly what you need.

set installer = CreateObject("WindowsInstaller.Installer")
const READONLY = 0

set db = installer.OpenDataBase("<FULL PATH TO YOUR MSI>", READONLY)
set session = installer.OpenPackage(db, READONLY)
session.DoAction("CostInitialize")
session.DoAction("CostFinalize")

set view = db.OpenView("SELECT File, Directory_, FileName, Component_, Component FROM File,Component WHERE Component=Component_ ORDER BY Directory_")
view.Execute
set record = view.Fetch

do until record is nothing
    file = record.StringData(1) 
    directoryName = record.StringData(2) 
    fileName = record.StringData(3)
    if instr(fileName, "|") then fileName = split(fileName, "|")(1)
    wsh.echo(session.TargetPath(directoryName) & fileName)
    set record = view.Fetch
loop

just add the path to your MSI file.

tell me if you need a more detailed answer. i will have some more time to answer this in detail this evening.

EDIT the promised background (and why i need to call ConstFinalize)

naveen actually MSDN was the only resource that can give an definitive answer on this, but you need to know where and how to look since windows installer ist IMHO a pretty complex topic. I really recommend a mix of the msdn installer function reference, the database reference, and the examples from the windows installer SDK (sorry couldn't find a download link, i think its somewhere hidden in the like 3GB windows SDK)

first you need general knowledge of MSIs:

an MSI is actually a relational database. Everything is stored in tables that relate to each other. (actually not everything, but i will try to keep it simple ;))

This database is interpreted by the Windows Installer, this creates a 'Session'

also some parts are dynamically resolved, depending on the system you install the msi on, like 'special' folders similar to environment variables. E.g. msi has a "ProgramFilesFolder", where windows generally has %ProgramFiles%.

All dynamic stuff only exists in the Installer session, not the database itself.

In your case there are 3 tables you need to look at, take care of the relations and resolve them.

the 'File' table contains all Files, the 'Component' table tells you which file goes into which directory and the 'Directory' table contains all information about the filesystem structure.

Using a SQL Query i could link the Component and File table to find the directory name (or primary key in database jargon).

But the directory table has relations in itself, its structured like a tree. take a look at this example directory table (taken from the instEd MSI)

The columns are Directory, Directory_Parent and DefaultDir

InstEdAllUseAppDat  InstEdAppData   InstEd
INSTALLDIR  InstEdPF    InstEd
CUBDIR  INSTALLDIR  hkyb3vcm|Validation
InstEdAppData   CommonAppDataFolder instedit.com
CommonAppDataFolder TARGETDIR   .
TARGETDIR       SourceDir
InstEdPF    ProgramFilesFolder  instedit.com
ProgramFilesFolder  TARGETDIR   .
ProgramMenuFolder   TARGETDIR   .
SendToFolder    TARGETDIR   .
WindowsFolder_x86_VC.1DEE2A86_2F57_3629_8107_A71DBB4DBED2   TARGETDIR   Win
SystemFolder_x86_VC.1DEE2A86_2F57_3629_8107_A71DBB4DBED2    WindowsFolder_x86_VC.1DEE2A86_2F57_3629_8107_A71DBB4DBED2   System

The directory_parent links it to a directory. the DefaultDir contains the actual name. You could now resolve the tree by yourself and replace all special folders(which in a vbscript would be very tedious)...

...or let the windows installer handle that (just like when installing a msi). now i have to introduce a new thing: Actions (and Sequences): when running (installing, removing, repairing) an msi a defined list of actions is performed. some actions just collect information, some change the actual database.

there are list of actions (called sequences) for various things a msi can do, like one sequence for installing (called InstallExecuteSequence), one for collecting information from the user (the UI of the MSI: InstallUISequence) or one for adminpoint installations(AdminExecuteSequence).

in our case we don't want to run a whole sequence (which could alter the system or just take to long), luckily the windows installer lets us run single actions without running a whole sequence. reading the reference of the directory table on MSDN (the remarks section) you can see which action you need:

Directory resolution is performed during the CostFinalize action

so putting all this together the script is easier to read * open the msi file * 'parse' it (providing the session) * query component and file table * run the CostFinalize action to resolve directory table (without running the whole MSI) * get the resolved path with the targetPath function

btw i found the targetPath function by browsing the Installer Reference on MSDN also i just noticed that CostInitialize is not required. its only required if you want to get the sourcePath of a file.

I hope this makes everything clearer, its very hard to explain since it took me like half a year to understand it myself ;)

And regarding PhilmEs answer: Yes there are more influences to the resolution of the directory table, like custom actions. keeping that in mind also the administrative installation might result in different directorys (eg. because different sequence might hold different custom actions). Components have conditions so maybe a file is not installed at all. Im pretty sure InstEd doesnt take custom actions into account either.

So yes, there is no 100% solution. Maybe a mix of everything is necessary.

Weberik, you are a genius! This is the eactly what I seek. I think I understand the relation your doing there b/n the tables. Although, while running the script it is triggering the MSI. Is there a way to avoid this. And can you kindly provide reference (other than MSDN, since it went over my head) or reason on why you are using costInitialize and costFinialize? — Naveen Rajeev, Jul 09 '13 at 14:43

Philm · Answer 2 · 2017-01-15T20:36:41.947

The script given by weberik (deriven from MS SDK VB code) is very good, because it makes it easy to analyse the directory table without an own algorithm (which is a mid-size effort to do it in a loop or with a recursion algorithm). But it gives not a 100% perfect view for all files, see below. The method of the script is semi-dynamic (can be extended by other actions), but in effect it gives only the static directory structure, similar to a default administrative install or advanced MSI viewers.

Normally this is enough and what we want. But be aware, that this is not the 100% solution (Knowing before exact the path of each file afterwards). That does mean, this will not give you always the correct paths in some cases:

You use command line parameters which substitute predefined directory table entries.
The MSI uses custom actions which change paths.
Especially it is not guaranteed, that every file is installed. There may be optional conditions and features and this may depend on the install environment.

In effect, a 100% solution is very very hard to achieve, without installing really. It comes near to reprogram nearly the whole windows installer engine. So simplifications are normally sufficient and accepted.

But you can extend the method to cover custom actions, e.g. with adding a line "session.DoAction(..)" for each additional action needed. Or to include command line parameters.

Sometimes it can be tricky. The easier the structure of the MSI is, the more likely it is that you succeed without more efforts.

Alternative to write an own program: The question is, what you really want to find out, and if it is really necessary to program it: If you don't want to write an automatical every-day MSI analyzer maybe the following is sufficient for you:

First tip: install the MSI with "msiexec /a mysetup.msi TARGETDIR="c:\mytestpath" . (similar restrictions as script above by weberik) If the MSI has not used custom actions to change pathes including forgetting to add to the admin sequence ("forgetting" should be taken as the normal case for 99% or existing setups :-), you get the filestructure like if you install "really" with some special namings for the Windows predefined folders which you will find out easily.

If the administrative install lacks some folders, it is often a better idea of fixing the custom action (adding to the admin sequence) and using this scenario as your primary test case. The advantage is, that only you limit the dynamics used by admin install. BTW, you can use the same command line params or path settings custom actions as in real install.

Second tip: Google for the InstEd tool , go to the file or component table and you will see the resulting MSI paths in the same static way as with the mentioned VB-script after calling CostInitialize/CostFinalize. For human view such an editor view maybe better.

For automatic testing and improvements or accuracy, you need an own program of course. For those of you that mentioned snippet given is a good starting point. :-)

The rest of you should live easier with one of the two given methods without programming.

Thank You very much for the detailed answer, Philm ! Always good to know more ! — Naveen Rajeev, Jan 12 '17 at 08:25

How can I resolve MSI paths in VBScript?

2 Answers2

Linked