Vimscript: Number of listed buffers

Question

In my vimscript, I need to get a count of all buffers that are considered listed/listable (i.e. all buffers that do not have the unlisted, 'u', attribute).

What's the recommended way of deriving this value?

score 16 · Accepted Answer · answered Jul 29 '13 at 20:14

16

You could use bufnr() to get the number of the last buffer, then create a list from 1 to that number and filter it removing the unlisted buffers, by using the buflisted() function as the test expression.

" All 'possible' buffers that may exist
let b_all = range(1, bufnr('$'))

" Unlisted ones
let b_unl = filter(b_all, 'buflisted(v:val)')

" Number of unlisted ones
let b_num = len(b_unl)

" Or... All at once
let b_num = len(filter(range(1, bufnr('$')), 'buflisted(v:val)'))

answered Jul 29 '13 at 20:14

sidyll

57,726
14
108
151

I'm under the impression that this answer don't quite address the OP's question. He asked for "listed", not "unlisted". Although I see how it is related, of course. But I believe the answer would be simpler, and I'm curious to how that would be. -- Edited: it seems it do answer by filtering the unlisted "out" – DrBeco Jul 12 '17 at 16:49

score 4 · Answer 2 · answered Mar 07 '19 at 04:08

4

A simple solution is using getbufinfo.

In your vimscript:

len(getbufinfo({'buflisted':1}))

or test it with command:

:echo len(getbufinfo({'buflisted':1}))

answered Mar 07 '19 at 04:08

hankchiutw

1,546
1
12
15

score 3 · Answer 3 · answered Jul 29 '13 at 20:13

I would do it by calling buflisted() on the range of numbers up to the largest buffer number given by bufnr("$"). Something like this:

function! CountListedBuffers()
    let num_bufs = 0
    let idx = 1
    while idx <= bufnr("$")
        if buflisted(idx)
            let num_bufs += 1
        endif
        let idx += 1
    endwhile
    return num_bufs
endfunction

Vimscript: Number of listed buffers

3 Answers3

Linked