Batch file - Pick a card

Question

I created a batch file that selects a random playing card using the variable %random%. the batch script keeps looping until %random% is between 1 and 13, and does it again for the suit. I then convert the variables that are set as numbers into text, so the batch file would say something like this: Four of Hearts, or King of Spades. The only problem is, it takes forever! If you open CMD.exe and type in

Echo %random%

and do that until the number is between 1 and four, you will be there FOREVER. Even if you put it into a batch file and use a loop, It still takes about twenty seconds. Is there a way to cut down the time, by perhaps narrowing down the search BEFORE the random number generation? I'm really not sure. In case it helps, or you can't understand me, here's the code:

@echo off
:loop
cls
echo generating card...
set num=%random%
if /i %num% GTR 13 goto loop
if /i %num% LSS 1 goto loop
goto next
:next
set suit=%random%
if /i %suit% GTR 4 goto next
if /i %suit% LSS 1 goto next
goto next2
:next2
if %num%==11 set num=jack
if %num%==12 set num=queen
if %num%==13 set num=king
goto next3
:next3
if %suit%==1 set suiter=Hearts
if %suit%==2 set suiter=Diamonds
if %suit%==3 set suiter=Clubs
if %suit%==4 set suiter=Spades
goto ech
:ech
echo %num% of %suiter%
echo.
echo.
echo.
echo press any key to choose again
pause >nul
goto loop

score 2 · Answer 1 · edited May 23 '17 at 10:25

2

You can use a little math to get a number between 1 and 13 on the first try:

set /a num=13*%random%/32768+1

and the same thing for 1 and 4

set /a suit=4*%random%/32768+1

See How to use random in BATCH script? - very similar to what you're asking

edited May 23 '17 at 10:25

Community

1
1

answered Sep 27 '13 at 22:38

Barbara Laird

12,599
2
44
57

urish · Accepted Answer · 2013-09-27T22:43:57.817

1

You can completely eliminate the search using a simple remainder operation, thus limiting the generated random numbers to be in the range [1,13] and [1,4]. This will also simplify the code much. You can achieve this using the 'set /a' command which can be used for arithmetic. Just change your script to read:

@echo off
:loop
cls
echo generating card...
set /a num=%random% %% 13 + 1
set /a suit=%random% %% 4 + 1
if %num%==11 set num=jack
if %num%==12 set num=queen
if %num%==13 set num=king
if %suit%==1 set suiter=Hearts
if %suit%==2 set suiter=Diamonds
if %suit%==3 set suiter=Clubs
if %suit%==4 set suiter=Spades
goto ech
:ech
echo %num% of %suiter%
echo.
echo.
echo.
echo press any key to choose again
pause >nul
goto loop

Good luck!

edited Sep 27 '13 at 22:43

answered Sep 27 '13 at 22:37

urish

8,943
8
54
75

1

Well, that certainly is better than your first answer. – Barbara Laird Sep 27 '13 at 22:49
Thanks! Just a moment after writing it I realized it was actually biased towards generating two digit numbers (10, 11, 12) so I looked for a better approach... – urish Sep 27 '13 at 22:57

Batch file - Pick a card

2 Answers2