XSLT 1 display distinct values

Question

Is there an easy way to get the following code to only show distinct values please?

<xsl:template match="/">
   <xsl:for-each select="NewDataSet/Vehicle">
      <xsl:value-of select="ManufacturerName" />
   </xsl:for-each>

<!-- Does a load of other stuff down here -->

</xsl:template>

This is essentially what the xml looks like:

<NewDataSet>
  <Vehicle>
   <ManufacturerName>FORD</ManufacturerName>
  </Vehicle>
  <Vehicle>
   <ManufacturerName>CHEVROLET</ManufacturerName>
  </Vehicle>
  <Vehicle>
   <ManufacturerName>VAUXHALL</ManufacturerName>
  </Vehicle>
  <Vehicle>
   <ManufacturerName>VAUXHALL</ManufacturerName>
  </Vehicle>
  <Vehicle>
   <ManufacturerName>VAUXHALL</ManufacturerName>
  </Vehicle>
</NewDataSet>

Thanks.

Distinct values of what? Can you show an example of your input XML? — Ben L, Sep 11 '13 at 11:09
possible duplicate of [How to use XSLT to create distinct values](http://stackoverflow.com/questions/2291567/how-to-use-xslt-to-create-distinct-values) — Nick Grealy, Sep 04 '14 at 23:45

score 4 · Accepted Answer · answered Sep 11 '13 at 12:52

To get distinct values, the most efficient way is usually to use a technique called Muenchian Grouping. You may not actually be getting all the vehicles in a group, but to get the distinct values you effectively get the first element in each group.

To do this, you define a key to look-up Vehicle elements by the ManufacturerName

<xsl:key name="Manufacturer" match="Vehicle" use="ManufacturerName" />

Then, to get the distinct values, you iterate over all Vehicle elements, and pick the one which occurs first in the key for its given ManufacturerName

<xsl:for-each select="Vehicle
              [generate-id() = generate-id(key('Manufacturer', ManufacturerName)[1])]">

Try this XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:key name="Manufacturer" match="Vehicle" use="ManufacturerName" />

  <xsl:template match="/*">
    <xsl:for-each select="Vehicle[generate-id() = generate-id(key('Manufacturer', ManufacturerName)[1])]">
      <xsl:value-of select="ManufacturerName"/>
    </xsl:for-each>
    <!-- Does a load of other stuff down here -->
  </xsl:template>
</xsl:stylesheet>

score 2 · Answer 2 · answered Sep 11 '13 at 11:34

This XSLT stylesheet:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="text"/>

  <xsl:template match="NewDataSet">
    <xsl:apply-templates select="Vehicle[not(ManufacturerName=preceding-sibling::Vehicle/ManufacturerName)]"/>  
  </xsl:template>

  <xsl:template match="Vehicle">
    <xsl:value-of select="ManufacturerName"/>
    <xsl:text>&#xa;</xsl:text>
  </xsl:template>
</xsl:stylesheet>

produces the following output when applied to your example XML:

FORD
CHEVROLET
VAUXHALL

The important part is the select in the xsl:apply-templates. It works by only selecting Vehicle elements whose Manufacturer has not appeared in one of the preceding Vehicle elements at the same level.

Sorry, this is totally my fault for over simplifying the code. I'm running into problems, and this is due to my lack of knowledge with regard to XSL. My xslt is doing a load of other stuff, so the distinct list need to be assimilated from within a template. I've again amended my original post to try and describe what I mean. Sorry. — Strontium_99, Sep 11 '13 at 12:08

score 1 · Answer 3 · edited May 23 '17 at 12:05

1

This has to be the easiest way to show distinct values... (The <xsl:text>
</xsl:text> is just to display new lines).

XSL

<xsl:template match="/">
    <xsl:for-each select="//ManufacturerName[not(.=preceding::*)]">
        <xsl:value-of select="." /><xsl:text>&#xa;</xsl:text>
    </xsl:for-each>
</xsl:template>

Result

FORD
CHEVROLET
VAUXHALL

More information here.

edited May 23 '17 at 12:05

Community

1
1

answered Sep 04 '14 at 23:45

Nick Grealy

24,216
9
104
119

XSLT 1 display distinct values

3 Answers3