Using a variable name as the key name in a hash (Perl)

Question

I have this block of Perl code that I want to simplify. It's part of a subroutine, where a series of arguments are added to values to a hash of hashes.

$user{$account_num}{'item0'} += $item0;
$user{$account_num}{'item1'} += $item1;
$user{$account_num}{'item2'} += $item2;
$user{$account_num}{'item3'} += $item3;
$user{$account_num}{'item4'} += $item4;
$user{$account_num}{'item5'} += $item5;
$user{$account_num}{'item6'} += $item6;

You can see that the variable names are the same as the key names. I seem to remember watching a friend do this kind of thing in one line once. Something like:

[looping through input arguments]:
$user{$account_num}{'variable_name'} += $variable_name;

Does anybody know of a way to do this?

Answer 1

The syntax is

for my $i (0..6) {
   my $variable_name = "item$i";
   $user{$account_num}{$variable_name} += $$variable_name;
}

but it assumes $item0 and such are package variables, and its use goes against the fundamental principles of software development.

---

You should be using an array.

$user{$account_num}{'item0'} += $items[0];
$user{$account_num}{'item1'} += $items[1];
$user{$account_num}{'item2'} += $items[2];
$user{$account_num}{'item3'} += $items[3];
$user{$account_num}{'item4'} += $items[4];
$user{$account_num}{'item5'} += $items[5];
$user{$account_num}{'item6'} += $items[6];

which allows you to use

for my $i (0..$#items) {
    $user{$account_num}{"item$i"} += $items[$i];
}

Answer 2

You're over thinking it.

I can tell because I do it all of the time:

Me: If I make a device that can vibrate the socket with the right frequency, I can cause that bulb to screw and unscrew. I can then attach the device to the socket...

My Son: Dad, why don't you just use the light switch?

If you have a bunch of items called item1, item2, item3, etc. Why not make this an array of items? Then you would have $item[0], $item[1], etc. That would greatly simplify your code:

for item ( @items ) {
    $user{$account_name}->[$item] += $items[item];
}

Maybe you were using item1 and item2 as stand-ins to the actual variable names. Maybe they're $widget and $left_handed_smoke_shifter. In that case, you can make it a hash of items, so you would have $item{left_handed_smoke_shifter} and $item{widget}. Then, your loop would look something like this:

for my $item ( keys %items ) {
    $user{$account_name}->{$item} += $items{$item};
}

Simple, easy to understand and maintain.

However, if you really, truly insist that you need to be able to use variable names the way you insist, use eval:

$user{$account_name}->{$varible_name} = eval '$' . "$variable_name";

I just sell lengths of ropes that are long enough for someone to hang themselves with it. What they actually do with it is none of my business.

Answer 3

The problem with the above code is you want to use the name of the variable as the key, which could look like this:

for my $item ( @items ) {
   $user{$account_num}{$item} = $item
}

the problem being that $items value is going to be used as the key, not its name.

Possible solutions:

This would be greatly simplified if you also had a list of the key names:

my @keys = qw(item0 item1 item2 item3 item4 item5 item6);

Now assuming you actually have all of these items coming into your subroutine, you can easily loop

# 1
sub update_items {
   my @items = @_;

   for my $k ( @keys ) { 
      my $item = shift @items;          # take an item from the front
      $user{$account_num}{$k} += $item; # update
   }
}

OR you could use a technique called hash-slicing which takes a hash in list context and assigns a list of values to a list of keys:

# 2
sub update_items {
   my @items = @_;

   # update all keys of @keys with all values of @items
   @user{$account_num}{@keys} += @items;
}

Answer 4

Here's a simple example in the Perl debugger:

main::(-e:1):   0
  DB<1> @a=('v1', 'v2', 'v3', 'v4')

  DB<2> x @a
0  'v1'
1  'v2'
2  'v3'
3  'v4'
  DB<3> $v1=10
  DB<4> $v2=20
  DB<5> $v3=30
  DB<6> $v4=40

  DB<7> for (@a) { $hash{$_} += $$_ }

  DB<8> x %hash
0  'v4'
1  40
2  'v1'
3  10
4  'v2'
5  20
6  'v3'
7  30
  DB<10>

The key is $$_, which uses variable indirection to get the value of a variable whose name is contained in a variable, in this case $_.

Answer 5

#!/usr/bin/env perl

use strict;
use warnings;

use Data::Dumper;
$Data::Dumper::Indent = 0;

my %user = (
    '0022334401' => [ map int(1000 * rand), 1 .. 7 ],
    '1177459393' => [ map int(1000 * rand), 1 .. 7 ],
);

my $account_id = '0022334401';

print "Before:\n", Dumper($user{$account_id}) ,"\n";

my @vals = (11, 22, 33, 44, 55, 66, 77);

# done setting up. now, update each value for $user{$account_id}
# by adding the value at the corresponding index in @vals

$user{$account_id}[$_] += $vals[$_] for 0 .. $#vals;

print "After:\n", Dumper($user{$account_id}), "\n";

Sample output:

Before:
$VAR1 = [645,553,864,165,463,455,906];
After:
$VAR1 = [656,575,897,209,518,521,983];

Answer 6

The tidiest way is with eval. Like this

$user{$account_num}{$_} += eval "\$$_" for 'item0' .. 'item6'

but remember what others have said, that you shouldn't be doing this sort of thing. Refactor the code as soon as it is appropriate.