Loading multiple swf files

Question

Like every programmer I´m facing a tricky challenge, and I hope someone could share with me some knowledge.   I'm creating a game, and for each game component(such as audio, video, pictures), I´ve created a swf file(library). At the main file, I am trying to load my swf files using the Loader class.   I would like to make a preloader and I want to calculate the percentage of bytes loaded from of all of my swf files. I´ve realized that loading 3 loaders at the same time makes my game slow. I tried to upload one file at a time, but I don´t know how to catch the bytes loaded from my files without using ProgressEvent(Here I can access bytesTotal variable).   Does anyone faced a similar problem and could share a tip or a link?     Regards and Good Friday!

Answer 1

I strongly recommend you the GreenSock's LoaderMax library. It simplifies and enhances the entire process. It's easy to setup and small.

import com.greensock.*;
import com.greensock.loading.*;
import com.greensock.events.LoaderEvent;
import com.greensock.loading.display.*;

// Create a LoaderMax named "gameQueue" and bind onProgress, onComplete and onError listeners
var queue:LoaderMax = new LoaderMax({name:"gameQueue", onProgress:progressHandler, onComplete:completeHandler, onError:errorHandler});

// Append several loaders
queue.append( new XMLLoader("xml/data.xml", {name:"xmlDoc"}) );
queue.append( new ImageLoader("img/photo1.jpg", {name:"photo1", estimatedBytes:2400, container:this, alpha:0, width:250, height:150, scaleMode:"proportionalInside"}) );
queue.append( new SWFLoader("swf/child.swf", {name:"childClip", estimatedBytes:3000, container:this, x:250, autoPlay:false}) );
queue.append( new MP3Loader("mp3/audio.mp3", {name:"audio", repeat:2, autoPlay:true}) );

// Run
queue.load();

function progressHandler(event:LoaderEvent):void {
    trace("progress: " + event.target.progress);
}

function completeHandler(event:LoaderEvent):void {
    var image:ContentDisplay = LoaderMax.getContent("photo1");
    TweenLite.to(image, 1, {alpha:1, y:100});
    trace(event.target + " is complete!");
}

function errorHandler(event:LoaderEvent):void {
    trace("error occured with " + event.target + ": " + event.text);
}

You can display the progress of individual loaders or groups of loaders.

In order to accurately calculate the overall progress of a group of loaders, it’s important to know the total file size (bytesTotal) of each child loader. But if some files haven’t started loading yet, how could your loader possibly know their sizes?

There's no TCP packet, that will inform you about the final size when the progress starts.

Remember: get is like a stream. You'll never know the final size, until the file is ready!

new ImageLoader("1.jpg", {estimatedBytes:26000});

A simple workaround:

1. Generate a xml or json list, that contains the url and the total size of each preloadable element. You can do this with some automation in php (for example), check this SO answer.

2. Preload the xml/json file-list with LoaderMax and parse it in AS3.

3. Load all files from within the xml and add the correct file size. That's it.

You can find the full AS3 documentation here.

Answer 2

Start to load your files, get file size and close the stream immediately after you received size info.

And then load your files one by one as you wanted.

Or compile your main swf with merged into code libraries(if this is suitable for you).