Batch file if statement fail

Question

I am trying to just see if an application is currently running based on the Image Name in the task manager or tasklist... I am using firefox.exe as the example but it always fails. The goal is to not launch another script if its already running and/or to taskkill it when we need.

This is my current status script:

@echo off
set STATUS=
FOR /F "tokens=*" %%A IN ('tasklist ^| findstr "firefox.exe"') DO SET STATUS=%%A
echo %STATUS%
if [%STATUS%]==[] set STATUS=stopped

echo %STATUS%

Always gives the following output: (it always fails on the if statement)

firefox.exe                   6216 Console                    1    411,760 K
6216 was unexpected at this time.

Do you have an idea why this is or suggest another way to go about achieve this?

use better `if not defined status set "status=stopped"` – Endoro Jul 30 '13 at 20:12 — Endoro, Jul 30 '13 at 20:12

score 2 · Answer 1 · answered Jul 30 '13 at 20:17

2

better than compare is the test of existence:

  if not defined status set "status=stopped"

answered Jul 30 '13 at 20:17

Endoro

37,015
8
50
63

score 1 · Accepted Answer · edited May 23 '17 at 11:46

1

Try this instead:

if "%STATUS%"=="" set STATUS=stopped

The issue is that STATUS has spaces in it, and it's handled by the quotes but not brackets. Try the batch file below to see what's going on... right before the if statement, you will see the value of status which is echoed.

@echo off
set STATUS=
FOR /F "tokens=*" %%A IN ('tasklist ^| findstr "firefox.exe"') DO (
  SET STATUS=%%A
)
echo The status is "%STATUS%"
if [%STATUS%]==[] set STATUS=stopped

echo %STATUS%

See also this related thread: What is the proper way to test if variable is empty in a batch file?

edited May 23 '17 at 11:46

Community

1
1

answered Jul 30 '13 at 20:11

JohnD

14,327
4
40
53

It is good practice to do set "STATUS=" instead of set STATUS= So that you don't introduce a trailing space! – RGuggisberg Jul 30 '13 at 20:36
concerning your link, please note: `%1` is **not** a variable, it's a batch parameter. – Endoro Jul 30 '13 at 20:51

score 1 · Answer 3 · answered Jul 31 '13 at 01:20

1

Here's one method:

@echo off
set "prog=firefox.exe"
tasklist /fi "IMAGENAME EQ %prog%"| find /i "%prog%" >nul && (echo %prog% is running) || (echo %prog% is stopped)

answered Jul 31 '13 at 01:20

foxidrive

40,353
10
53
68

score 1 · Answer 4 · edited Apr 28 '17 at 13:35

1

The best way i have seen (for me) was this, which was from another user here on stack, can't find the original question though :

:LOOP
tasklist | find /i "program.exe" >nul 2>&1
IF ERRORLEVEL 1 (
  GOTO CONTINUE
) ELSE (
  ECHO Program still running!
  Timeout /T 3 /Nobreak
  GOTO LOOP
)

:CONTINUE

You can adjust the time you want (this one checks every 3 seconds)

edited Apr 28 '17 at 13:35

Mark Wragg

22,105
7
39
68

answered Jan 11 '17 at 16:40

Rakha

1,874
3
26
60

Batch file if statement fail

4 Answers4