Get java installed path using batch file?

Question

I need to set JAVA_HOME variable using batch script
Tried below codes, but no use.

for /f %%j in ("java.exe") do @echo.%%~dp$PATH:j

the above script gives empty

FOR /F "skip=2 tokens=2*" %%A IN ('REG QUERY "HKLM\Software\JavaSoft\Java Runtime Environment" /v CurrentVersion') DO set CurVer=%%B

the above script gives 1.6

dir java.exe /B /S

the above script gives C:\Windows\System32 but actually java installed in C:\Program Files\Java\jdk1.6.0_31

I need to set JAVA_HOME as C:\Program Files\Java\jdk1.6.0_31.

How to get this?

Bobby Rachel · Answer 1 · 2013-07-19T07:27:19.443

4

I got solution. this gives exactly the installed path.

FOR /F "skip=2 tokens=2*" %%A IN ('REG QUERY "HKLM\Software\JavaSoft\Java Development Kit" /v CurrentVersion') DO
set CurVer=%%B ECHO %CurVer%


FOR /F "skip=2 tokens=2*" %%A IN ('REG QUERY "HKLM\Software\JavaSoft\Java Development Kit\%CurVer%" /v JavaHome')
DO set JavaPath=%%B ECHO %JavaPath%

edited Jul 19 '13 at 07:27

answered Jul 19 '13 at 06:35

Bobby Rachel

453
6
10
20

Tried the second one with hardcoding the version to 1.8. However, JavaPath is only being fetched till `C:\Program` . I guess we need to work on the whitespace in `Program Files` – Shivkumar Birnale Nov 08 '19 at 10:32

score 3 · Answer 2 · answered Jul 19 '13 at 07:00

Path to Java 1.6 JavaHome:

@ECHO OFF &SETLOCAL 
FOR /F "tokens=2*" %%a IN ('REG QUERY "HKEY_LOCAL_MACHINE\SOFTWARE\JavaSoft\Java Runtime Environment\1.6" /v JavaHome') DO set "JavaHome16=%%b"
ECHO %JavaHome16%

Path to Java 1.7 JavaHome:

@ECHO OFF &SETLOCAL 
FOR /F "tokens=2*" %%a IN ('REG QUERY "HKEY_LOCAL_MACHINE\SOFTWARE\JavaSoft\Java Runtime Environment\1.7" /v JavaHome') DO set "JavaHome17=%%b"
ECHO %JavaHome17%

Susan Yanders · Answer 3 · 2013-07-19T06:16:51.760

0

how about:

setx JAVA_HOME "path/to/it"

get it by doing %JAVA_HOME%

edited Jul 19 '13 at 06:16

answered Jul 19 '13 at 06:02

Susan Yanders

854
1
9
18

How "path/to/it" will get java path? i tried, its setting JAVA_HOME as path/to/it – Bobby Rachel Jul 19 '13 at 06:13
@BobbyRachel sorry, i meant for you to replace that with your path. and i answered your how to set it question not how to get it. – Susan Yanders Jul 19 '13 at 06:15
its ok.. i know how to set. the problem is getting. – Bobby Rachel Jul 19 '13 at 06:16
before setting the path, if i get it using %JAVA_HOME% means, it will give empty value. – Bobby Rachel Jul 19 '13 at 06:19
@BobbyRachel updated it. – Susan Yanders Jul 19 '13 at 06:19
@BobbyRachel You have to have it set first – Susan Yanders Jul 19 '13 at 06:19
let us [continue this discussion in chat](http://chat.stackoverflow.com/rooms/33745/discussion-between-susan-yanders-and-bobby-rachel) – Susan Yanders Jul 19 '13 at 06:21
i guess, yet you aren't clear about my question. to set JAVA_HOME i need java installed path rite? after getting its path, i can set JAVA_HOME. i need that path to set JAVA_HOME – Bobby Rachel Jul 19 '13 at 06:22
@BobbyRachel Your computer most likely wont have the java home variable. You add that yourself – Susan Yanders Jul 19 '13 at 06:24
yep... but java home is not the only way to get its path. while installing every program, it will make an entry in registry. so possibly java will do an entry after installation. so its possible to get its path from registry, but i do not know how. – Bobby Rachel Jul 19 '13 at 06:27
@BobbyRachel Oh. you have gone beyond my knowledge. What are you trying to do anyways? – Susan Yanders Jul 19 '13 at 06:28

Ruchira Gayan Ranaweera · Answer 4 · 2013-07-19T06:27:50.890

This will work if your JAVA_HOME is configured.save this as someName.bat and run.

echo 
   where java
pause

OK then use this, By running this will creates a text file where same place you put this bat contains the JAVA path

 @ECHO OFF
SET TITLE=JavaHome.bat
TITLE=%TITLE%
SETLOCAL ENABLEDELAYEDEXPANSION
SET JDKBIN=\bin
SET JREBIN=\jre\bin
SET JBINARY=%JREBIN%\java.exe
SET SCRIPTDIR=%~dp0
SET SCRIPTDIR=%SCRIPTDIR:~0,-1%
IF EXIST "%SCRIPTDIR%\javahome.txt" (
ECHO.
ECHO JDK home already set in javahome.txt file.
GOTO :LOCKFILE
)
IF DEFINED JAVA_HOME (
ECHO.
ECHO JAVA_HOME is already set to !JAVA_HOME!
CALL :STRIP "!JAVA_HOME!">"!SCRIPTDIR!\javahome.txt"
ECHO Created !SCRIPTDIR!\javahome.txt file containing JAVA_HOME
GOTO :END
)
SET "dir=%~f0"
:DIRLOOP
CALL :FGETDIR "%dir%"
IF EXIST "%dir%\%JBINARY%" (
ECHO Parent directory search found JAVA_HOME at %dir%
GOTO :SEARCHSET
)
IF "%dir:~-1%" == ":" (
ECHO Parent directory search reached root and "%JBINARY%" was not found.
GOTO :REGISTRY
)
GOTO :DIRLOOP
:SEARCHSET
SET JAVA_HOME=%dir%
ECHO %JAVA_HOME%>javahome.txt
ECHO Created file %SCRIPTDIR%\javahome.txt with value %JAVA_HOME%
GOTO :END
:REGISTRY
:: registry search section
:: runs only when JAVA_HOME not set, file search fails, and javahome.txt doesn't exist
ECHO Searching registry for JAVA_HOME...
ECHO. 2>merged.txt
ECHO. 2>list.txt
ECHO. 2>uniquelist.txt
IF NOT EXIST reg32.txt ECHO. 2>reg32.txt
IF NOT EXIST reg64.txt ECHO. 2>reg64.txt
START /w REGEDIT /e reg32.txt "HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\JavaSoft\Java Development Kit"
TYPE reg32.txt | FIND "JavaHome" > merged.txt
START /w REGEDIT /e reg64.txt "HKEY_LOCAL_MACHINE\SOFTWARE\JavaSoft\Java Development Kit"
TYPE reg64.txt | FIND "JavaHome" >> merged.txt
FOR /f "tokens=2 delims==" %%x IN (merged.txt) DO (
CALL :STRIP "%%~x" >>list.txt
)
FOR /F "tokens=* delims= " %%a IN (list.txt) DO (
SET str=%%a
FIND /I ^"!str!^" list.txt>nul
FIND /I ^"!str!^" uniquelist.txt>nul
IF ERRORLEVEL 1 ECHO !str!>>uniquelist.txt
)
:PROMPT
ECHO Select a JDK from the list:
SET /A COUNT=0
FOR /f "tokens=1,* delims=" %%y IN (uniquelist.txt) DO (
SET /A COUNT += 1
ECHO !COUNT!: %%~y
)
SET /P NUMBER=Type a number here:
IF "%NUMBER%" GTR "%COUNT%" GOTO :PROMPT
SET /A COUNT=0
FOR /f "tokens=1,* delims=" %%z IN (uniquelist.txt) DO (
SET /A COUNT += 1
IF !COUNT!==!NUMBER! (
SET JAVA_HOME=%%~z
)
)
ECHO %JAVA_HOME%>javahome.txt
GOTO CLEANUP

:: batch functions section
:FGETDIR
SET "dir=%~dp1"
SET "dir=%dir:~0,-1%"
EXIT /B 0
:STRIP
REM Strip quotes and extra backslash from string
SET n=%~1
SET n=%n:\\=\%
SET n=%n:"=%
IF NOT "%n%"=="" ECHO %n%
GOTO :EOF
:: cleanup and end
:CLEANUP
REM cleanup of registry search
DEL /Q merged.txt
DEL /Q list.txt
DEL /Q uniquelist.txt
DEL /Q reg32.txt
DEL /Q reg64.txt
GOTO :LOCKFILE
:: if all fails
:FAILED
IF NOT DEFINED JAVA_HOME (
ECHO Error: JAVA_HOME not set in system vars, file search failed, && javahome.txt didn't exist.
GOTO :END
)
:LOCKFILE
ECHO.
SET /P JAVA_HOME=<"%SCRIPTDIR%\javahome.txt"
ECHO The file %SCRIPTDIR%\javahome.txt shows JAVA_HOME to be %JAVA_HOME%
:END
FOR /l %%a in (30,-1,1) do (TITLE %TITLE% -- Closing in %%as&ping -n 2 -w 1 127.0.0.1>NUL)

FYI : original reference: https://gist.github.com/djangofan/1445440

JAVA_HOME configured means? its giving, C:\Windows\System32\java.exe. i want program files location. — Bobby Rachel, Jul 19 '13 at 06:15

Get java installed path using batch file?

4 Answers4