How to loop through array in batch?

Question

I created an array like this:

set sources[0]="\\sources\folder1\"
set sources[1]="\\sources\folder2\"
set sources[2]="\\sources\folder3\"
set sources[3]="\\sources\folder4\"

Now I want to iterate through this array:

for %%s in (%sources%) do echo %%s

It doesn't work! It seems that script is not going into the loop. Why is that? How can I iterate then?

score 56 · Answer 1 · answered Sep 11 '14 at 15:48

56

Another Alternative using defined and a loop that doesn't require delayed expansion:

set Arr[0]=apple
set Arr[1]=banana
set Arr[2]=cherry
set Arr[3]=donut

set "x=0"

:SymLoop
if defined Arr[%x%] (
    call echo %%Arr[%x%]%%
    set /a "x+=1"
    GOTO :SymLoop
)

Be sure you use "call echo" as echo won't work unless you have delayedexpansion and use ! instead of %%

answered Sep 11 '14 at 15:48

Dss

2,162
1
24
27

1

I like this way. Its bit simpler – Farrukh Waheed Jan 23 '15 at 12:55
1

Whoever designed loops syntax in batch files was... a funny guy. – dzieciou Oct 26 '22 at 11:59

score 42 · Accepted Answer · edited Sep 15 '15 at 14:18

42

If you don't know how many elements the array have (that seems is the case), you may use this method:

for /F "tokens=2 delims==" %%s in ('set sources[') do echo %%s

Note that the elements will be processed in alphabetical order, that is, if you have more than 9 (or 99, etc) elements, the index must have left zero(s) in elements 1..9 (or 1..99, etc.)

edited Sep 15 '15 at 14:18

Bucket

7,415
9
35
45

answered Aug 28 '13 at 06:38

Aacini

65,180
12
72
108

score 31 · Answer 3 · answered Aug 27 '13 at 13:02

31

If you don't need environment variables, do:

for %%s in ("\\sources\folder1\" "\\sources\folder2\" "\\sources\folder3\" "\\sources\folder4\") do echo %%s

answered Aug 27 '13 at 13:02

LS_ᴅᴇᴠ

10,823
1
23
46

12

This is definitely not helpful :/ I asked how to iterate through array, and you gave an answer: "just don't use the array!" – aurel Aug 28 '13 at 13:02
24

I only gave you this suggestion because sometimes I reconsider my program architecture depending on possible solutions. Imagine you had create array just to be able to iterate through items, then iterating without previous array would turn that array unneeded! – LS_ᴅᴇᴠ Aug 28 '13 at 13:12
notice that space between `in` and `(` is important. This wont work: `in("\\sources...)` but if you write with space `in ("\\sources...)` would work – Dimitry K Sep 04 '17 at 16:39

foxidrive · Answer 4 · 2014-01-16T15:45:02.540

18

This is one way:

@echo off
set sources[0]="\\sources\folder1\"
set sources[1]="\\sources\folder2\"
set sources[2]="\\sources\folder3\"
set sources[3]="\\sources\folder4\"

for /L %%a in (0,1,3) do call echo %%sources[%%a]%%

edited Jan 16 '14 at 15:45

answered Aug 27 '13 at 09:58

foxidrive

40,353
10
53
68

7

@LS_dev Oh ye of little faith. Try it. :) – foxidrive Aug 27 '13 at 13:49
1

You're right, my apologies! As an aside, it would be nice to have a dynamic iteration regardless of array length. – Wim Jan 17 '14 at 11:16
note that the `for /L` loop needs (0,1,), in this case last_element_id is 3 – Zac Apr 05 '23 at 14:36

score 5 · Answer 5 · answered Dec 07 '18 at 09:26

For posterity: I just wanted to propose a slight modification on @dss otherwise great answer.

In the current structure the way that the DEFINED check is done causes unexpected output when you assign the value from Arr to a temporary variable inside the loop:

Example:

@echo off
set Arr[0]=apple
set Arr[1]=banana
set Arr[2]=cherry
set Arr[3]=donut

set "x=0"

:SymLoop
if defined Arr[%x%] (
    call set VAL=%%Arr[%x%]%%
    echo %VAL%
    REM do stuff with VAL
    set /a "x+=1"
    GOTO :SymLoop
)

This actually produces the following incorrect output

donut
apple
banana
cherry

The last element is printed first. To fix this it is simpler to invert the DEFINED check to have it jump over the loop when we're done with the array instead of executing it. Like so:

@echo off
set Arr[0]=apple
set Arr[1]=banana
set Arr[2]=cherry
set Arr[3]=donut

set "x=0"

:SymLoop
if not defined Arr[%x%] goto :endLoop
call set VAL=echo %%Arr[%x%]%%
echo %VAL%
REM do your stuff VAL
SET /a "x+=1"
GOTO :SymLoop

:endLoop
echo "Done"

This regardless of what you do inside the SymLoop always produces the desired correct output of

apple
banana
cherry
donut
"Done"

The problem in your first example is simply the `echo %var%` change it to `call echo %%var%%` and it works as expected. Or even better, use delayed expansion — jeb, Dec 07 '18 at 09:50
@jeb This is the crux of the issue, the code inside the loop doesn't behave as you would expect it in a normal bat script. You need to call things differently. This will be a maintenance pain in the long term.. better just make sure it works as users expect. — Sverrir Sigmundarson, Dec 07 '18 at 10:46
It behaves exactly as expected in a batch script! It's important to know, [how batch works](https://stackoverflow.com/a/4095133/463115), than to circumvent constructs you don't understand. And you couldn't circumvent all parenthesis blocks. — jeb, Dec 07 '18 at 11:12

score 4 · Answer 6 · answered Jul 04 '18 at 16:42

i use like this, what is important is that the variable is only 1 length, like %%a, and not like %%repo:

for %%r in ("https://github.com/patrikx3/gitlist" "https://github.com/patrikx3/gitter" "https://github.com/patrikx3/corifeus" "https://github.com/patrikx3/corifeus-builder" "https://github.com/patrikx3/gitlist-workspace" "https://github.com/patrikx3/onenote" "https://github.com/patrikx3/resume-web") do (
   echo %%r
   git clone --bare %%r
)

How to loop through array in batch?

6 Answers6

Linked